如何解决冲压中的穿透问题

gean

各位大虾: 小弟做了几个冲压练习,但是凸模和凹模以及配料间均出现了穿透,小生不才,不能解决该问题,望大虾哥哥帮帮忙.

kesuliu

If you use ls-dyna, change the first parameter of *CONTROL_CONTACT,
if it is too little, the penetration appears.

abcdefghijk

你的问题说得不太清楚，最好能把命令流贴出来。下面的例子好好研究一下，对照着做可能会有帮助
/prep7
/view,,1,2,3
/plopts,info,1
/pnum,mat,1
/num,1
  
et,1,SHELL163
keyopt,1,1,10   ! 10th element formulation recommended for springback  
r,1,,3,0.05
edshell,,,1     ! membrane straining causes thickness change (default)
  
et,2,SOLID164
r,2
  
et,3,SOLID164
r,3
  
mp,ex,1,30e6
mp,nuxy,1,0.29
mp,dens,1,2.28e-3
tb,biso,1,1
tbdata,1,30e3,100e3
edmp,hgls,1,5
  
mp,ex,2,30e6
mp,nuxy,2,0.29
mp,dens,2,2.28e-3
edmp,rigid,2,6,7
  
mp,ex,3,30e6
mp,nuxy,3,0.29
mp,dens,3,2.28e-3
edmp,rigid,3,7,7
  
wpoffs,,-0.069
wprota,,-90
rectng,-0.99,-0.01,0.01,0.49
  
type,1
mat,1
real,1
lesize,1,,,10,1
lesize,2,,,5,1
lesize,3,,,10,1
lesize,4,,,5,1
amesh,1
  
wpcsys,-1,0
wpstyl
esize,0.1
  
k, 11, 0.00, 0.00, 0.00
k, 12, 0.00, 0.50, 0.00
k, 13,-1.00, 0.50, 0.00
k, 14,-1.00, 0.10, 0.00
k, 15, 0.50, 0.05, 0.00
  
k, 16, 0.00,-0.50, 0.00
k, 17, 0.00,-0.20, 0.00
k, 18,-1.00,-0.10, 0.00
k, 19,-1.00,-0.50, 0.00
k, 20, 0.50,-0.15, 0.00
  
l,11,12
l,12,13
l,13,14
larc,14,11,15,6
al,5,6,7,8
mat,2
amesh,2
  
l,16,17
larc,17,18,20,6
l,18,19
l,19,16
al,9,10,11,12
mat,3
amesh,3
  
esize,,5
mat,2
type,2
voffst,2,-0.5
aclear,2
  
mat,3
type,3
voffst,3,-0.5
aclear,3
eplot
  
edwrite,pcreate
edwrite,plist
edcgen,assc
  
fini
/solu
  
esel,s,mat,,1
cm,eblank,elem
nsle
cm,nblank,node
nsel,r,loc,x,-0.995,-0.985
nsel,u,loc,z,-0.485,-0.015
d,all,ux,0.0
nsel,r,loc,z,-0.495,-0.485
d,all,uz,0.0
  
esel,s,mat,,2
cm,epunch,elem
nsle
cm,npunch,node
  
esel,s,mat,,3
cm,edie,elem
nsle
cm,ndie,node
  
nsel,all
esel,all
  
! Punch displacement function = (amplitude*cos(omega*time))-amplitude
  
*dim,time1,,101,1,1           ! dimension array for time
*dim,disp1,,101,1,1           ! dimension array for punch displacement
  
curtime=0.0                   ! initialize current time to zero
tottime=0.0101                ! total load curve time, seconds
deltime=tottime/100.0         ! time increment, seconds
amp1=0.0825                   ! displacement amplitude, inches
omega1=180.0/tottime          ! product of this constant and time = wt  
*afun,deg                     ! work in degrees
  
*do,i,1,101,1
   time1(i,1,1)=curtime
   disp1(i,1,1)=(amp1*cos(omega1*curtime))-amp1  ! maximum uy = -0.165"
   curtime=curtime+deltime
*enddo
  
edload,add,rbuy,,2,time1,disp1,0      ! punch = part number 2
  
time,0.01
edrst,50
edhtime,100
edhist,nblank
edhist,eblank
edenergy,1,1,1,1
edout,glstat
  
save
eplot
SAVE
/STAT,SOLU   
SOLVE   
ESEL,S,MAT,,1   
NSLE,S   
FINISH   
/POST1   
SET,LAST
!*   
/DSCALE,1,1.0   
/REPLOT  
!*   
!*   
PLNS,S,EQV   
ANDATA,0.5, ,0,1,51,5,0,0   
!*   
FINISH   
/POST26  
NUMVAR,30,   
FILE,stamp,his,  
!*   
!*   
!*   
!*   
NSOL,2,2,U,Y,node2uy
!*   
STORE,MERGE, ,   
PLVAR,2, , , , , , , , , ,   
ALLSEL,ALL   
SAVE
!*   
!*   
FINISH   
/FILNAM,spring   
!*   
/PREP7   
ETCHG,ETI   
!*   
TBDELE,ALL,ALL, ,   
SHPP,OFF
!*   
UPGEOM,1,1,51,stamp,rst,
!*   
EPLOT   
ESEL,S,MAT,,1   
NSLE,S   
EPLOT   
FINISH   
/SOLU   
FLST,2,2,1,ORDE,2   
FITEM,2,1   
FITEM,2,17   
!*   
/GO  
D,P51X, ,0.0, , , ,UY, , , , ,   
RIMPORT,DYNA,STRESS,ELEM,1,51,stamp,rst,
!*   
NLGEOM,1
NROPT,AUTO, ,   
LUMPM,0  
EQSLV,SPAR, ,0,  
PREC,0   
PIVCHECK,1   
SSTIF   
PSTRES   
TOFFST,0,   
!*   
SAVE
/STAT,SOLU   
SOLVE   
FINISH   
/POST1   
SET,LAST
!*   
/DSCALE,1,10.0
/REPLOT  
!*   
*SET,_ZF,1   
AVPRIN,0,0,  
!*   
/EFACE,_ZF   
PLNSOL,U,SUM,2,1
FINISH   
!*   
! /EXIT,NOSAV  

songlongzi

谢谢abcdefghijk 提供的命令流文件！偶觉得收益颇多，再次感谢！
希望在论坛上多有一些这样的源程序供参考研究，呵呵~！这样大家进步才会快。