小超 发表于 2007-9-4 22:48:08

请教:建了一个涡流检测的模型,一直调不对

这是用solid97和circuit124建立的场路耦合模型,模式是一个管道的1/4模型,管壁上设置有缺陷,管内有一个激励线圈和一个检测线圈,以前也发过,又做过一些修改,不过所得到的检测线圈上的感应电压一直不对,和正确的差了3个数量级,应该说把错误的地方指出来请教大家的,不过调了2个星期,实在找不出是哪里的错误,只能先把命令流帖上来了,有哪里标注不清楚的,我再添加,劳烦有经验的朋友帮帮忙,给我提点建议。

/TITLE,3D TRANSIENT ANALYSIS OF TUBE DEFECTS
KEYW,MAGNOD,1                !指定磁场分析

/PREP7
ET,1,SOLID97,0                   !定义空气单元类型
ET,2,SOLID97,3                   !定义线圈单元类型
ET,3,SOLID97,1,0               !定义管道单元类型,考虑涡流效应

!定义材料属性
MP,MURX,1,1                !定义空气材料属性
MP,MURX,2,1                !定义线圈材料属性
MP,RSVX,2,1.724E-8
MP,MURX,3,100            !定义管道材料属性
MP,RSVX,3,2E-7
!定义分析参数
TUBE_L=300/1000                                                    ! 管道长度
TUBE_R_IN=25/1000                                                 !管道内径
TUBE_R_OUT=30/1000                                              !管道外径
TUBE_T=TUBE_R_OUT-TUBE_R_IN
COIL_E_N=300                                                      !激励线圈匝数
COIL_E_P=60/1000                                                !激励线圈轴向位置
COIL_E_L=40/1000                                                !激励线圈长度
COIL_E_R_IN=5.2/1000                                          !激励线圈内径
COIL_E_R_OUT=10/1000                                           !激励线圈外径
COIL_E_T=COIL_E_R_OUT-COIL_E_R_IN
COIL_E_AREA=COIL_E_T*COIL_E_L
COIL_D_N=1200                                                      !检测线圈
COIL_D_P=COIL_E_P+COIL_E_L+4*TUBE_R_IN
COIL_D_L=2.4/1000
COIL_D_R_IN=1.2/1000
COIL_D_R_OUT=3/1000
COIL_D_T=COIL_D_R_OUT-COIL_D_R_IN
COIL_D_AREA=COIL_D_T*COIL_D_L
INTERVAL=3/1000                                                   !检测线圈距管壁距离
DEFECT_P=COIL_D_P-10/1000                                    !缺陷位置
DEFECT_L=20/1000                                                   !缺陷长度
DEFECT_T=2/1000                                                    !缺陷深度
DEFECT_W=2.5/1000                                                !缺陷半宽度
AIRW1_T=20/1000                                                   !管外内层空气厚度
AIRW2_T=200/1000                                                !管外外层空气厚度
PI=3.1415926
P=1.724E-8
COIL_E_RES=36                                                       !激励线圈直流电阻

!定义线圈实常数
R,1,COIL_E_AREA,COIL_E_N,PI*(COIL_E_R_OUT**2-COIL_E_R_IN**2)/4*COIL_E_L,0,1,0,
RMORE,4,2*PI*P*(COIL_E_R_OUT+COIL_E_R_IN)/2*(COIL_E_N**2)/(COIL_E_AREA*COIL_E_RES),            
                                                            !激励线圈实常数
R,2,COIL_D_AREA,COIL_D_N,PI*(COIL_D_R_OUT**2-COIL_D_R_IN**2)*COIL_D_L,0,1,0,
RMORE,1,PI*((0.06/1000/2)**2)*COIL_D_N/COIL_D_AREA,                !检测线圈实常数

