SimWe仿真论坛 » C06：ANSYS--实例赏评 » ansys模拟岩石隧道开挖平面弹塑性分析

licaifeng 发表于 2006-4-20 23:32

ansys模拟岩石隧道开挖平面弹塑性分析

ansys模拟岩石隧道开挖平面弹塑性分析

/prep7

!开挖土体1
ET,1,PLANE42
KEYOPT,1,3,2
!开挖土体2
ET,2,PLANE42
KEYOPT,2,3,2
!加固土体1
ET,3,PLANE42
KEYOPT,3,3,2
!加固土体2
ET,4,PLANE42
KEYOPT,4,3,2
!第一层围岩土体
ET,5,PLANE42
KEYOPT,5,3,2
!围岩土体
ET,6,PLANE42
KEYOPT,6,3,2


!初期支护1
ET,7,BEAM3
R,1,0.15,0.15*0.15*0.15/12,0.15,0,0,0,  
!初期支护2
ET,8,BEAM3  
R,2,0.15,0.15*0.15*0.15/12,0.15,0,0,0,
!临时支护3
ET,9,BEAM3  
R,3,0.15,0.15*0.15*0.15/12,0.15,0,0,0,
!围岩材料属性
MP,EX,1,14.75e9
MP,PRXY,1,0.31
MP,DENS,1,2060
TB,DP,1
TBDATA,1,0.7e6,38.5,0   
!加固土体材料属性
MP,EX,2,14.751e9
MP,PRXY,2,0.3
MP,DENS,2,2060
TB,DP,2
TBDATA,1,0.974e6,38.5,0
!初期支护材料属性
MP,EX,3,21e9
MP,PRXY,3,0.2
MP,DENS,3,2200

CYL4, 0,0 ,2
CYL4, 0,0 ,3.3  
RECTNG,-20,20,-16,10,
RECTNG,-20,20,10,14,
  
AOVLAP,ALL,
NUMMRG,KP, , , ,LOW
NUMCMP,KP   
NUMCMP,LINE
NUMCMP,AREA

LSTR,5,7
ASEL,S,,,1
ASEL,A,,,3
LSEL,S,,,16
ASBL,ALL,ALL, ,DELETE,DELETE  
allsel,all

NUMMRG,KP, , , ,LOW
NUMCMP,KP   
NUMCMP,LINE
NUMCMP,AREA

!开挖1材料属性赋予
ASEL,S , , , 3
AATT,1, 1,1,,  
!开挖2材料属性赋予
ASEL, S, , , 4
AATT,1,1,2,,   
!加固区土体1材料属性赋予
ASEL, S, , , 5
AATT,1,1,3,,

!加固区土体2材料属性赋予
ASEL,S , , , 6
AATT,1,1,4,,  
!开挖周围土体1(表层土体）材料属性赋予
ASEL,S , , , 1
AATT,1,1,5,,  
!开挖周围土体2材料属性赋予
ASEL,S , , , 2
AATT,1,1,6,,
!上台阶初期支护
LSEL,S,,,1,2
LATT,3,1,7, , , ,
LSEL,S,,,16
LATT,3,3,9, , , ,  

!下台阶初期支护
LSEL,S,,,3,4
LATT,3,2,8, , , ,


LSEL,S,,,1,2
LESIZE,all, , ,10, , , , ,0
LSEL,S,,,16
LESIZE,all, , ,12, , , , ,0
LSEL,S,,,3,4
LESIZE,all, , ,10, , , , ,0
LSEL,S,,,17,18
LESIZE,all, , ,4, , , , ,0
LSEL,S,,,5,8
LESIZE,all, , ,10, , , , ,0
LSEL,S,,,10,12,2
LESIZE,all, , ,25, , , , ,0

LSEL,S,,,9,13,2
LESIZE,all, , ,45, , , , ,0

LSEL,S,,,14,15
LESIZE,all, , ,3, , , , ,0

ALLSEL,ALL

!!!划分上下台阶开挖土体
ASEL,S,TYPE,,1,2
MSHKEY,0
AMESH,ALL,

!!!划分加固区1网格
!!将1、2和5、6号线分别连接成一条线，以便于面的映射网格划分
LCCAT,1,2
LCCAT,5,6
!!划分网格
ASEL,S,TYPE,,3
MSHKEY,1
AMESH,ALL,

!!!划分加固区2
!!将3、4和7、8号线分别连接成一条线，
LCCAT,3,4
LCCAT,7,8
!!划分网格
ASEL,S,TYPE,,4
MSHKEY,1
AMESH,ALL,

!!!删除连接线
ALLSEL,ALL
LSEL,S,LCCA
LDELE,ALL
ALLSEL,ALL

ASEL,S,TYPE,,5,6
MSHKEY,0
AMESH,ALL,

LSEL,S,TYPE,,7,9
LMESH,ALL

NUMMRG,NODE, , , ,LOW   
NUMMRG,ELEM, , , ,LOW  
NUMCMP,NODE
NUMCMP,ELEM
FINISH

/SOLU
ANTYPE,STATIC,NEW
NLGEOM,ON
NROPT,FULL
SSTIF,ON

!施加边界条件
LSEL,S, , ,10,12,2
LSEL,A,,,14,15
DL,ALL, ,UX,0
LSEL,S, , ,9
DL,ALL, ,UY,0
ALLSEL,ALL
ACEL,0,10,0

TIME,1
DELTIM,0.025,0.0001,0.05
AUTOTS,ON
LNSRCH,ON
PRED,ON

!初始地应力计算
ESEL,S,TYPE,,7,9
ekill,all  
allsel,all
solve

!!上台阶开挖模拟
ESEL,S,TYPE,,3
MPCHG,2,ALL,
ESEL,S,TYPE,,1
EKILL,ALL

ESEL,S,TYPE,,7,9,2
EALIVE,ALL
ALLSEL,ALL
TIME,2
SOLVE

!!下台阶开挖模拟
ESEL,S,TYPE,,2,9,7
EKILL,ALL

ESEL,S,TYPE,,8
EALIVE,ALL
ALLSEL,ALL
TIME,3
SOLVE
FINISH
save


/post1
/UDOC,1,CNTR,RIGH
ESEL,S,live
set,last,last
*DO,I,1,3
lcdef,I,I,last
*ENDDO
lcase,2
lcoper,sub,1

倚天剑 发表于 2006-5-9 16:13

好啊

lily_bjtu2004 发表于 2006-5-11 16:42

谢谢！！！

谢谢

wufan314 发表于 2006-6-2 16:03

谢谢搂住分享

zlh98111411 发表于 2006-8-27 20:57

支持楼主奉献精神！

qingq 发表于 2008-7-10 17:25

都这样了

楼主大公无私让我心里久久不能平静
菜鸟一名，不知道能否得楼主指导！752765159

qingq 发表于 2008-7-13 09:24

louzhu

我发现上下台阶开挖分步不释放应力吗？

sxman 发表于 2008-7-19 14:13

关于应力释放问题，本例显然是假定了应力全部释放，这在围岩状况较好的情况下，可以这样假定。本例仅是一个简化的实例，如果想进一步了解，应该看看相关专业的参考书籍，比如如何考虑应力释放问题，加固范围、开挖方式等等。（菜鸟留言）

qingq 发表于 2008-7-24 11:06

好

能推荐哈嘛！！！比如相关的问题
希望不吝赐教

查看完整版本: ansys模拟岩石隧道开挖平面弹塑性分析