ainite 发表于 2003-9-26 16:57:57

【原创】ANSYS动力学分析的几个入门例子

本来想对ANSYS动力学部分,包括模态分析、谐响应分析、谱分析和瞬态动力学分析这几个方面,分别给出三、四个对初学者有用的例子。但是被其他的事情耽误了,先跟那几位网友道声歉。

这次贴出来的,每个部分只给了一个例子,其它的有时间了再补上。匆忙之中有些错误和问题,和感兴趣的网友们一起讨论、学习。

ainite 发表于 2003-9-26 16:59:06

回复: 【原创】ANSYS动力学分析的几个入门例子

问题一:悬臂梁受重力作用发生大变形,求其固有频率。

基本过程:
1、建模
2、静力分析
   NLGEOM,ON
   PSTRES,ON   
3、求静力解
4、开始新的求解:modal
   PSTRES,ON
   UPCOORD,1,ON修正坐标
   PSOLVE...      
5、扩展模态解
6、察看结果   

/PREP7   
ET,1,BEAM189                        !使用beam189梁单元
MPTEMP,,,,,,,,   
MPTEMP,1,0   
MPDATA,EX,1,,210e9   
MPDATA,PRXY,1,,0.3   
MPDATA,DENS,1,,7850
SECTYPE,   1, BEAM, RECT, secA, 0   !定义梁截面secA
SECOFFSET, CENT
SECDATA,0.005,0.01,0,0,0,0,0,0,0,0   
K, ,,,,                               !建模与分网
K, ,2,,,
K, ,2,1,,   
LSTR,       1,       2   
LATT,1, ,1, ,       3, ,1   
LESIZE,1, , ,20, , , , ,1
LMESH,       1   
FINISH   

/SOL                                  !静力大变形求解
ANTYPE,0
NLGEOM,1                              
PSTRES,ON                           !计及预应力效果
DK,1, , , ,0,ALL, , , , , ,   
ACEL,0,9.8,0,                         !只考虑重力作用
TIME,1   
AUTOTS,1
NSUBST,20, , ,1
KBC,0   
SOLVE   
FINISH   

/SOLUTION   
ANTYPE,2                              !进行模态求解
MSAVE,0
MODOPT,LANB,10   
MXPAND,10, , ,0                     !取前十阶模态
PSTRES,1                              !打开预应力效应
MODOPT,LANB,10,0,0, ,OFF
UPCOORD,1,ON                        !修正坐标以得到正确的应力
PSOLVE,TRIANG                         !三角化矩阵
PSOLVE,EIGLANB                        !提取特征值和特征向量
FINISH   
/SOLU   
EXPASS,1                              !扩展模态解
PSOLVE,EIGEXP   
FINISH   

/POST1   
SET,LIST                              !观察结果
FINISH

ainite 发表于 2003-9-26 17:00:47

回复: 【原创】ANSYS动力学分析的几个入门例子

问题二:循环对称结构模态分析
这是ANSYS HELP里的例子,但那个命令流似乎有些问题,下面是整理过的命令流。

基本过程:
1、建模
2、define cyclic
3、定义约束
4、求模态解
5、展开并察看结果

r1=5                                 !建模
r2=10
d1=2
nsect=24
alpha_deg=360/nsect
alpha_rad=2*acos(-1)/nsect

/prep7
csys,1
k,1,0,0,0
k,2,0,0,d1
k,3,r1,0,0
k,4,r1,0,d1
l,3,4
arotat,1,,,,,,1,2,alpha_deg/2
k,7,r2,0,0
k,8,r2,0,d1
l,7,8
arotat,5,,,,,,1,2,alpha_deg/2
arotat,2,,,,,,1,2,alpha_deg/2
arotat,6,,,,,,1,2,alpha_deg/2
a,5,6,10,9
mshkey,1
et,1,181
r,1,0.20
r,2,0.1
mp,ex,1,10e6
mp,prxy,1,0.3
mp,dens,1,1e-4
esize,0.5
asel,,,,1,4
aatt,,1
asel,,,,5
aatt,,2
allsel