!生成几何模型
LOCAL,11,1,0,0,0, , , ,1,1,                                 !建立局部11号坐标系,定义激励线圈
LOCAL,12,1,0,0,0,45, , ,1,1,                                  !建立局部12号坐标系,定义缺陷
LOCAL,13,1,(TUBE_R_IN-INTERVAL-COIL_D_R_OUT)/1.414,(TUBE_R_IN-INTERVAL-
COIL_D_R_OUT)/1.414,COIL_D_P, , , ,1,1,      !建立局部13号坐标系,定义检测线圈
WPCSYS,-1,13,          !移动工作平面到13号局部坐标系
CSYS,13
CYLIND,COIL_D_R_OUT,COIL_D_R_IN,O,COIL_D_L,0,360                                  !检测线圈
CYLIND,COIL_D_R_IN,0,0,COIL_D_L,0,360,                                          !空气N3
WPCSYS,-1,11         !移动工作平面到11号坐标系
CSYS,11
CYLIND,COIL_E_R_OUT,COIL_E_R_IN,-1.5*TUBE_L,2.5*TUBE_L,0,90,                  !激励线圈
WPCSYS,-1,0         !移动工作平面到0号坐标系
CSYS,0
CYLIND,TUBE_R_IN,0,-1.5*TUBE_L,2.5*TUBE_L,0,90,                                 !空气N
CYLIND,TUBE_R_OUT+AIRW1_T,TUBE_R_OUT,-1.5*TUBE_L,2.5*TUBE_L,0,90,               !空气W1
CYLIND,AIRW2_T,0,-1.5*TUBE_L,2.5*TUBE_L,0,90,                                 !空气W2
CYLIND,TUBE_R_OUT,TUBE_R_IN,-1.5*TUBE_L,2.5*TUBE_L,0,90,                        !管道
WPCSYS,-1,12,          !移动工作平面到12号局部坐标系
CSYS,12
BLOCK,TUBE_R_IN+DEFECT_T,TUBE_R_IN-0.5/1000,-DEFECT_W,DEFECT_W,DEFECT_P,DEFECT_P+DEFECT_L,      
!缺陷
WPCSYS,-1,0            !移动工作平面到0号坐标系
CSYS,0
VSBV,8,4,,DELETE,KEEP,
ALLSEL,ALL
VOVLAP,ALL       !搭接
NUMCMP,ALL       !压缩编号
/PNUM,VOLU,1   !打开体积编号
!体积编号:coil_d:1 coil_e:2defect:5airn2:4airn1:6/9tube:8 airw1:3airw2:7
VSBW,ALL,,DELE          !为了划分六面体网格切分模型
WPOFFS,0,0,TUBE_L
VSBW,ALL,,DELE
WPOFFS,0,0,COIL_E_P-TUBE_L
VSBW,ALL,,DELE
WPOFFS,0,0,COIL_E_L
VSBW,ALL,,DELE
WPOFFS,0,0,DEFECT_P-COIL_E_P-COIL_E_L
VSBW,ALL,,DELE
WPOFFS,0,0,DEFECT_L
VSBW,ALL,,DELE
ALLSEL,ALL
VGLUE,ALL      !粘帖
NUMCMP,ALL       !压缩编号
!体积编号:coil_d:1 coil_e:24 tube:27/32/39/44/43/
VSEL,S,VOLU,,24,            !给激励线圈赋予材料特性
VATT,2,1,2,11
VSEL,S,VOLU,,1,             !给检测线圈赋予材料特性
VATT,2,2,2,13
VSEL,S,VOLU,,27             !给管道赋予材料特性            
VSEL,A,VOLU,,32
VSEL,A,VOLU,,39
VSEL,A,VOLU,,43,44
VATT,3,1,3,0
ALLSEL,ALL
LSEL,S,,,107          !中间部分轴向
LSEL,A,,,148
LSEL,A,,,156
LSEL,A,,,185
LSEL,A,,,154
LSEL,A,,,167,168
LSEL,A,,,195,196
LSEL,A,,,225,226
LSEL,A,,,255,256
LSEL,A,,,240
LSEL,A,,,242
LSEL,A,,,170
LSEL,A,,,204
LSEL,A,,,229
LSEL,A,,,259
LSEL,A,,,250
LESIZE,ALL,5/1000
LSEL,S,,,87         !两边部分轴向
LSEL,A,,,116
LSEL,A,,,103
LSEL,A,,,111
LSEL,A,,,36
LSEL,A,,,139
LSEL,A,,,126
LSEL,A,,,134
LESIZE,ALL,40/1000   
LSEL,S,,,83         !管内径向
LSEL,A,,,94
LSEL,A,,,121
LSEL,A,,,30
LSEL,A,,,53
LSEL,A,,,144
LESIZE,ALL,4/1000
LSEL,S,,,119         !管壁径向
LSEL,A,,,142
LESIZE,ALL,2/1000
LSEL,S,,,104         !管外1径向
LSEL,A,,,129
LESIZE,ALL,5/1000
LSEL,S,,,114         !管外2径向
LSEL,A,,,137
LSEL,A,,,61
LSEL,A,,,65
LESIZE,ALL,30/1000
LSEL,S,,,56         !缺陷宽度
LSEL,A,,,59
LSEL,A,,,68
LSEL,A,,,71
LESIZE,ALL,6/1000
LSEL,S,,,25         !周向9份
LSEL,A,,,44
LSEL,A,,,51
LSEL,A,,,24
LSEL,A,,,39
LSEL,A,,,50
LESIZE,ALL,,,9
ALLSEL,ALL
VSWEEP,ALL
MSHAPE,1,3D,
MSHKEY,0
ESIZE,5/1000
VMESH,45                     !自由划分检测线圈周围空气,体积号45
ALLSEL,ALL
SAVE,3d_t_id_o_4-0_Model.db    !保存网格单元数据到文件
FINISH

