SimWe仿真论坛 » C06：ANSYS--实例赏评 » 钢管的弹性屈曲荷载(即特征值屈曲)

pengfm 发表于 2005-3-6 07:57

钢管的弹性屈曲荷载(即特征值屈曲)

一长度为4.0m、内径为100mm、外径为110mm的钢管，两端铰支，根据欧拉公式，其弹性屈曲荷载应为295110，但采用ANSYS计算出来的结果为16627937.2，与理论值相差二个数量级，请问是何原因？命令流见下：
fini
/clear

/prep7
! 参数设置

Es=2.06e5 ! 钢材的弹性模量

ET,1,PLANE42
KEYOPT,1,3,1 ! 轴对称单元

MP,ex,1,Es ! 钢材的材料属性
mp,prxy,1,0.3

k,1,50
k,2,55
k,3,55,2000
k,4,50,2000

a,1,2,3,4

LESIZE,1, , ,1, , , , ,0
LESIZE,4, , ,200, , , , ,0

MSHAPE,0,2D
MSHKEY,1
amesh,1,2

FINISH
/SOLU
PSTRES,ON ! CALCULATE PRESTRESS EFFECTS
allsel,all
DL,1, ,UY,

nsel,s,loc,y,2000,2000
*get,numld,node,,count
F,all,FY,-1/numld
OUTPR,,1
allsel,all
SOLVE
FINISH

/SOLU
ANTYPE,BUCKLE ! BUCKLING ANALYSIS
BUCOPT,SUBSP,1 ! USE SUBSPACE SOLUTION METHOD, EXTRACT 1 MODE
MXPAND,1 ! EXPAND 1 MODE SHAPE
SOLVE

*GET,FCR,MODE,1,FREQ

pengfm 发表于 2005-3-8 07:09

Re:钢管的弹性屈曲荷载(即特征值屈曲)

各位朋友：
     大家好!请问上面荷载的施加方法对吗？提取的FCR是否就为屈曲荷载，与理论值为何差别如此之大呢？

lzlan100 发表于 2005-7-14 16:38

Re:钢管的弹性屈曲荷载(即特征值屈曲)

你为什么用这种单元建模啊，看看我下面的命令流形式：
fini
/clear
/filnam,buckling
/prep7
! 参数设置

Es=2.06e5 ! 钢材的弹性模量

ET,1,beam188
!KEYOPT,1,3,1 ! 轴对称单元

MP,ex,1,Es   ! 钢材的材料属性
mp,prxy,1,0.3

sectype,1,beam,ctube
secdata,50,55,10

k,1,0
k,2,0,4000
k,3,1,1

l,1,2
lesize,all,20
latt,1,,1,,3,,1
lmesh,all

FINISH
/SOLU
PSTRES,ON ! CALCULATE PRESTRESS EFFECTS
allsel,all
Dk,1,Ux,
dk,1,uy,
dk,1,uz,
dk,2,ux,
dk,2,uz,

Fk,2,FY,-1
allsel,all
OUTPR,,1

SOLVE
FINISH

/SOLU
ANTYPE,BUCKLE   ! BUCKLING ANALYSIS
BUCOPT,SUBSP,1  ! USE SUBSPACE SOLUTION METHOD, EXTRACT 1 MODE
MXPAND,1        ! EXPAND 1 MODE SHAPE
SOLVE

*GET,FCR,MODE,1,FREQ
最后得到的结果是：FCR = 287978.612
误差为：2.4％
可接受！

lzlan100 发表于 2005-7-14 16:39

Re:钢管的弹性屈曲荷载(即特征值屈曲)

呵呵，老大，应该给我加上一分吧！

liu3806881 发表于 2005-7-18 16:33

Re:钢管的弹性屈曲荷载(即特征值屈曲)

!KEYOPT,1,3,1 ! 轴对称单元
与
k,1,50
k,2,55
k,3,55,2000
k,4,50,2000
不对应，

改为
k,1,50
k,2,55
k,3,55,4000
k,4,50,4000
这是我求出来的值：
FCR      = 30586573.9
误差：    3.648166

xianshu-j 发表于 2005-7-25 03:24

Re:钢管的弹性屈曲荷载(即特征值屈曲)

因为约束加错了。你使用了钢管的一半建模，所以对模型的一端应该施加完全约束。将你的DL,1, ,UY, 命令改为：

1）dl,1,,all,0

或者

2）nsel,s,loc,y,0
    d,all,all
    allsel,all

即可得到满意的结果。

shimly521 发表于 2007-2-7 11:11

钢材的弹性模量为什么那么小啊???????????????????????

daxia_2004 发表于 2007-7-31 18:02

这个问题我也遇到了，采用不同建模方法结果不一致，好象后面两位老兄改进后误差更大了，真不知道怎么回事

wangqingniu 发表于 2008-4-10 16:42

轴对称单元
为什么要取42单元呢？183会不会好点啊
比如：et,1,183,,,1

[[i] 本帖最后由 wangqingniu 于 2008-4-10 17:37 编辑 [/i]]

wangqingniu 发表于 2008-4-10 16:44

还有就是为什么
ANTYPE,BUCKLE   ! BUCKLING ANALYSIS
BUCOPT,SUBSP,1  ! USE SUBSPACE SOLUTION METHOD, EXTRACT 1 MODE
MXPAND,1        ! EXPAND 1 MODE SHAPE
SOLVE 中选择SUBSP，而不是lanb？
高手给个解答吧，困扰好久了

shimly521 发表于 2008-4-14 11:49

谢谢分享，，，，

查看完整版本: 钢管的弹性屈曲荷载(即特征值屈曲)