复合材料的胶结问题。请大家帮忙啊，不胜感激！

skee2010

本人正在做本科毕业设计，遇到复合材料胶结问题，请大家帮忙啊！:)

在T型接头中，各个部分采用不同的复合材料层合板，如下图所示。 红色和浅蓝色为层合板采用solid46划分网格。深蓝色部分为柔性树脂，采用solid92划分网格。左右绿色和紫色的部分也是层合板。现在需要将各个部分胶结起来，请问胶结的地方应该怎么处理呢？我使用的是接触中的bonded(always)，可是结果与实验结果相差很大。请问怎么办？

skee2010

焦急等待中。。。:)

yuanbiao

同求啊。。。

星球密探

胶结问题好像用的是czmesh，命令，但是帮助文档只有二维的没有三维的，我也找三维的怎么做，

星球密探

/COM,ANSYS MEDIA REL. 140 (11/26/2011) REF. VERIF. MANUAL: REL. 140
/VERIFY,VM248
/TITLE, VM248, DELAMINATION OF DOUBLE CANTILEVER BEAM - 2D PLANE STRAIN
C*** USING INTER202
/COM,   REF: ALFANO, G. AND CRISFIELD, M. A.,
/COM,   "FINITE ELEMENT INTERFACE MODELS FOR THE DELAMINATION ANALYSIS
/COM,   OF LAMINATED COMPOSITES: MECHANICAL AND COMPUTATIONAL ISSUES"
/COM,   INT. J. NUMER. METH. ENGNG 2001, 50:1701-1736.
/PREP7
ET,1,182                   !* 2D 4-NODE STRUCTURAL SOLID ELEMENT
KEYOPT,1,1,2               !* ENHANCE STRAIN FORMULATION
KEYOPT,1,3,2               !* PLANE STRAIN
ET,2,182
KEYOPT,2,1,2
KEYOPT,2,3,2
ET,3,202                   !* 2D 4-NODE COHESIVE ZONE ELEMENT
KEYOPT,3,3,2               !* PLANE STRAIN
MP,EX,4,1.353E5            !* E11 = 135.3 GPA
MP,EY,4,9.0E3              !* E22 =   9.0 GPA
MP,EZ,4,9.0E3              !* E33 =   9.0 GPA
MP,GXY,4,5.2E3             !* G12 =   5.2 GPA
MP,PRXY,4,0.24
MP,PRXZ,4,0.24
MP,PRYZ,4,0.46
GMAX = 0.004
TNMAX = 25                 !* TENSILE STRENGTH
TB,CZM,5,,,EXPO            !* COHESIVE ZONE MATERIAL
TBDATA,1,TNMAX,GMAX,1000.0
RECTNG,0,100,0,1.5         !* DEFINE AREAS
RECTNG,0,100,0,-1.5
LSEL,S,LINE,,2,8,2         !* DEFINE LINE DIVISION
LESIZE,ALL,0.75
LSEL,INVE
LESIZE,ALL, , ,200
ALLSEL,ALL
TYPE,1                     !* MESH AREA 2
MAT,4
LOCAL,11,0,0,0,0
ESYS,11
AMESH,2
CSYS,0
TYPE,2                     !* MESH AREA 1
ESYS,11
AMESH,1
CSYS,0
NSEL,S,LOC,X,30,100
NUMMRG,NODES
ESLN
TYPE,3
MAT,5
CZMESH,,,1,Y,0,            !* GENERATE INTERFACE ELEMENTS
ALLSEL,ALL
NSEL,S,LOC,X,100           !* APPLY CONSTRAINTS
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,1.5           !* APPLY DISPLACEMENT LOADING ON TOP
D,ALL,UY,10
NSEL,ALL
ESEL,ALL
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,-1.5          !* APPLY DISPLACEMENT LOADING ON BOTTOM
D,ALL,UY,-10
NSEL,ALL
ESEL,ALL
NLGEOM,ON
AUTOTS,ON
TIME,1
NSUBST,40,40,40
OUTRES,ALL,ALL
SOLVE                      !* PERFORM SOLUTION
FINISH
/POST26
NSEL,S,LOC,Y,1.5
NSEL,R,LOC,X,0
*GET,NTOP,NODE,0,NUM,MAX
NSEL,ALL
NSOL,2,NTOP,U,Y,UY
RFORCE,3,NTOP,F,Y,FY
PROD,4,3, , ,RF, , ,20
/TITLE,VM248, DCB: REACTION AT TOP NODE VERSES PRESCRIBED DISPLACEMENT
/AXLAB,X,DISP U (mm)
/AXLAB,Y,REACTION FORCE R (N)
/YRANGE,0,60
XVAR,2
PLVAR,4
PRVAR,UY,RF
*GET,TMAX,VARI,4,EXTREM,TMAX   !* TIME CORRESPONDING TO MAX RFORCE
FINISH
/POST1
SET, , , , ,TMAX               !* RETRIEVE RESULTS AT TMAX
NSEL,S,NODE, ,NTOP             !* SELECT NODE NTOP
*GET,RF_NTOP,NODE,NTOP,RF,FY   !* FY RFORCE AT NODE NTOP
*GET,UY_NTOP,NODE,NTOP,U,Y     !* DISP AT NODE NTOP CORRESPONDING TO RFORCE
RF_MAX = RF_NTOP*20            !* PLANE STRAIN OPTION AND WIDTH = 20 mm
SET,LAST                       !* RETRIEVE RESULTS AT LAST SUBSTEP
*GET,RF_END,NODE,NTOP,RF,FY    !* FY RFORCE AT NODE NTOP AT LAST SUBSTEP
*GET,UY_END,NODE,NTOP,U,Y      !* DISP AT NODE NTOP CORRESPONDING TO RFORCE
RF_END = RF_END*20             !* PLANE STRAIN OPTION AND WIDTH = 20 mm
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
*DIM,VALUE2,,2,3
LABEL(1,1) = 'RFORCE','DISP '
LABEL(1,2) = 'FY (N)','UY (mm)'
*VFILL,VALUE(1,1),DATA,60.0,1.0
*VFILL,VALUE(1,2),DATA,RF_MAX,UY_NTOP
*VFILL,VALUE(1,3),DATA,ABS(RF_MAX/60.0),ABS(UY_NTOP/1.0)
*VFILL,VALUE2(1,1),DATA,24,10.0
*VFILL,VALUE2(1,2),DATA,RF_END,UY_END
*VFILL,VALUE2(1,3),DATA,ABS(RF_END/24.0),ABS(UY_END/10.0)
SAVE,INF1
FINI
/CLEAR,NOSTART
/OUT,SCRATCH
ansys14帮助文档的一个例子，你看看吧

andy211

同样为胶接的处理问题发愁中……

文文

我最近也在做粘接分析