!定义电路模型及其与有限元模型的连接
/PREP7
CSYS,0         !激活0号坐标系
N,100000,-0.2,0.2,0
N,100001,-0.2,0.15,0
R,3,0,18,0.0005,0.0001,0.0001,0.0023,
RMORE,0.025,
ET,4,CIRCU124,4,2         !独立脉冲电压源
TYPE,4
REAL,3
N,100002,-0.18,0.1,0
E,100000,100001,100002
R,4,1
ET,5,CIRCU124,5,0         !电路耦合激励线圈
TYPE,5
REAL,4
VSEL,S,VOLU,,24
NSLV,S,0                  !选择激励线圈体积内部节点
*GET,NE,NODE,,NUM,MIN   !选择其中节点号最小的节点
E,100000,100001,NE

N,100003,-0.2,0.1,0
N,100004,-0.2,0.05,0
R,5,1E10
ET,6,CIRCU124,0,0         !检测线圈连接10G ohm电阻
TYPE,6
REAL,5
E,100003,100004
R,6,1
ET,7,CIRCU124,5,0         !电路耦合检测线圈
TYPE,7
REAL,6
VSEL,S,VOLU,,1
NSLV,S,0                  !选择检测线圈体积内部节点
*GET,ND,NODE,,NUM,MIN   !选择其中节点号最小的节点
E,100003,100004,ND
NSEL,S,NODE,,100001
D,100001,VOLT,0         !电路施加接地边界条件
NSEL,S,NODE,,100004
D,100004,VOLT,0
ALLSEL,ALL
FINISH
/SOLU
ANTYP,TRANS               !瞬态分析
TRNOPT,FULL
CSYS,0
!耦合线圈上的自由度
VSEL,S,VOLU,,24
ESLV,S
NSLE,S
CP,1,CURR,ALL             !耦合电流自由度
CP,2,EMF,ALL            !耦合电动势自由度
CM,COIL_E,ELEM            !将激励线圈定义为一个组件
VSEL,S,,,1
ESLV,S
NSLE,S
CP,3,CURR,ALL             !耦合电流自由度
CP,4,EMF,ALL            !耦合电动势自由度
CM,COIL_D,ELEM            !将检测线圈定义为一个组件
ALLSEL,ALL

ASEL,S,EXT,    !外表面设置平行边界条件
DA,ALL,ASYM


!管壁对称面上设置电压自由度为0,模拟管壁短路条件
ASEL,S,,,116
ASEL,A,,,136
ASEL,A,,,162
ASEL,A,,,186
ASEL,A,,,181
NSLA,S,1
D,ALL,VOLT,0
CP,5,VOLT,ALL

ASEL,S,,,117
ASEL,A,,,137
ASEL,A,,,163
ASEL,A,,,187
ASEL,A,,,182
NSLA,S,1
CP,6,VOLT,ALL
D,ALL,VOLT,0
ALLSEL,ALL

OUTRES,ALL,ALL,         !求解结果输出控制
TIME,0.01                !设置保持载荷终止时间10ms,周期是25ms
AUTOTS,0                  !关闭自动步长
DELTIM,2E-005             !设置保持载荷步长2E-005s
SOLVE
FINISH
/POST26
NSOL,2,NE,CURR,,COIL_E_CURRENT
NSOL,3,ND,EMF,,COIL_D_EMF
PLVAR,2
PLVAR,3
SAVE,3d_t_id_o_2-0_Resu.db   !保存计算结果到文件

[ 本帖最后由 小超 于 2007-9-6 17:28 编辑 ]

ponderadams 发表于 2007-9-5 07:37:06

数量级的问题,以前我也遇到过,可能是实常数那里引起的,好好检查一下

小超 发表于 2007-9-5 10:53:28

图形也不太对,一直怀疑是边界条件的问题

