论坛 › C07：ANSYS--实例赏评 › 浅层地下隧道3D模型

winloudy 发表于 2011-9-29 21:16:32

浅层地下隧道3D模型

本帖最后由 winloudy 于 2011-11-3 14:12 编辑

这是我自己为了完成课程作业自己编写的命令流，大家觉得有借鉴的地方可以学习，觉得有改进的地方可以指正！谢谢大家相互交流！

FINI
/CLEAR
/PREP7
!定义几何参数
EL=2               !纵向单元长度
H=6.35+4.9+0.4+0.5
NN=3
L=8*NN
B=9.05*2+0.9
HN1=10
BN1=2
BN2=20
BN=BN2*2-1+(BN1+1)*2
LN=3*8/EL+1
DD=0.8         !立柱的直径
!定义材料参数
K1=77.4E6*B*L/BN*LN
K2=1000
!!!
ET,1,45
MP,EX,1,30E9
MP,PRXY,1,0.2
MP,DENS,1,25E3
ET,2,PIPE288      !用188不能抗扭，自然不能计算
MP,EX,2,30E9
MP,PRXY,2,0.2
MP,DENS,2,25E3
ET,3,14   !底面弹簧
ET,4,14   !侧面弹簧
R,1
R,2
R,3,K1
R,4,K2
SECTYPE,2,PIPE
SECDATA,DD,DD/2-0.05,16
SECPLOT,2
!创建几何模型
K,1 $ K,2,0.9 $ K,3,0.9+8.2+0.4
KGEN,,ALL,,,-B/2,0,0,,,1                        !移动
KGEN,2,ALL,,,0,1,0
!!
KSEL,S,LOC,Y,0
KGEN,2,ALL,,,0,6.55
KSEL,S,LOC,Y,0
KGEN,2,ALL,,,0,6.55+0.6
KSEL,S,LOC,Y,0
KGEN,2,ALL,,,0,6.55+0.3+4.9-0.4
KSEL,S,LOC,Y,0
KGEN,2,ALL,,,0,6.55+0.3+4.9+0.4
KSEL,S,LOC,Y,0
KSEL,R,LOC,X,-B/2,-B/2+0.9
KGEN,2,ALL,,,0,1,0
!!柱截面控制点
!创建荷载施加位置控制点
KSEL,S,LOC,Y,0
KGEN,2,ALL,,,0,8.24
!
K,1E4,,1,100
K,1E4+1,,7.15,100
ALLSEL
!!横向
A,1,2,5,4 $ A,2,3,6,5
A,7,8,11,10 $ A,8,9,12,11
A,13,14,17,16 $ A,14,15,18,17
!!竖向
A,19,20,8,7 $ A,10,11,22,21 $ A,21,22,14,13
!!柱体
L,6,9 $ L,12,15
!!
LSEL,S,LENGTH,,0.9
LSEL,A,LENGTH,,0.6
LSEL,A,LENGTH,,0.8
LESIZE,ALL,,,BN1
LSEL,S,LENGTH,,1
LESIZE,ALL,,,BN1*2
!!水平
LSEL,S,LENGTH,,9.05-0.45
LESIZE,ALL,,,BN2
!!竖直
LSEL,S,LENGTH,,5.55
LSEL,R,LOC,X,-B/2,-B/2+0.9
LESIZE,ALL,,,HN1
!!
LSEL,S,LOC,X,-B/2,-B/2+0.9
LSEL,R,LOC,Y,6.35+0.5+0.3,H-0.8
LESIZE,ALL,4.2/HN1
!!立柱预划分
LSEL,A,LENGTH,,5.55
LSEL,R,LOC,X,0
LATT,2,2,2,,1E4,,2
LESIZE,ALL,,,HN1
LSEL,S,LENGTH,,5-0.8
LATT,2,2,2,,1E4+1,,2
LESIZE,ALL,4.2/HN1
ALLSEL
ARSYM,X,ALL
!!
ASEL,S,LOC,Y,1,H
LSLA,S
KSLL,S
NUMMRG,KP
ASEL,S,LOC,Y,1,0
LSLA,S
KSLL,S
NUMMRG,KP
ALLSEL
NUMCMP,AREA
!!
!!!!!沿纵向创建
/VIEW,1,1,1,1
VEXT,ALL,,,0,0,4
*DO,I,1,2*NN-1,1
ASEL,S,LOC,Z,-4*(I-1)
VEXT,ALL,,,0,0,-4
*ENDDO
ALLSEL
LESIZE,ALL,EL
!!!立柱复制
LSEL,S,TYPE,,2
LGEN,NN,ALL,,,0,0,-8
KSEL,S,LOC,X,0
NUMMRG,KP
LSEL,S,TYPE,,2
TYPE,2 $ MAT,2 $ REAL,2
LMESH,ALL
!!
ALLSEL
TYPE,1
MAT,1
REAL,1
VMESH,ALL
NSEL,S,LOC,Y,1+0.001,H
NUMMRG,NODE
NSEL,S,LOC,Y,-0.001,0
NUMMRG,NODE
/ESHAPE,1
!!!创建底面弹簧
NSEL,S,LOC,Y,-0.01,0.001
NGEN,2,1E6,ALL,,,0,-0.5
TYPE,3 $ MAT,3 $ REAL,3
EINTF,,,LOW,,0,0.5,0
!!!创建侧面弹簧
TYPE,4 $ MAT,4 $ REAL,4
NSEL,S,LOC,X,-B/2
NSEL,U,LOC,Y,-0.5
NGEN,2,1E6,ALL,,,-0.5,
EINTF,,,LOW,,0.5,0,0
NSEL,S,LOC,X,B/2
NSEL,U,LOC,Y,-0.5
NGEN,2,1E6,ALL,,,0.5,
EINTF,,,LOW,,0.5,0,0
ALLSEL
!!!!!!!!!!!!!!!!!!!!!!!!!
!!!施加边界条件!!!!!!!!
!!约束弹簧
NSEL,S,LOC,Y,-0.5
NSEL,A,LOC,X,-B/2-0.5
NSEL,A,LOC,X,B/2+0.5
D,ALL,ALL
!!纵向对称约束
NSEL,S,LOC,Z,4
NSEL,A,LOC,Z,-L+4
DSYM,SYMM,Z
!!底板和墙面节点耦合
NSEL,S,LOC,Y,1
NSEL,U,LOC,X,-B/2+0.9+0.001,B/2-0.9-0.001
CPINTF,UX
CPINTF,UY
CPINTF,UZ
!!施加荷载
!!顶面土压力
ALLSEL
/PSF,PRES,NORM,2,1,1
ASEL,S,LOC,Y,H
SFA,ALL,,PRES,138.646E3
!!底面水压力
ASEL,S,LOC,Y,0
SFA,ALL,,PRES,111.24E3
!!站厅层荷载
ASEL,S,LOC,Y,7.15
ASEL,R,LOC,X,-B/2+0.9,B/2-0.9
SFA,ALL,,PRES,16.4E3
!!侧面土压力和水压力荷载
ASEL,S,LOC,X,-B/2
ASEL,A,LOC,X,B/2
ASEL,R,LOC,Y,0,H-3.91
SFGRAD,PRES,0,Y,0,-18.049757E3
SFA,ALL,,PRES,82.4E3+161.58E3
!
ASEL,S,LOC,X,-B/2
ASEL,A,LOC,X,B/2
ASEL,R,LOC,Y,H-3.91,H
SFGRAD,PRES,0,Y,0,-8.051029E3
SFA,ALL,,PRES,161.58E3
!SFALIST,ALL
ALLSEL
FINI
/SOLU
ACEL,0,9.8,0
/ESHAPE,0
SOLVE
FINI
!!!后期处理
/POST1
/PLOPTS,INFO,2
/PLOPTS,FRAME,OFF
/ESHAPE,1         
PLNSOL,U,SUM
ESEL,S,TYPE,,1,2
PLNSOL,U,SUM
PLNSOL,S,EQV

