论坛 › C01：ANSYS--低频软件(Maxwell \PExprt\Rmxprt\Simplorer) › 求助：压电换能器提取声压全为零？？？

steven710 发表于 2010-9-20 12:54:39

求助：压电换能器提取声压全为零？？？

本帖最后由 steven710 于 2010-9-20 13:43 编辑

我现在在仿真压电换能器在空气中的声压辐射图，可是，提取到的声压却全是零，请各位高手帮帮忙呀。。。。附代码如下：
/PREP7
/TITLE

S11=16.1E-12
S12=-5.74E-12
S13=-7.22E-12
S33=20.4E-12
S44=52.6E-12
S66=44.3E-12

D15=7.58E-10
D31=-2.1E-10
D33=3.74E-10

EP11=2270
EP33=2130

RHO=7650

TB,ANEL,1,,,1
TBDATA,1,S11,S13,S12
TBDATA,7,S33,S13
TBDATA,12,S11
TBDATA,16,S44

TB,PIEZ,1,,,1
TBDATA,2,D31
TBDATA,5,D33
TBDATA,8,D31
TBDATA,10,D15

TB,DPER,1,,,1
TBDATA,1,EP11,EP33

MP,DENS,1,RHO
MP,DMPR,1,0.005

ET,1,PLANE223,1001,,1
ET,2,FLUID29
ET,3,129
R,3,0.05,0,0
ET,4,FLUID29,,1,0

MP,DENS,2,1.21
MP,SONC,2,344

R=7.5E-3
T=15.5E-3
RL=0.05

CYL4,0,0,0,90,RL,-90

RECT,0,R,-T/2,T/2

AOVLAP,1,2

ASEL,S,AREA,,3
AATT,1,1,1,0
LESIZE,6,,,2,1
LESIZE,4,,,2,1
LESIZE,5,,,4,1
LESIZE,8,,,2,1
LESIZE,9,,,2,1
MSHKEY,0
MSHAPE,0,2D
AMESH,3

ASEL,S,AREA,,4
AATT,2,1,2,0
LESIZE,10,,,10,1
LESIZE,11,,,10,1
LESIZE,1,,,30,1
MSHKEY,0
MSHAPE,0,2D
AMESH,4

ESEL,S,TYPE,,1
NSLE,S
ESLN,S,0
NSLE,S
ESEL,INVE
NSLE,S
EMODIF,ALL,TYPE,4
ESEL,ALL
NSEL,ALL

CSYS,1
NSEL,S,LOC,X,RL
TYPE,3
REAL,3
MAT,2
ESURF
ESEL,ALL
NSEL,ALL

LSEL,S,,,6
LSEL,A,,,4
LSEL,A,,,5
NSLL,S,1
ESEL,S,TYPE,,2
SF,ALL,FSI,1
NSEL,ALL
ESEL,ALL

LSEL,S,,,6
NSLL,S,1
CP,1,VOLT,ALL
*GET,N_TOP,NODE,,NUM,MIN
D,ALL,VOLT,1


LSEL,S,,,4
NSLL,S,1
CP,2,VOLT,ALL
*GET,N_BOT,NODE,,NUM,MIN
D,ALL,VOLT,0

NSEL,ALL
ESEL,ALL
FINISH


/SOLU
EQSLV,SPARSE
ANTYPE,HARMIC
HROPT,FULL
HARFRQ,10000,500000
NSUBST,500
KBC,1
SOLVE

/POST1
SET,FIRST
ESEL,S,MAT,,2
PLESOL,NMISC,1,0,1

steven710 发表于 2010-9-20 13:06:37

1# steven710 1

steven710 发表于 2010-9-20 13:08:37

声压提取结果图，都是零，，，， 2# steven710

hy1966 发表于 2010-9-21 12:58:21

没有定义流体固体耦合

steven710 发表于 2010-9-21 13:08:45

感谢老师的回复！
LSEL,S,,,6
LSEL,A,,,4
LSEL,A,,,5
NSLL,S,1
ESEL,S,TYPE,,2
SF,ALL,FSI,1   ！！！！这句不是定义流固耦合了么？
NSEL,ALL
ESEL,ALL

我对这个地方还是不太清楚，请老师指导一下吧，看了很多资料，还是有点晕。。。

4# hy1966

hy1966 发表于 2010-9-21 15:20:28

不好意思，看走眼了，呵呵

steven710 发表于 2010-9-21 15:37:20

呃，没关系，老师有时间看我的帖子已经很感谢了！！
那我的问题现在到底在哪呢，还请老师多多指教呀！！ 6# hy1966

feitianlong 发表于 2010-9-21 16:08:27

流固耦合没定义上：
以下是我修改了一下你的命令流，可以计算出声压结果：
LSEL,S,,,6
LSEL,A,,,4
LSEL,A,,,5
SFL,ALL,FSI
NSEL,ALL
ESEL,ALL

LSEL,S,,,6
NSLL,S,1
CP,1,VOLT,ALL
*GET,N_TOP,NODE,,NUM,MIN
D,ALL,VOLT,1

allsel,all
LSEL,S,,,4
NSLL,S,1
CP,2,VOLT,ALL
*GET,N_BOT,NODE,,NUM,MIN
D,ALL,VOLT,0

NSEL,ALL
ESEL,ALL
FINISH


/SOLU
EQSLV,SPARSE
ANTYPE,HARMIC
HROPT,FULL
HARFRQ,10000,500000
NSUBST,500
KBC,1
SOLVE

