向高手求助：钢梁计算，PRERR命令的SEPC值很高，自适应分网也不行
现有一桥梁顶升用扁担梁，构造为顶、底、腹板及横隔板，均采用Q345钢板，顶板受均布面荷载作用。计算下来SEPC高达36%，改用自自适应分网也无法降下来。感觉不是一个复杂结构，可就是求解不出来，束手无策，请各位高手不吝赐教！命令流如下：finish
/cle
/FILNAME, Sustaining_20080704_10:05, ON
/View,all,1,1,1
/VUP,all,Z
/ESHAPE,1,1
!units:kN,mm,kg,s
/prep7
!分析模式
ANTYPE,STATIC
csys,0
SMRT,OFF
MP,EX,1,206
MP,NUXY,1,0.3
MP,DENS,1,7.85E-6
!================================================================
!钢梁部分
!================================================================
!生成面
B=600 !顶板宽
L=6500 !顶板长
H=750 !腹板高度
B1=300 !腹板间距
B2=250 !抱柱箍宽度
H1=400 !抱柱箍高度
!========================
!底板
K,1001,2100-B/2,0,7000
K,1002,2100+B/2,0,7000
K,1003,2100+B/2,L/2,7000
K,1004,2100-B/2,L/2,7000
NUMSTR,area,1001
A,1001,1002,1003,1004
!第2象限
NUMSTR,area,2001
ARSYM,X,1001,1001,1,1000,0,0
!第3象限
NUMSTR,area,3001
ARSYM,Y,2001,2001,1,1000,0,0
!第4象限
NUMSTR,area,4001
ARSYM,X,3001,3001,1,1000,0,0
!========================
!顶板
K,1101,2100-B/2,0,7000+H
K,1102,2100+B/2,0,7000+H
K,1103,2100+B/2,1200,7000+H
K,1104,2100-B/2,1200,7000+H
K,1105,2100+B/2,L/2,7000+H
K,1106,2100-B/2,L/2,7000+H
NUMSTR,area,1101
A,1101,1102,1103,1104
A,1104,1103,1105,1106
!第2象限
NUMSTR,area,2101
ARSYM,X,1101,1102,1,1000,0,0
!第3象限
NUMSTR,area,3101
ARSYM,Y,2101,2102,1,1000,0,0
!第4象限
NUMSTR,area,4101
ARSYM,X,3101,3102,1,1000,0,0
!========================
!外腹板
K,1201,2100+B1/2,0,7000
K,1202,2100+B1/2,L/2,7000
K,1203,2100+B1/2,L/2,7000+H
K,1204,2100+B1/2,0,7000+H
NUMSTR,area,1201
A,1201,1202,1203,1204
!第2象限
NUMSTR,area,2201
ARSYM,X,1201,1201,1,1000,0,0
!第3象限
NUMSTR,area,3201
ARSYM,Y,2201,2201,1,1000,0,0
!第4象限
NUMSTR,area,4201
ARSYM,X,3201,3201,1,1000,0,0
!========================
!内腹板
K,1301,2100-B1/2,0,7000
K,1302,2100-B1/2,0,7000+H-H1
K,1303,2100-B1/2,L/2,7000+H-H1
K,1304,2100-B1/2,L/2,7000
K,1305,2100-B1/2,0,7000+H
K,1306,2100-B1/2,L/2,7000+H
NUMSTR,area,1301
A,1301,1302,1303,1304
A,1305,1306,1303,1302
!第2象限
NUMSTR,area,2301
ARSYM,X,1301,1302,1,1000,0,0
!第3象限
NUMSTR,area,3301
ARSYM,Y,2301,2302,1,1000,0,0
!第4象限
NUMSTR,area,4301
ARSYM,X,3301,3302,1,1000,0,0
!========================
!内横隔板
K,1401,2100-B/2,0,7000
K,1402,2100-(B-B1)/2,0,7000
K,1403,2100-(B-B1)/2,0,7000+H
K,1404,2100-B/2,0,7000+H
NUMSTR,area,1400
A,1401,1402,1403,1404
!第1象限
*Dim,DistStiffPlate,ARRAY,9,1,1,,,,0
DistStiffPlate(1)=275
DistStiffPlate(2)=300
DistStiffPlate(3)=325
DistStiffPlate(4)=350
DistStiffPlate(5)=262.5
DistStiffPlate(6)=262.5
DistStiffPlate(7)=300
DistStiffPlate(8)=325
DistStiffPlate(9)=350
NUMSTR,area,1401
DSP=0
*DO, NN,1,9,1
DSP=DSP+DistStiffPlate(NN)
AGEN,2,1400,1400+NN,NN,0,DSP,0,10*NN
*ENDDO
!第2象限
NUMSTR,area,2401
ARSYM,X,1401,1409,1,1000,0,0
!第3象限
NUMSTR,area,3400
ARSYM,X,1400,1400,1,2000,0,0
NUMSTR,area,3401
ARSYM,Y,2401,2409,1,1000,0,0
!第4象限
NUMSTR,area,4401
ARSYM,X,3401,3409,1,1000,0,0
!外横隔板
!第1象限
NUMSTR,area,1500
AGEN,2,1400,1409,1,(B+B1)/2,0,0,100
!第2象限
NUMSTR,area,2501
AGEN,2,2401,2409,1,-(B+B1)/2,0,0,100
!第3象限
NUMSTR,area,3500
AGEN,2,3400,3409,1,-(B+B1)/2,0,0,100
!第4象限
NUMSTR,area,4501
AGEN,2,4401,4409,1,(B+B1)/2,0,0,100
!========================
!抱柱箍底板
K,1601,2100-B1/2,600+B2,7000+H-H1
K,1602,2100-B1/2,600,7000+H-H1
K,1603,0,600,7000+H-H1
K,1604,0,600+B2,7000+H-H1
NUMSTR,area,1601
A,1601,1602,1603,1604
!第2象限
NUMSTR,area,2601
ARSYM,X,1601,1601,1,1000,0,0
!第3象限
NUMSTR,area,3601
ARSYM,Y,2601,2601,1,1000,0,0
!第4象限
NUMSTR,area,4601
ARSYM,X,3601,3601,1,1000,0,0
!========================
!抱柱箍顶板
K,1701,2100-B/2,600,7000+H
K,1702,2100-B/2,600+B2,7000+H
K,1703,0,600+B2,7000+H
K,1704,0,600,7000+H
NUMSTR,area,1701
A,1701,1702,1703,1704
!第2象限
NUMSTR,area,2701
ARSYM,X,1701,1701,1,1000,0,0
!第3象限
NUMSTR,area,3701
ARSYM,Y,2701,2701,1,1000,0,0
!第4象限
NUMSTR,area,4701
ARSYM,X,3701,3701,1,1000,0,0
!========================
!抱柱箍腹板
K,1801,2100-B1/2,600+B2,7000+H-H1
K,1802,0,600+B2,7000+H-H1
K,1803,0,600+B2,7000+H
K,1804,2100-B1/2,600+B2,7000+H
NUMSTR,area,1801
A,1801,1802,1803,1804
!第2象限
NUMSTR,area,2801
ARSYM,X,1801,1801,1,1000,0,0
!第3象限
NUMSTR,area,3801
ARSYM,Y,2801,2801,1,1000,0,0
!第4象限
NUMSTR,area,4801
ARSYM,X,3801,3801,1,1000,0,0
!========================
!面粘合
SAVE
ASEL,ALL
!APLOT,ALL
AGLUE,ALL
!==================================================================
!面属性分配
ET,1,SHELL63
T=40
HBB=T !扁担梁底板厚度
HBT=T !扁担梁顶板厚度
HBW=T !扁担梁腹板厚度
HBD=T !扁担梁横隔板厚度
HZB=16 !抱柱梁底板厚度
HZT=16 !抱柱梁顶板厚度
HZW=16 !抱柱梁腹板厚度
!=============================
!扁担梁底板
ASEL,S,LOC,X,2100-B/2,2100+B/2
ASEL,A,LOC,X,-(2100+B/2),-(2100-B/2)
ASEL,R,LOC,Y,-3250,3250
ASEL,R,LOC,Z,7000
R,101,HBB, HBB,HBB,HBB
AATT, 1, 101, 1, 0,0
CM,BDbottom,AREA
!=============================
!扁担梁顶板
ASEL,S,LOC,X,2100-B/2,2100+B/2
ASEL,A,LOC,X,-(2100+B/2),-(2100-B/2)
ASEL,R,LOC,Y,-3250,3250
ASEL,R,LOC,Z,7000+H
R,102,HBT, HBT,HBT,HBT
AATT, 1, 102, 1, 0,0
CM,BDtop,AREA
!=============================
!扁担梁外腹板
ASEL,S,LOC,X,2100+B1/2
ASEL,A,LOC,X,-(2100+B1/2)
ASEL,R,LOC,Y,-3250,3250
ASEL,R,LOC,Z,7000,7000+H
R,103,HBW, HBW,HBW,HBW
AATT, 1, 103, 1, 0,0
CM,BDoweb,AREA
!=============================
!扁担梁内腹板
ASEL,S,LOC,X,2100-B1/2
ASEL,A,LOC,X,-(2100-B1/2)
ASEL,R,LOC,Y,-3250,3250
ASEL,R,LOC,Z,7000,7000+H
R,104,HBW, HBW,HBW,HBW
AATT, 1, 104, 1, 0,0
CM,BDiweb,AREA
!=============================
!扁担梁横隔板
ASEL,S,LOC,X,2100-B/2,2100-B1/2
ASEL,A,LOC,X,2100+B1/2,2100+B/2
ASEL,A,LOC,X,-(2100-B1/2),-(2100-B/2)
ASEL,A,LOC,X,-(2100+B/2),-(2100+B1/2)
ASEL,R,LOC,Z,7000,7000+H
ASEL,R,LOC,Y,0
DSP=0
*DO, NN,1,9,1
DSP=DSP+DistStiffPlate(NN)
ASEL,A,LOC,Y,DSP
ASEL,A,LOC,Y,-DSP
*ENDDO
R,105,HBD, HBD,HBD,HBD
AATT, 1, 105, 1, 0,0
CM,BDdiaphragm,AREA
!=============================
!抱柱箍底板
ASEL,S,LOC,Y,600,600+B2
ASEL,A,LOC,Y,-(600+B2),-600
ASEL,R,LOC,X,-(2100-B1/2),2100-B1/2
ASEL,R,LOC,Z,7000+H-H1
R,111,HZB, HZB,HZB,HZB
AATT, 1, 111, 1, 0,0
CM,BZbottom,AREA
!=============================
!抱柱箍顶板
ASEL,S,LOC,Y,600,600+B2
ASEL,A,LOC,Y,-(600+B2),-600
ASEL,R,LOC,X,-(2100-B/2),2100-B/2
ASEL,R,LOC,Z,7000+H
R,112,HZT, HZT,HZT,HZT
AATT, 1, 112, 1, 0,0
CM,BZtop,AREA
!=============================
!抱柱箍腹板
ASEL,S,LOC,Y,600+B2
ASEL,A,LOC,Y,-(600+B2)
ASEL,R,LOC,X,-(2100-B1/2),2100-B1/2
ASEL,R,LOC,Z,7000+H-H1,7000+H
R,113,HZW, HZW,HZW,HZW
AATT, 1, 113, 1, 0,0
CM,BZweb,AREA
!==================================================================
!网格划分
ASEL,ALL
MSHAPE,0,2d
MSHKEY,0
!SMRTSIZE,3
!ESIZE,50
!ASEL,ALL
!AMESH,ALL
!==================================================================
!合并节点、单元、关键点
ALLSEL
NUMMRG,NODE
NUMMRG,ELEM
NUMMRG,KP
!==================================================================
!保存
ALLSEL
SAVE
FINISH
!================
!生成分网子程序
*CREATE,ADAPTMSH,MAC
C*** Subroutine ADAPTMSH.MAC - ZSF - NanPu Bridge
ASEL,ALL
TYPE,1
ACLEAR,ALL
AMESH,ALL
*END
!================
!生成边界条件子程序
*CREATE,ADAPTBC,MAC
C*** Subroutine ADAPTBC.MAC - ZSF - NanPu Bridge
!支撑第1象限
NSEL,NONE
LOCAL,11,1,2100,1075,7000
NSEL,S,LOC,X,0,275
NSEL,R,LOC,Z,0
NSEL,A,LOC,X,0
NSEL,R,LOC,Z,0
CM,HptNode_1,NODE
D,HptNode_1,ALL
!================
NSEL,NONE
LOCAL,11,1,2100,2575,7000
NSEL,S,LOC,X,0,275
NSEL,R,LOC,Z,0
NSEL,A,LOC,X,0
NSEL,R,LOC,Z,0
CM,HptNode_2,NODE
D,HptNode_2,ALL
!支撑第2象限
NSEL,NONE
LOCAL,11,1,-2100,2575,7000
NSEL,S,LOC,X,0,275
NSEL,R,LOC,Z,0
NSEL,A,LOC,X,0
NSEL,R,LOC,Z,0
CM,HptNode_3,NODE
D,HptNode_3,ALL
!自重
ACEL,0,0,9.8e-3
!加载面荷载作用于扁担梁
ASEL,S,LOC,X,-2400,-1800
ASEL,A,LOC,X,1800,2400
ASEL,R,LOC,Y,-1200,1200
ASEL,R,LOC,Z,7000+H
CM,Loadsurface_1,Area
SFA,Loadsurface_1,2,PRES,4.5833e-3
SFTRAN
*END
!================
!生成求解子程序
*CREATE,ADAPTSOL,MAC
C*** Subroutine ADAPTSOL.MAC - ZSF - NanPu Bridge
/SOLU
SOLVE
FINISH
*END
!==================================================================
!自适应网格划分
ADAPT,,5,,,,,1
!*ULIB,ADAPTMSH.MAC
*USE,ADAPTMSH.MAC
!*ULIB,ADAPTBC.MAC
*USE,ADAPTBC.MAC
!*ULIB,ADAPTSOL.MAC
*USE,ADAPTSOL.MAC
!==================================================================
!后处理
/POST1
PLDISP
PRERR
[[i] 本帖最后由 hishaw 于 2008-7-25 12:50 编辑 [/i]] 你的标题是不是可以修改一下？谢谢
页:
[1]