斜拉桥模态分析
本帖最后由 xiaoliang678324 于 2011-1-6 20:43 编辑!斜拉桥动力特性分析
finish
/clear
/title,tgb
/prep7
!定义单元及材料类型************************************************************************************
!钢箱梁特性 !
et,1,beam4 !
MP,EX,1,2.1e11 !
MP,PRXY,1,0.3 !
MP,DENS,1,7850 !
MP,ALPX,1,0.000012 !
!
!主塔主梁混凝土特性 !
MP,EX,2,3.45e10 !
MP,PRXY,2,0.2 !
MP,DENS,2,2600 !
MP,ALPX,2,1e-5 !
!
!刚性横梁特性 !
MP,EX,3,2.1e13 !
MP,PRXY,3, !
MP,DENS,3, !
MP,ALPX,3,0.000012 !
!
!主塔刚臂特性(有质量) !
MP,EX,4,3.45e13 !
MP,PRXY,4,0.2 !
MP,DENS,4,2600 !
MP,ALPX,4,1e-5 !
!
!主塔刚臂特性(无质量) !
MP,EX,5,3.45e13 !
MP,PRXY,5,0.2 !
MP,DENS,5,0 !
MP,ALPX,5,1e-5 !
!
!斜拉索特性 !
!拉索等效弹模 !
*DIM,cable_e,ARRAY,24 !
cable_e(1 )= 1.8749E+11 !
cable_e(2 )= 1.8787E+11 !
cable_e(3 )= 1.8822E+11 !
cable_e(4 )= 1.8853E+11 !
cable_e(5 )= 1.8882E+11 !
cable_e(6 )= 1.8906E+11 !
cable_e(7 )= 1.8929E+11 !
cable_e(8 )= 1.8949E+11 !
cable_e(9 )= 1.8965E+11 !
cable_e(10)= 1.8978E+11 !
cable_e(11)= 1.8988E+11 !
cable_e(12)= 1.8995E+11 !
cable_e(13)= 1.8995E+11 !
cable_e(14)= 1.8988E+11 !
cable_e(15)= 1.8978E+11 !
cable_e(16)= 1.8965E+11 !
cable_e(17)= 1.8949E+11 !
cable_e(18)= 1.8929E+11 !
cable_e(19)= 1.8906E+11 !
cable_e(20)= 1.8882E+11 !
cable_e(21)= 1.8853E+11 !
cable_e(22)= 1.8822E+11 !
cable_e(23)= 1.8787E+11 !
cable_e(24)= 1.8749E+11 !
!
!拉索等效密度 !
*DIM,cable_d,ARRAY,24 !
cable_d(1 )= 8480.82 !
cable_d(2 )= 8480.82 !
cable_d(3 )= 8466.47 !
cable_d(4 )= 8466.47 !
cable_d(5 )= 8466.47 !
cable_d(6 )= 8543.10 !
cable_d(7 )= 8543.10 !
cable_d(8 )= 8510.51 !
cable_d(9 )= 8510.51 !
cable_d(10)= 8510.51 !
cable_d(11)= 8510.51 !
cable_d(12)= 8510.51 !
cable_d(13)= 8510.51 !
cable_d(14)= 8510.51 !
cable_d(15)= 8510.51 !
cable_d(16)= 8510.51 !
cable_d(17)= 8510.51 !
cable_d(18)= 8543.10 !
cable_d(19)= 8543.10 !
cable_d(20)= 8466.47 !
cable_d(21)= 8466.47 !
cable_d(22)= 8466.47 !
cable_d(23)= 8480.82 !
cable_d(24)= 8480.82 !
!
et,2,link8 !
*do,i,1,24,1 !
*set,j,i+5 !
MP,EX,j,cable_e(i) !
MP,PRXY,j,0.25 !
MP,DENS,j,cable_d(i) !
*enddo !
!
!质量单元 !
et,3,mass21 !
keyopt,3,3,0 !
!定义单元及材料类型************************************************************************************
!定义主梁、主塔、斜拉索实常数**************************************************************************
!主梁 !
R, 1, 1.2435 , 2.4807 ,57.5950 ,21.6420 ,4.2038 , 0 !钢箱梁标准断面 !
RMORE, ,7.0552 !
!
!主塔（C-L） !
R,2, 17.500, 99.646 , 52.639 , 5.000, 7.000, 0 !D !
RMORE, ,119.100 !
R,3, 16.140, 90.934 , 51.329 , 5.000, 7.000, 0 !E !
RMORE, ,112.870 !
R,4, 23.940, 117.370, 63.305 , 5.000, 7.000, 0 !F !
RMORE, ,144.220 !
R,5, 31.491, 199.460, 103.860 , 5.540, 7.862, 0 !G !
RMORE, ,231.320 !
R,6, 24.111, 189.470, 100.960 , 5.718, 8.195, 0 !H !
RMORE, ,218.480 !
R,7, 27.853, 289.510, 157.860 , 6.514, 9.270, 0 !I !
RMORE, ,335.470 !
R,8, 49.629, 455.500, 233.250 , 6.734, 9.602, 0 !J !
RMORE, ,521.650 ! !
!主塔横梁(M-O) !
R, 12, 15.500 , 39.290 , 96.979 , 7.000, 4.500 , 0 !K !
RMORE, ,89.954 !
R, 13, 13.500 , 20.431 , 78.813 , 7.000, 3.500 , 0 !L !
RMORE, ,53.890 !
R, 14, 17.458 , 80.980 , 85.813 , 6.398, 5.917 , 0 !M !
RMORE, ,134.110 !
R,15, 1.1069 , 2.1189 ,53.9110 ,4.0 ,4.0 , 0 !主梁刚臂断面 !
RMORE, ,5.8068 !
!
!斜拉索（边跨10，主跨10） !
*DIM,cable_a,ARRAY,24 !创建拉索面积矩阵 !
cable_a(1 ) = 6.2730E-03 !
cable_a(2 ) = 6.2730E-03 !
cable_a(3 ) = 5.8112E-03 !
cable_a(4 ) = 5.8112E-03 !
cable_a(5 ) = 5.8112E-03 !
cable_a(6 ) = 5.3493E-03 !
cable_a(7 ) = 5.3493E-03 !
cable_a(8 ) = 4.1948E-03 !
cable_a(9 ) = 4.1948E-03 !
cable_a(10) = 4.1948E-03 !
cable_a(11) = 4.1948E-03 !
cable_a(12) = 4.1948E-03 !
cable_a(13) = 4.1948E-03 !
cable_a(14) = 4.1948E-03 !
cable_a(15) = 4.1948E-03 !
cable_a(16) = 4.1948E-03 !
cable_a(17) = 4.1948E-03 !
cable_a(18) = 5.3493E-03 !
cable_a(19) = 5.3493E-03 !
cable_a(20) = 5.8112E-03 !
cable_a(21) = 5.8112E-03 !
cable_a(22) = 5.8112E-03 !
cable_a(23) = 6.2730E-03 !
cable_a(24) = 6.2730E-03 !
*DIM,cable_str,ARRAY,24 !创建拉索初应变矩阵 !
cable_str(1 ) = 3.5158E-03 !
cable_str(2 ) = 3.5158E-03 !
cable_str(3 ) = 3.5158E-03 !
cable_str(4 ) = 3.5158E-03 !
cable_str(5 ) = 3.5158E-03 !
cable_str(6 ) = 3.5158E-03 !
cable_str(7 ) = 3.5158E-03 !
cable_str(8 ) = 3.5158E-03 !
cable_str(9 ) = 3.5158E-03 !
cable_str(10) = 3.5158E-03 !
cable_str(11) = 3.5158E-03 !
cable_str(12) = 3.5158E-03 !
cable_str(13) = 3.5158E-03 !
cable_str(14) = 3.5158E-03 !
cable_str(15) = 3.5158E-03 !
cable_str(16) = 3.5158E-03 !
cable_str(17) = 3.5158E-03 !
cable_str(18) = 3.5158E-03 !
cable_str(19) = 3.5158E-03 !
cable_str(20) = 3.5158E-03 !
cable_str(21) = 3.5158E-03 !
cable_str(22) = 3.5158E-03 !
cable_str(23) = 3.5158E-03 !
cable_str(24) = 3.5158E-03 !
*DO,i,1,24,1 !
R, i+15 , cable_a(i) , cable_str(i) !
*ENDDO !
!
!定义过渡墩、辅助墩实常数 !
R ,40 , 15.120 , 19.967 , 18.022 , 3.800 , 4.000 , 0 !过渡墩墩柱 !
RMORE, ,32.409 !
R ,41 , 14.360 , 17.107 , 17.107 , 3.800 , 3.800 , 0 !辅助墩墩柱 !
RMORE, ,29.283 !
R ,42 , 12.500 , 6.510 , 26.042 , 5.000 , 2.500 , 0 !过渡墩系梁 !
RMORE, ,17.866 !
R ,43 , 8.500 , 4.427 , 8.188 , 3.400 , 2.500 , 0 !辅助墩系梁 !
RMORE, ,9.727 !
!
!定义主梁、主塔、斜拉索实常数**************************************************************************
!创建泉州海湾桥几何模型**************************************************************************
!主梁关键点
!z_beam = -0.996
r_line=20000 !竖曲线半径
y_mid=19940.898 !竖曲线半径-主梁跨中标高
z_beam = 0
shear_center = 1.9115!主梁扭心距主梁顶部距离
*DIM,x_beam,ARRAY,100
x_beam(1 ) = -400.0000
x_beam(2 ) = -392.0000
x_beam(3 ) = -377.0000
x_beam(4 ) = -362.0000
x_beam(5 ) = -347.0000
x_beam(6 ) = -332.0000
x_beam(7 ) = -329.9940
x_beam(8 ) = -317.0000
x_beam(9 ) = -302.0000
x_beam(10) = -287.0000
x_beam(11) = -272.0000
x_beam(12) = -257.0000
x_beam(13) = -242.0000
x_beam(14) = -227.0000
x_beam(15) = -200.0000
x_beam(16) = -173.0000
x_beam(17) = -158.0000
x_beam(18) = -143.0000
x_beam(19) = -128.0000
x_beam(20) = -113.0000
x_beam(21) = -98.0000
x_beam(22) = -83.0000
x_beam(23) = -68.0000
x_beam(24) = -53.0000
x_beam(25) = -38.0000
x_beam(26) = -23.0000
x_beam(27) = -8.0000
x_beam(28) = 0.0000
*DIM,y_beam,ARRAY,100
*DO,i,1,28,1
*SET,x,x_beam(i)
*SET,y_beam(i),(r_line**2-(x_beam(i))**2)**0.5-y_mid-shear_center
*SET,y,y_beam(i)
*SET,z,z_beam
K,i,x,y,z
*ENDDO
!创建主梁线
*DO,i,1,27,1
L,i,i+1
*ENDDO
ALLSEL
LESIZE,ALL,1 !
TYPE,1 !
MAT,1 !
REAL,1 !
LMESH,ALL !划分主梁单元 !
CM,beam_half,ELEM !定义主梁为beam_half组
!创建横梁线
!拉索z坐标
z_cablel = -10.87
z_cabler =10.87
!横梁z坐标
z_support = 4.8
*DO,i,1,27,1
*SET,x,x_beam(i)
*SET,y,y_beam(i)
*SET,z1,z_cablel
*SET,z2,-1*z_support
*SET,z3,z_support
*SET,z4,z_cabler
K,,x,y,z1
K,,x,y,z2
K,,x,y,z3
K,,x,y,z4
*ENDDO
*DO,i,1,27,1
ALLSEL
*SET,x,x_beam(i)
*SET,y,y_beam(i)
*SET,z1,z_cablel
*SET,z2,-1*z_support
*SET,z3,z_beam
*SET,z4,z_support
*SET,z5,z_cabler
k1 = KP(x,y,z1)
k2 = KP(x,y,z2)
k3 = KP(x,y,z3)
k4 = KP(x,y,z4)
k5 = KP(x,y,z5)
*DO,j,1,4,1
L,k%j%,k%j+1%
*ENDDO
*ENDDO
LSEL,ALL
LSEL,U,REAL,,1
LESIZE,ALL,2 !
TYPE,1 !
MAT,3 !
REAL,15 !
LMESH,ALL !划分横梁单元
ALLSEL
ESEL,S,MAT,,3
CM,crossbeam,ELEM !定义刚性横梁为crossbeam组
!创建主塔
!上塔柱部分y坐标
*DIM,y_tow,ARRAY,50
y_tow(1 ) = 164.50000
y_tow(2 ) = 158.49955
y_tow(3 ) = 156.24955
y_tow(4 ) = 153.99955
y_tow(5 ) = 152.96335
y_tow(6 ) = 150.96335
y_tow(7 ) = 148.96335
y_tow(8 ) = 146.96335
y_tow(9 ) = 144.96335
y_tow(10) = 143.49955
y_tow(11) = 142.96335
y_tow(12) = 141.74955
y_tow(13) = 140.96335
y_tow(14) = 138.96335
y_tow(15) = 136.96335
y_tow(16) = 134.96335
y_tow(17) = 132.96335
y_tow(18) = 130.96335
y_tow(19) = 128.50000
y_tow(20) = 123.50000
y_tow(21) = 65.70000
y_tow(22) = 60.70000
y_tow(23) = 58.10100 - shear_center
y_tow(24) = 52.70000
y_tow(25) = 49.70000
y_tow(26) = 44.67302
y_tow(27) = 40.70000
y_tow(28) = 27.10000
y_tow(29) = 13.50000
y_tow(30) = 5.50000
z_tower = 13.85
x_tower = -200
*DO,i,1,30,1
*SET,x,x_tower
*SET,z,-1*z_tower
*SET,y,y_tow(i)
K,,x,y,z
*ENDDO
ALLSEL
kt = KP(x_tower,y_tow(1),z_tower)
*DO,i,1,29,1
L,kt,kt+1
kt = kt+1
*ENDDO
!定义主塔截面特性转变处y坐标
*DIM,y_towchange,ARRAY,50
y_towchange(1 ) = 164.50000 !D
y_towchange(2 ) = 123.50000 !D
y_towchange(3 ) = 65.70000 !E
y_towchange(4 ) = 49.70000 !F
y_towchange(5 ) = 40.70000 !G
y_towchange(6 ) = 27.10000 !H
y_towchange(7 ) = 13.50000 !I
y_towchange(8 ) = 5.50000 !J
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!2010.05.24
!定义主塔横梁刚臂处y坐标
*DIM,y_towstiff,ARRAY,50
y_towstiff(1) = 158.49955
y_towstiff(2) = 153.99955
y_towstiff(3) = 143.49955
y_towstiff(4) = 136.96335
y_towstiff(5) = 52.70000
y_towstiff(6) = 44.67302
*DO,i,1,7,1
*SET,y_max,y_towchange(i)
*SET,y_min,y_towchange(i+1)
TYPE,1
REAL,1+i
LSEL,ALL
LSEL,S,LOC,Y,y_min,y_max
LSEL,U,TYPE,,1,100,1
LSEL,U,LOC,Y,y_towstiff(2),y_towstiff(1)
LSEL,U,LOC,Y,y_towstiff(4),y_towstiff(3)
LSEL,U,LOC,Y,y_towstiff(6),y_towstiff(5)
LESIZE,ALL,1 ! !
MAT,2 ! !
LMESH,ALL
*ENDDO
!桥塔上横梁，中横梁处塔柱刚臂
ALLSEL
LSEL,S,LOC,Y,y_towstiff(4),y_towstiff(1)
LSEL,U,TYPE,,1,100,1
LESIZE,ALL,1
TYPE,1
REAL,2
MAT,4
LMESH,ALL
!桥塔下横梁处塔柱刚臂
ALLSEL
LSEL,S,LOC,Y,y_towchange(4),y_towstiff(5)
LSEL,U,TYPE,,1,100,1
LESIZE,ALL,1
TYPE,1
REAL,4
MAT,4
LMESH,ALL
ALLSEL
LSEL,S,LOC,Y,y_towstiff(6),y_towchange(4)
LSEL,U,TYPE,,1,100,1
LESIZE,ALL,1
TYPE,1
REAL,5
MAT,4
LMESH,ALL
!创建锚索区刚臂
*DIM,x_cablet,ARRAY,12
x_cablet(1 ) = -203.5000
x_cablet(2 ) = -203.5000
x_cablet(3 ) = -203.5000
x_cablet(4 ) = -203.5000
x_cablet(5 ) = -203.5000
x_cablet(6 ) = -203.5000
x_cablet(7 ) = -203.5000
x_cablet(8 ) = -203.5000
x_cablet(9 ) = -203.5000
x_cablet(10) = -203.5000
x_cablet(11) = -203.5000
x_cablet(12) = -203.5000
*DIM,y_cablet,ARRAY,12
y_cablet(1 ) = 152.96335
y_cablet(2 ) = 150.96335
y_cablet(3 ) = 148.96335
y_cablet(4 ) = 146.96335
y_cablet(5 ) = 144.96335
y_cablet(6 ) = 142.96335
y_cablet(7 ) = 140.96335
y_cablet(8 ) = 138.96335
y_cablet(9 ) = 136.96335
y_cablet(10) = 134.96335
y_cablet(11) = 132.96335
y_cablet(12) = 130.96335
*DO,i,1,12,1
*SET,x1,x_cablet(i)
*SET,y1,y_cablet(i)
*SET,z1,-1*z_tower
*SET,x2,x_tower
*SET,y2,y_cablet(i)
*SET,z2,-1*z_tower
*SET,x3,-400-x_cablet(i)
*SET,y3,y_cablet(i)
*SET,z3,-1*z_tower
K,,x1,y1,z1
K,,x3,y3,z3
*SET,k1,KP(x1,y1,z1)
*SET,k2,KP(x2,y2,z2)
*SET,k3,KP(x3,y3,z3)
L,k1,k2
L,k2,k3
*ENDDO
ALLSEL
LSEL,S,LOC,Z,-1*z_tower
LSEL,U,MAT,,1,100,1
LESIZE, ALL, , , 1 !
TYPE,1 !
MAT,5 !
REAL,2 !
LMESH,ALL
ALLSEL
LSEL,S,MAT,,2,4,2
LSEL,A,MAT,,5
LSYMM, Z, ALL
ALLSEL
ESEL,S,MAT,,2,4,2
ESEL,A,MAT,,5
CM,tower_half,ELEM
!创建桥塔横梁
*DIM,y_tcross,ARRAY,3
y_tcross(1) = 156.24955
y_tcross(2) = 141.74955
y_tcross(3) = 49.70000
*DIM,z_tcross,ARRAY,3
z_tcross(1) = 11.35000
z_tcross(2) = 11.35000
z_tcross(3) = 11.35000
*DO,i,1,3,1
TYPE,1
REAL,11+i
*SET,x,x_tower
*SET,y,y_tcross(i)
*SET,z1,-1*z_tower
*SET,z2,-1*z_tcross(i)
*SET,z3,-1*z_support
*SET,z4,z_support
*SET,z5,z_tcross(i)
*SET,z6,z_tower
*DO,j,2,5,1
K,,x,y,z%j%
*ENDDO
*DO,j,1,6,1
*SET,z,z%j%
*SET,k%j%,KP(x,y,z)
*ENDDO
*DO,j,1,5,1
L,k%j%,k%j+1%
*ENDDO
ALLSEL
LSEL,S,LOC,y,y_tcross(i)
LSEL,U,LOC,z,z2,z5
LSEL,U,TYPE,,1,100,1
MAT,4
LESIZE,ALL,2
LMESH,ALL
ALLSEL
LSEL,S,LOC,y,y_tcross(i)
LSEL,U,TYPE,,1,100,1
MAT,2
LESIZE,ALL,2
LMESH,ALL
*ENDDO
!创建拉索
*DIM,x_cableb,ARRAY,24 !定义拉索在主梁上锚固点的x坐标
x_cableb(1 ) = -392.0000
x_cableb(2 ) = -377.0000
x_cableb(3 ) = -362.0000
x_cableb(4 ) = -347.0000
x_cableb(5 ) = -332.0000
x_cableb(6 ) = -317.0000
x_cableb(7 ) = -302.0000
x_cableb(8 ) = -287.0000
x_cableb(9 ) = -272.0000
x_cableb(10) = -257.0000
x_cableb(11) = -242.0000
x_cableb(12) = -227.0000
x_cableb(13) = -173.0000
x_cableb(14) = -158.0000
x_cableb(15) = -143.0000
x_cableb(16) = -128.0000
x_cableb(17) = -113.0000
x_cableb(18) = -98.0000
x_cableb(19) = -83.0000
x_cableb(20) = -68.0000
x_cableb(21) = -53.0000
x_cableb(22) = -38.0000
x_cableb(23) = -23.0000
x_cableb(24) = -8.0000
*DIM,y_cableb,ARRAY,24 !定义拉索在主梁上锚固点的y坐标
*DO,i,1,24,1
*SET,y_cableb(i),(r_line**2-(x_cableb(i))**2)**0.5-y_mid-shear_center
*ENDDO
*DO,i,1,12,1
*SET,x1,x_cableb(i)
*SET,y1,y_cableb(i)
*SET,z1,z_cablel
*SET,x2,x_cablet(i)
*SET,y2,y_cablet(i)
*SET,z2,-1*z_tower
*SET,x3,x_cableb(i)
*SET,y3,y_cableb(i)
*SET,z3,z_cabler
*SET,x4,x_cablet(i)
*SET,y4,y_cablet(i)
*SET,z4,z_tower
*SET,x5,x_cableb(12+i)
*SET,y5,y_cableb(12+i)
*SET,z5,z_cablel
*SET,x6,-400-x_cablet(13-i)
*SET,y6,y_cablet(13-i)
*SET,z6,-1*z_tower
*SET,x7,x_cableb(12+i)
*SET,y7,y_cableb(12+i)
*SET,z7,z_cabler
*SET,x8,-400-x_cablet(13-i)
*SET,y8,y_cablet(13-i)
*SET,z8,z_tower
*DO,j,1,8,1
*SET,k%j%,KP(x%j%,y%j%,z%j%)
*ENDDO
L,k1,k2
L,k3,k4
ALLSEL
LSEL,S,LOC,X,-400,400
LSEL,U,TYPE,,1,100,1
TYPE,2
MAT,i+5
REAL,i+15
LESIZE, ALL, , , 1
LMESH,ALL
L,k5,k6
L,k7,K8
ALLSEL
LSEL,S,LOC,X,-400,400
LSEL,U,TYPE,,1,100,1
TYPE,2
MAT,i+5+12
REAL,i+15+12
LESIZE, ALL, , , 1
LMESH,ALL
*ENDDO
!创建过渡墩、辅助墩
x_pier1 = -400
x_pier2 = -330
*DIM,y_pier1,ARRAY,5 !过渡墩
y_pier1(1) = 50.13153
y_pier1(2) = 48.88153
y_pier1(3) = 45.67747
y_pier1(4) = 41.10217
y_pier1(5) = 5.50000
*DIM,z_pier1,ARRAY,5 !过渡墩
z_pier1(1) = -4.80000
z_pier1(2) = -4.26371
z_pier1(3) = -3.49660
z_pier1(4) = -3.10000
z_pier1(5) = -3.10000
!创建过渡墩、辅助墩
*DIM,y_pier2,ARRAY,5 !辅助墩
y_pier2(1) = 52.01517
y_pier2(2) = 50.76517
y_pier2(3) = 47.56022
y_pier2(4) = 42.98581
y_pier2(5) = 5.50000
*DIM,z_pier2,ARRAY,5 !辅助墩
z_pier2(1) = -4.80000
z_pier2(2) = -4.26371
z_pier2(3) = -3.49645
z_pier2(4) = -3.10000
z_pier2(5) = -3.10000
*DO,j,1,2,1
*SET,x,x_pier%j%
*DO,i,1,5,1
*SET,y,y_pier%j%(i)
*SET,z,z_pier%j%(i)
K,,x,y,z
*ENDDO
*ENDDO
*DO,j,1,2,1
*DO,i,1,4,1
*SET,x1,x_pier%j%
*SET,y1,y_pier%j%(i)
*SET,z1,z_pier%j%(i)
*SET,x2,x_pier%j%
*SET,y2,y_pier%j%(i+1)
*SET,z2,z_pier%j%(i+1)
*SET,k1,KP(x1,y1,z1)
*SET,k2,KP(x2,y2,z2)
L,k1,k2
LSEL,S,LOC,X,-400,400
LSEL,U,TYPE,,1,100,1
TYPE,1
MAT,2
REAL,39+j
LESIZE, ALL,2
LMESH,ALL
*ENDDO
*ENDDO
ALLSEL
LSEL,S,REAL,,40,41
LSYMM, Z, ALL
*DO,j,1,2,1
*SET,x1,x_pier%j%
*SET,y1,y_pier%j%(2)
*SET,z1,z_pier%j%(2)
*SET,x2,x_pier%j%
*SET,y2,y_pier%j%(2)
*SET,z2,-1*z_pier%j%(2)
*SET,k1,KP(x1,y1,z1)
*SET,k2,KP(x2,y2,z2)
L,k1,k2
LSEL,S,LOC,X,-400,400
LSEL,U,TYPE,,1,100,1
TYPE,1
MAT,2
REAL,41+j
LESIZE, ALL,2
LMESH,ALL
*ENDDO
!镜像复制另外半边桥
ALLSEL
LSEL,S,LOC,X,-400,400
LSYMM, X, ALL
ALLSEL
NUMMRG,ALL,0.0001,0.0001, ,LOW
!附加质量单元(kg/m,kgm2/m)
R, 200, 9188.5, 9188.5, 9188.5, 516673.98
TYPE,3
REAL,200
ALLSEL
*DO, i, 1, 800, 1
*SET, x, -400.0+(i-1)
*SET, y, (r_line**2-x**2)**0.5-y_mid-shear_center
*SET, Z, z_beam
ALLSEL
ni = NODE(x,y,z)
E,ni
*ENDDO
!过渡墩、辅助墩处主梁压重
R, 201, 2.0E+4, 2.0E+4, 2.0E+4, 0 !过渡墩
R, 202, 4.0E+4, 4.0E+4, 4.0E+4, 0 !辅助墩
TYPE,3
REAL,201
*DO,i,1,18,1
*SET, x, -400.0+(i-1)
*SET, y, (r_line**2-x**2)**0.5-y_mid-shear_center
*SET, Z, z_beam
ALLSEL
ni = NODE(x,y,z)
E,ni
*ENDDO
*DO,i,1,18,1
*SET, x, 400.0-(i-1)
*SET, y, (r_line**2-x**2)**0.5-y_mid-shear_center
*SET, Z, z_beam
ALLSEL
ni = NODE(x,y,z)
E,ni
*ENDDO
TYPE,3
REAL,202
*DO,i,1,19,1
*SET, x, -340.0+(i-1)
*SET, y, (r_line**2-x**2)**0.5-y_mid-shear_center
*SET, Z, z_beam
ALLSEL
ni = NODE(x,y,z)
E,ni
*ENDDO
*DO,i,1,18,1
*SET, x, 340.0-(i-1)
*SET, y, (r_line**2-x**2)**0.5-y_mid-shear_center
*SET, Z, z_beam
ALLSEL
ni = NODE(x,y,z)
E,ni
*ENDDO
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!2010.5.25 17:56
!施加约束条件
ALLSEL
KSEL,S,LOC,Y,5.5000
DK,ALL,ALL
*DIM,x_main,ARRAY,3
x_main(1) = -400
x_main(2) = -330
x_main(3) = -200
*DIM,y_main,ARRAY,3
y_main(1) = 50.13153
y_main(2) = 52.01517
y_main(3) = 52.70000
*DIM,x_slav,ARRAY,3
x_slav(1) = -400
x_slav(2) = -330
x_slav(3) = -200
*DIM,y_slav,ARRAY,3
*DO,i,1,3,1
*SET,y_slav(i),(r_line**2-(x_slav(i))**2)**0.5-y_mid-shear_center
*ENDDO
*DO,i,1,3,1 !UY
*DO,j,1,2,1
*SET,x1_main,x_main(i)
*SET,y1_main,y_main(i)
*SET,z1_main,((-1)**j)*z_support
*SET,x1_slav,x_slav(i)
*SET,y1_slav,y_slav(i)
*SET,z1_slav,((-1)**j)*z_support
*SET,nmain,NODE(x1_main,y1_main,z1_main)
*SET,nslav,NODE(x1_slav,y1_slav,z1_slav)
CP,j+3*(i-1),UY,nmain,nslav
*ENDDO
*ENDDO
*DO,i,1,2,1 !UZ
*SET,x1_main,x_main(i)
*SET,y1_main,y_main(i)
*SET,z1_main,z_support
*SET,x1_slav,x_slav(i)
*SET,y1_slav,y_slav(i)
*SET,z1_slav,z_support
*SET,nmain,NODE(x1_main,y1_main,z1_main)
*SET,nslav,NODE(x1_slav,y1_slav,z1_slav)
CP,NEXT,UZ,nmain,nslav
*ENDDO
*DO,i,1,3,1
*DO,j,1,2,1
*SET,x1_main,-1*x_main(i)
*SET,y1_main,y_main(i)
*SET,z1_main,((-1)**j)*z_support
*SET,x1_slav,-1*x_slav(i)
*SET,y1_slav,y_slav(i)
*SET,z1_slav,((-1)**j)*z_support
*SET,nmain,NODE(x1_main,y1_main,z1_main)
*SET,nslav,NODE(x1_slav,y1_slav,z1_slav)
CP,NEXT,UY,nmain,nslav
*ENDDO
*ENDDO
*DO,i,1,2,1 !UX
*SET,x1_main,-1*x_main(i)
*SET,y1_main,y_main(i)
*SET,z1_main,z_support
*SET,x1_slav,-1*x_slav(i)
*SET,y1_slav,y_slav(i)
*SET,z1_slav,z_support
*SET,nmain,NODE(x1_main,y1_main,z1_main)
*SET,nslav,NODE(x1_slav,y1_slav,z1_slav)
CP,NEXT,UZ,nmain,nslav
*ENDDO
!横向抗风支座
*DO,i,1,2,1 !UZ
*SET,x1_main,-200*((-1)**(i-1))
*SET,y1_main,(r_line**2-x1_main**2)**0.5-y_mid-shear_center
*SET,z1_main,-1*z_tower
*SET,x1_slav,x1_main
*SET,y1_slav,y1_main
*SET,z1_slav,z_cablel
*SET,nmain,NODE(x1_main,y1_main,z1_main)
*SET,nslav,NODE(x1_slav,y1_slav,z1_slav)
CP,NEXT,UZ,nmain,nslav
*ENDDO
*DO,i,1,2,1 !UZ
*SET,x1_main,-200*((-1)**(i-1))
*SET,y1_main,(r_line**2-x1_main**2)**0.5-y_mid-shear_center
*SET,z1_main,z_tower
*SET,x1_slav,x1_main
*SET,y1_slav,y1_main
*SET,z1_slav,z_cabler
*SET,nmain,NODE(x1_main,y1_main,z1_main)
*SET,nslav,NODE(x1_slav,y1_slav,z1_slav)
CP,NEXT,UZ,nmain,nslav
*ENDDO
!求解*****************************************************************************
finish
/solu
ANTYPE,0
!施加重力加速度
ACEL,0,9.81,0,
NROPT,AUTO, ,
LUMPM,0
EQSLV, , ,0,
PRECISION,0
MSAVE,0
PIVCHECK,1
PSTRES,ON !对斜拉桥而言
!SSTIF,ON !对悬索桥而言
TOFFST,0,
SOLVE
FINISH
/POST1
PLDISP,0
FINISH
/SOL
!*
ANTYPE,2
MSAVE,0
!*
MODOPT,LANB,50
EQSLV,SPAR
MXPAND,50, , ,0
LUMPM,0
PSTRES,1
!SSTIF,ON
!*
MODOPT,LANB,50,0,0, ,OFF
solve
FINISH
/POST1
SET,FIRST
PLDISP,0 兄弟，我有问题想问你一下，我的QQ:420248064 希望你能帮忙，非常感谢！ 我说，lz没正文啊 有的喊声啊。。。。。。 楼主的意思？ 命令流都贴了，建议楼主把该桥有关信息发上来，谢谢！ 我还是把命令流贴到软加上让其自己生成看看究竟是什么样子的 该不会是安庆长江大桥的吧？？ 表示关注... 谢谢喽，我要试试后处理 谢谢楼主。。。 缺少桥梁结构基本介绍 请楼主给出具体信息 希望您在百忙之中把该桥有关信息发上来，我们将万分感谢
页:
[1]