feitianlong 发表于 2010-9-21 16:12:39

再给你贴张计算结果的图片吧：

steven710 发表于 2010-9-21 16:45:16

9# feitianlong

steven710 发表于 2010-9-21 16:46:26

非常感谢你的解答，对我帮助很大！
我按照你修改后的程序运行了一下，没有得到你给出的一样的结果，我的声场分布貌似没有那么对称，请问你是如何进行后处理的呢？ 9# feitianlong

steven710 发表于 2010-9-21 16:54:47

我求得的声场图。。。。很不对称呀。。。。。 9# feitianlong

hy1966 发表于 2010-9-21 21:18:05

本帖最后由 hy1966 于 2010-9-21 21:24 编辑

前面的命令流应该没有什么大问题，只是所有单元均应打开轴对称选项
ESEL,S,MAT,,2
PLESOL,NMISC,1,0,1
有问题，因为对于fluid129最后那个命令显示声速，不是声压
只选择单元类型4显示ESEL,S,type,,4就可以了
由于单元声压是其所依附节点声压的算术平均值，选择节点自由度直接作图显示看起来要连续一些

steven710 发表于 2010-9-21 22:18:20

本帖最后由 steven710 于 2010-9-21 22:19 编辑

感谢hy1966老师！我按照老师的建议把各个单元属性都已经修改成对称的，同时我把网格划分得更小了，并且在后处理单元提取的是节点电压：
/POST1
SET,FIRST
NSEL,ALL
PLNSOL,PRES

可是结果还是不理想，只有一个方向上有声压，其他方向还是没有。。。不知道为什么。。
13# hy1966

steven710 发表于 2010-9-21 22:18:48

修改后的代码如下：/PREP7
/TITLE

S11=16.1E-12
S12=-5.74E-12
S13=-7.22E-12
S33=20.4E-12
S44=52.6E-12
S66=44.3E-12

D15=7.58E-10
D31=-2.1E-10
D33=3.74E-10

EP11=2270
EP33=2130

RHO=7650

TB,ANEL,1,,,1
TBDATA,1,S11,S13,S12
TBDATA,7,S33,S13
TBDATA,12,S11
TBDATA,16,S44

TB,PIEZ,1,,,1
TBDATA,2,D31
TBDATA,5,D33
TBDATA,8,D31
TBDATA,10,D15

TB,DPER,1,,,1
TBDATA,1,EP11,EP33

MP,DENS,1,RHO
MP,DMPR,1,0.005

ET,1,PLANE223,1001,,1
ET,2,FLUID29,,0,1
ET,3,129,,,1
R,3,0.05,0,0
ET,4,FLUID29,,1,1

MP,DENS,2,1.21
MP,SONC,2,344

R=7.5E-3
T=15.5E-3
RL=0.05

CYL4,0,0,0,90,RL,-90

RECT,0,R,-T/2,T/2

AOVLAP,1,2

ASEL,S,AREA,,3
AATT,1,1,1,0
LESIZE,6,,,8,1
LESIZE,4,,,8,1
LESIZE,5,,,16,1
LESIZE,8,,,8,1
LESIZE,9,,,8,1
MSHKEY,0
MSHAPE,0,2D
AMESH,3

ASEL,S,AREA,,4
AATT,2,1,2,0
LESIZE,10,,,40,1
LESIZE,11,,,40,1
LESIZE,1,,,120,1
MSHKEY,0
MSHAPE,0,2D
AMESH,4

ESEL,S,TYPE,,1
NSLE,S
ESLN,S,0
NSLE,S
ESEL,INVE
NSLE,S
EMODIF,ALL,TYPE,4
ESEL,ALL
NSEL,ALL

CSYS,1
NSEL,S,LOC,X,RL
TYPE,3
REAL,3
MAT,2
ESURF
ESEL,ALL
NSEL,ALL

CSYS,0

LSEL,S,,,6
LSEL,A,,,4
LSEL,A,,,5
SFL,ALL,FSI
NSEL,ALL
ESEL,ALL

LSEL,S,,,6
NSLL,S,1
CP,1,VOLT,ALL
*GET,N_TOP,NODE,,NUM,MIN
D,ALL,VOLT,1


ALLSEL,ALL

LSEL,S,,,4
NSLL,S,1
CP,2,VOLT,ALL
*GET,N_BOT,NODE,,NUM,MIN
D,ALL,VOLT,0

NSEL,ALL
ESEL,ALL
FINISH


/SOLU
EQSLV,SPARSE
ANTYPE,HARMIC
HROPT,FULL
OUTERS,ALL,ALL
HARFRQ,77000,80000
NSUBST,100
KBC,1
SOLVE

/POST1
SET,FIRST
NSEL,ALL
PLNSOL,PRES


13# hy1966

hy1966 发表于 2010-9-22 10:27:03

检查一下耦合界面

steven710 发表于 2010-9-22 12:37:17

感谢hy1966老师，已经发现问题了，是那两条耦合边界没有选中！结果如图！ 16# hy1966

feitianlong 发表于 2010-9-26 11:35:29

今天才看到帖子，既然问题已经解决，就不多说了。

yinzhen12 发表于 2012-2-5 13:28:45

:lol:lol:lol学习学习！

419321723 发表于 2013-3-28 21:22:21

hy1966 :老师您好，这个例子，为什么amps不能求出来呀？

查看完整版本: 求助：压电换能器提取声压全为零？？？