ponderadams 发表于 2007-9-5 10:55:48

恩,也会有很大的关系

小超 发表于 2007-9-5 10:59:38

调了很久了,就是不行,谁有经验,请大家帮忙看看,哪里是不是设置错了

lql_411 发表于 2007-9-5 14:48:15

回复 #1 小超 的帖子

检测线圈的电导率方面设置和外围的空气

小超 发表于 2007-9-5 15:06:05

lql_411说的什么意思,没看懂
把我错误的结果帖上来吧,大家帮忙分析下,第一个是激励的电流波形,第二个是感应电压的波形,明显不符合激励电流、磁场和感应电压的变化规律


[ 本帖最后由 小超 于 2007-9-5 16:00 编辑 ]

小超 发表于 2007-9-5 22:31:25

我又把靠近管壁内侧的小检测线圈换成了轴心位置的大检测线圈,边界条件设置不变,好像结果就正确着,是不是因为小检测线圈的局部坐标系的关系啊,有人知道是为什么吗,关系到毕业,请大家帮忙

小超 发表于 2007-9-6 17:43:11

以下的结果是我用2d的plane53单元做的,模型和上面的就是管道的内径和方波的重复频率不一样,其他都差不多,这个结果是正确的,可是用solid97那个模型就是得不到这样的结果,把正确的结果帖出来,供大家参考

如果大家还对模型里哪些不清楚,我很愿意和大家讨论,多谢大家的帮助!

小超 发表于 2007-9-8 16:31:31

请高手帮忙看看吧,快急出毛病了

icemman 发表于 2007-9-18 03:39:38

这是我运行的结果,包括有缺陷和无缺陷的情况,好象和你的要求比较接近。
为了省时间,载荷步长改为5E-004s,其余都没动。
模型中有一个可能导致误差的地方是你没有考虑钢管-空气的边界。另外我觉得最好用infin111代替平行边界,尽管在这个分析中似乎没什么区别。
还有你是否可以考虑用AC激励,harmonic比transient高效多了,通过比较检测信号一样可以知道是否有缺陷。
有缺陷:

无缺陷:


[ 本帖最后由 icemman 于 2007-9-18 04:57 编辑 ]

icemman 发表于 2007-9-18 22:42:21

再扩展一下这个问题,我也在做一个类似的项目,是交变激励的位置传感器。只是激励线圈和检测线圈在同一块PCB上位置很接近,除了磁链之外电场也会互相影响。用ANSOFT检查电场有4%的影响。
公司现在只有EMAG license,而且由于涉及到涡流和电路耦合,只能用SOLID97,但SOLID97无法分析电场。
北极熊甲老大能否给个建议可以怎么做?

[ 本帖最后由 icemman 于 2007-9-18 22:47 编辑 ]

tshlid 发表于 2007-9-19 18:13:16

回复 #1 小超 的帖子

CYLIND,COIL_E_R_OUT,COIL_E_R_IN,-1.5*TUBE_L,2.5*TUBE_L,0,90,                  !激励线圈
这句话是不是写错了?激励线圈怎么和管道一样长了?

小超 发表于 2007-9-22 20:46:01

谢谢各位
那个没有写错,是为了划分六面体网格,才加长的,材料属性指定其中一段即可

ponderadams 发表于 2007-11-23 09:30:36

我看了一下,好像实常数没有什么问题

我看程序,整体感觉就是,划分网格的时候选面和线用号来选取,建议换一种方法选,可能错误就会出来,因为这样万一有错误是检查不出来的

[ 本帖最后由 ponderadams 于 2007-11-23 09:40 编辑 ]

shiyingwang 发表于 2007-11-24 11:19:51

你的边界条件设置有没有问题呢?(我是新手,只是建议看一下边界条件)

高贵的点点滴滴 发表于 2008-3-9 10:33:58

问题是由于自由度的选取问题(V+AZ?还是AZ)斑竹的那个置顶帖中有。http://www.simwe.com/forum/thread-774283-4-1.html

AZ和AZ+Volt的区别(短路与开路的区别)? 开路?开在哪个方向上?

lifangqi 发表于 2008-3-9 18:06:25

能把你二维的命令贴出来吗

fossiler 发表于 2008-5-27 10:36:19

我只做到0.0035秒而且延时时间设定的为0.0001秒

liuxianghong 发表于 2008-7-15 16:52:56

很想联系楼主
电话:13516423053
正在研究ANSYS
页: [1] 2 3
查看完整版本: 请教:建了一个涡流检测的模型,一直调不对