CYCLIC, , , ,'CYCLIC'                !定义基本扇区
AMESH,all                            !分网
FINISH   

/SOL                                 !求模态解
ANTYPE,2
MODOPT,LANB,10   
MXPAND,10, , ,0
PSTRES,0
MODOPT,LANB,10,0,0, ,OFF
DK,5, , , ,0,UZ, , , , , ,   
SOLVE   
FINISH

/POST1   
SET,LIST
SET, , ,1, , , ,4,   
/CYCEXPAND, ,ON
PLNS,U,SUM                           !观察扩展模态
FINISH

ainite 发表于 2003-9-26 17:01:51

回复: 【原创】ANSYS动力学分析的几个入门例子

问题三:三角平台受谐波载荷作用,求结构响应
谐波载荷为作用在平台上面一点的集中力,幅值为10N,频率范围5Hz~70Hz

基本过程:
1、建模
2. 求模态解
3、用模态叠加法作谐分析
4. 观察结果

/PREP7                        !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,
MP,EX,1,210e9   
MP,PRXY,1,0.3   
MP,DENS,1,7850   
SECTYPE,   1, BEAM, RECT, secA, 0   
SECOFFSET, CENT
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0
K, ,-0.5,,,
K, ,0.5,,,   
K, ,,,1,
K, ,,1,1,   
K, ,-0.5,1,,
K, ,0.5,1,,
K, ,,,0.5,   
A,4,5,6
LSTR,       1,       5   
LSTR,       3,       4   
LSTR,       2,       6   
LSEL,S,LINE,,4,6
LATT,1,1,1, ,       7, ,1   
LSEL, , , ,ALL   
LESIZE,ALL, , ,10, , , , ,1
LMESH,4,6   
TYPE,   2   
MSHAPE,0,2D
MSHKEY,1
AMESH,1
FINISH   

/SOL                     !为了使用模态叠加法谐分析
ANTYPE,2
MODOPT,LANB,20         !先取结构前20阶模态
MXPAND,20, , ,0
MODOPT,LANB,20,0,0, ,OFF
KSEL,S,KP,,1,3
DK,ALL, , , ,0,ALL, , , , , ,   
SOLVE   
FINISH

!/POST1                  !最好事先看一下模态结果
!SET,LIST                !以了解模态频率范围
!FINISH   

/SOL                     !模态叠加法谐响应分析
ANTYPE,3
HROPT,MSUP   
HROUT,ON
HROPT,MSUP,20, ,
HROUT,ON,OFF,0   
F,177,FY,-10,            !施加10N的力在节点177的负Y方向
HARFRQ,5,70,             !载荷的强制频率范围
NSUBST,200,
KBC,1   
ALPHAD,5,   
SOLVE   
FINISH   

/POST26               !察看位移响应
FILE,,rfrq
NUMVAR,20
NSOL,2,139,U,Y,
PLVAR,2
FINISH

ainite 发表于 2003-9-26 17:04:29

回复: 【原创】ANSYS动力学分析的几个入门例子

问题四:三角平台受一地震谱激励,求应力分布和支反力

基本过程:
1、建模
2、求模态解
3、求谱解
4、扩展模态
5、模态合并
6、观察结果

/PREP7             !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,
MP,EX,1,210e9   
MP,PRXY,1,0.3   
MP,DENS,1,7850
SECTYPE,   1, BEAM, RECT, secA, 0   
SECOFFSET, CENT
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0
   
K, ,-0.5,,,
K, ,0.5,,,   
K, ,,,1,
K, ,,1,1,   
K, ,-0.5,1,,
K, ,0.5,1,,
K, ,,,0.5,   
A,4,5,6
LSTR,       1,       5   
LSTR,       3,       4   
LSTR,       2,       6   
LSEL,S,LINE,,4,6
LATT,1,1,1, ,       7, ,1   
LSEL, , , ,ALL
LESIZE,ALL, , ,10, , , , ,1
LMESH,4,6   
TYPE,   2   
MSHAPE,0,2D
MSHKEY,1
AMESH,1
FINISH   