xiaohu_86001 发表于 2011-10-4 15:03:47

抢沙发:)

qichun3277 发表于 2011-10-4 23:03:51

哎呦，怎么还要收费啊

winloudy 发表于 2011-10-7 01:29:59

我第一次发哈，抱歉了，我下次改下

fancunhui 发表于 2011-10-14 21:27:02

ding xia louzu

lmg20066028 发表于 2011-10-19 21:16:57

有没有人有两个隧道开挖的命令流啊急需啊

zp4655958 发表于 2011-10-31 14:09:30

运行错误。。。。。。。

winloudy 发表于 2011-11-3 14:09:42

能够运行哈，运行中弹出的对话框只是提示性的，不影响分析！

guol1989 发表于 2011-11-3 15:11:10

mark一个，学习学习

auk0001 发表于 2011-12-14 14:30:52

不错哟

zuchongzhi 发表于 2012-3-15 18:26:07

NICE!非常不催哦

lancesky 发表于 2012-3-27 12:15:51

太感谢了

yangyangbjiu 发表于 2012-4-18 15:09:34

学习学习

hjhfdzs 发表于 2019-3-22 09:13:59

学习学习

xypyd 发表于 2023-9-28 11:52:13

不错的资料

查看完整版本: 浅层地下隧道3D模型