/SOL            !取前十阶模态
ANTYPE,2
MODOPT,LANB,10   
KSEL,S,KP,,1,3
DK,ALL, , , ,0,ALL, , , , , ,   
SOLVE   
FINISH   

/SOL               !谱分析
ANTYPE,8
SPOPT,SPRS,10,1
SVTYP,3
SED,0,1,0,         !给出激励方向
FREQ,0.25,1.34,6.73,14.6,28.9,0,0,0,0    !激励谱
SV,0,0.00073,0.00016,0.00034,0.00034,0.00052,   
SOLVE   
FINISH   

/SOL                  !扩展模态
ANTYPE,2
EXPASS,1
MXPAND,10,0,0,1,0.001,   
SOLVE   
FINISH   

/SOL               !模态合并
ANTYPE,8
SRSS,0.001,DISP
SOLVE   

/POST1            !观察结果
SET,LIST
/INPUT,,mcom
PRRSOL,F
FINISH

ainite 发表于 2003-9-26 17:05:31

回复: 【原创】ANSYS动力学分析的几个入门例子

问题五:三角平台受时程载荷作用,求应力分布和变形过程

基本过程:
1、建模
2. 施加随时间变化载荷,定义载荷步
3、求解
4. 在POST1和POST26中观察结果

/PREP7                           !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,
MP,EX,1,210e9   
MP,PRXY,1,0.3   
MP,DENS,1,7850   
SECTYPE,   1, BEAM, RECT, secA, 0   
SECOFFSET, CENT
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0
K, ,-0.5,,,
K, ,0.5,,,   
K, ,,,1,
K, ,,1,1,   
K, ,-0.5,1,,
K, ,0.5,1,,
K, ,,,0.5,   
A,4,5,6
LSTR,       1,       5   
LSTR,       3,       4   
LSTR,       2,       6   
LSEL,S,LINE,,4,6
LATT,1,1,1, ,       7, ,1   
LSEL, , , ,ALL   
LESIZE,ALL, , ,10, , , , ,1
LMESH,4,6   
TYPE,   2   
MSHAPE,0,2D
MSHKEY,1
AMESH,1
FINISH   

/SOL                           
ANTYPE,4
TRNOPT,FULL                     !完全法瞬态分析
KSEL,S,KP,,1,3
DK,ALL, , , ,0,ALL, , , , , ,   
OUTRES,ALL,1
ALPHAD,5,                     !α阻尼

TIME,2                        !定义载荷曲线
AUTOTS,1
NSUBST,50, , ,1      
KBC,0   
SFA,ALL,1,PRES,500
LSWRITE,1,                     
   
TIME,3   
LSWRITE,2,   

TIME,4
SFA,ALL,1,PRES,150
KBC,1   
LSWRITE,3,   

TIME,5
SFA,ALL,1,PRES,
LSWRITE,4,   

LSSOLVE,1,4,1,                  !求解
FINISH   
   
/POST26                         !观察变形随时间的变化
NSOL,2,177,U,Y,uyy   
PLVAR,2
FINISH

bigmao 发表于 2003-10-16 14:36:18

回复: 【原创】ANSYS动力学分析的几个入门例子

高手,请问你的第四个例子(谱分析)中可以在后处理中画出模型上某点的位移-频率曲线(好象是响应的位移谱吧)么?速度谱和加速度谱又能否得到?

ainite 发表于 2003-10-17 09:57:37

回复: 回复: 【原创】ANSYS动力学分析的几个入门例子

bigmao wrote:
高手,请问你的第四个例子(谱分析)中可以在后处理中画出模型上某点的位移-频率曲线(好象是响应的位移谱吧)么?速度谱和加速度谱又能否得到?

在进行模态合并时,可选择合并结构总体响应的结果,包括总的位移、总的速度、总的加速度
Solution->Load Step Opts->Spectrum->Single Point->Mode Combin

bigmao 发表于 2003-10-22 14:23:32

回复: 回复: 回复: 【原创】ANSYS动力学分析的几个入门例子

ainite wrote:
在进行模态合并时,可选择合并结构总体响应的结果,包括总的位移、总的速度、总的加速度
Solution->Load Step Opts->Spectrum->Single Point->Mode Combin
不好意思,我可能没把问题说清楚。我的意思是问在POST26中能否选出模型中的一个节点,画出该节点的加速度随频率变化的趋势曲线图,如我的附件中所示的图形,其中那条直线是输入的加速度谱,而那个曲线就是一个板中点的响应加速度谱。

ainite 发表于 2003-10-24 14:40:12

回复: 回复: 回复: 回复: 【原创】ANSYS动力学分析的几个入门例子

bigmao wrote:
不好意思,我可能没把问题说清楚。我的意思是问在POST26中能否选出模型中的一个节点,画出该节点的加速度随频率变化的趋势曲线图,如我的附件中所示的图形,其中那条直线是输入的加速度谱,而那个曲线就是一个板中点的响应加速度谱。

这样的结果曲线我没做过,但是在随机振动分析PSD中,可以在求解前用PSDRES命令设置输出数据,可以计算位移解、速度解、加速度解。然后在后处理中观察它们,你不妨试试。

chuanxinyi 发表于 2003-10-29 10:44:04

bigmao 发表于 2003-10-29 18:16:33

回复: 回复: 回复: 回复: 回复: 【原创】ANSYS动力学分析的几个入门例子

ainite wrote:
这样的结果曲线我没做过,但是在随机振动分析PSD中,可以在求解前用PSDRES命令设置输出数据,可以计算位移解、速度解、加速度解。然后在后处理中观察它们,你不妨试试。
在随机振动分析PSD中可以输入加速度-频率关系吗?好像要输入功率谱密度的,单位不对,但我在ANSYS指南上看到一个例题好像输入的就是加速度(记不清了,明天我把那个例题贴出来),我搞不清PSD分析的原理,不知高手能否指点一二。我那个曲线是振动实验输出来的。

bobo 发表于 2003-11-19 17:54:46

回复: 【原创】ANSYS动力学分析的几个入门例子

One question, if I perform '问题三:三角平台受谐波载荷作用,求结构响应
谐波载荷为作用在平台上面一点的集中力,幅值为10N,频率范围5Hz~70Hz
'the value obtained in frequency domain is the true value or just an amplitude? Thanks!!

kuanglong 发表于 2003-11-23 17:38:29

回复: 【原创】ANSYS动力学分析的几个入门例子

ok

lornalong7909 发表于 2003-11-24 11:07:55

回复: 【原创】ANSYS动力学分析的几个入门例子

谢谢!很有用哦!!!

wpwp2002 发表于 2003-11-25 18:41:16

回复: 【原创】ANSYS动力学分析的几个入门例子

谢谢了 不过我对ansys的命令不熟,能不能改成用GUI方式的,不要APDL的?谢谢了!!

genius05 发表于 2003-11-27 11:37:30

回复: 【原创】ANSYS动力学分析的几个入门例子

请教各为大师
不知 ansys可不以 将
时域转换为频域
或频时域转换为时域的结构响应
小弟想知道其对应知之结果
小弟初学ANSYS动力学分析
正努力学习中请多指教
谢谢

zhaoht1860 发表于 2003-11-30 20:28:37

回复: 【原创】ANSYS动力学分析的几个入门例子

很好,谢谢。我正在做一个大坝的地震动力分析,考虑动水压力,请问有没有关于动力分析书籍及如何加质量单元的资料,还有就是有没有可以考虑开列的平面单元,相对于三维的solid65

主战坦克 发表于 2003-12-4 21:47:19

回复: 【原创】ANSYS动力学分析的几个入门例子

我喜欢,我要下载。谢谢ainite

guofeng23 发表于 2003-12-7 15:03:18

回复: 【原创】ANSYS动力学分析的几个入门例子

谢谢,你是大侠,向您学习
页: [1] 2 3 4 5 6 7 8 9
查看完整版本: 【原创】ANSYS动力学分析的几个入门例子