【原创】Workbench的焊接模拟过程（高斯移动热源）

一笑泯恩仇

       一直以来，都是用ANSYS经典做焊接模拟的，前两天用ANSYS Workbench做了一个焊接模拟过程，我查阅了很多文献和网络资料，没有人用Workbeach做焊接模拟，所以也不确定我做的是否完全正确，望高手斧正。

    问题阐述：三维平板堆焊焊接残余应力分析，先分析焊接温度场，然后转化为结构分析焊接残余应力，板材模型为0.2×0.2×0.006m，焊接速度10mm/s。考虑其对称性，建立了板材的一半模型进行分析。

    模型如图所示。

isjm

这是一个明显错误的分析，新手选择资料需慎重。

一笑泯恩仇

      靠近焊缝的部位网格要细化。

一笑泯恩仇

      对加热的表面named selection为A1、A2，因为后面的高斯热源加载采用的是APDL，为后面加高斯热源作准备。

一笑泯恩仇

      设置好瞬态热分析的步长和对流条件，插入Command定义高斯热源。

*DEL,_FNCNAME   
*DEL,_FNCMTID   
*DEL,_FNC_C1
*DEL,_FNC_C2
*DEL,_FNC_C3
*DEL,_FNCCSYS   
*SET,_FNCNAME,'GAOSI'   
*DIM,_FNC_C1,,1
*DIM,_FNC_C2,,1
*DIM,_FNC_C3,,1
*SET,_FNC_C1(1),2000
*SET,_FNC_C2(1),0.01   
*SET,_FNC_C3(1),0.007   
*SET,_FNCCSYS,0
! /INPUT,HANJIE.func,,,1
*DIM,%_FNCNAME%,TABLE,6,19,1,,,,%_FNCCSYS%   
! Begin of equation: Qm*exp(-3*({X}^2+({Y}-V*{TIME})^2)/R^2)
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), %_FNC_C2(1)%
*SET,%_FNCNAME%(5,0,1), %_FNC_C3(1)%
*SET,%_FNCNAME%(6,0,1), 0.0
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 0, 0, 0, 0  
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 0, 0, -1
*SET,%_FNCNAME%(0,3,1),   0, -3, 0, 1, -1, 2, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -1, 0, 3, 0, 0, -3
*SET,%_FNCNAME%(0,5,1), 0.0, -2, 0, 1, -3, 3, -1
*SET,%_FNCNAME%(0,6,1), 0.0, -1, 0, 2, 0, 0, 2  
*SET,%_FNCNAME%(0,7,1), 0.0, -3, 0, 1, 2, 17, -1
*SET,%_FNCNAME%(0,8,1), 0.0, -1, 0, 1, 18, 3, 1
*SET,%_FNCNAME%(0,9,1), 0.0, -4, 0, 1, 3, 2, -1
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 0, 2, 0, 0, -4
*SET,%_FNCNAME%(0,11,1), 0.0, -5, 0, 1, -4, 17, -1  
*SET,%_FNCNAME%(0,12,1), 0.0, -1, 0, 1, -3, 1, -5   
*SET,%_FNCNAME%(0,13,1), 0.0, -3, 0, 1, -2, 3, -1   
*SET,%_FNCNAME%(0,14,1), 0.0, -1, 0, 2, 0, 0, 19
*SET,%_FNCNAME%(0,15,1), 0.0, -2, 0, 1, 19, 17, -1  
*SET,%_FNCNAME%(0,16,1), 0.0, -1, 0, 1, -3, 4, -2   
*SET,%_FNCNAME%(0,17,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%_FNCNAME%(0,18,1), 0.0, -2, 0, 1, 17, 3, -1   
*SET,%_FNCNAME%(0,19,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: Qm*exp(-3*({X}^2+({Y}-V*{TIME})^2)/R^2)

D,A1,TEMP,%GAOSI%
D,A2,TEMP,%GAOSI%

一笑泯恩仇

      瞬态热分析设置完毕，然后就是求解，大概需要10分钟。
    不同时刻时的温度场结果：

一笑泯恩仇

      焊接温度场的动画：

一笑泯恩仇

      然后把瞬态热分析的结果转化为瞬态结构分析，把温度场作为焊接残余应力分析的热载荷。

一笑泯恩仇

      在瞬态结构分析模块里，设置好焊接约束条件，设置好时间和步长，读取每一步温度载荷作为热载荷进行结构分析，要注意设置热载荷读取的时间和结构分析时间一致（默认条件下结构分析读取热分析的最后一步作为热载荷）。
    求解时间大概半个小时，不同时刻的应力场分布：

一笑泯恩仇

      应力场的动态过程：

一笑泯恩仇

      不同时刻的焊接变形：

一笑泯恩仇

      焊接变形的动态过程：

一笑泯恩仇

      说明一下，以上只是Workbeach做的焊接模拟过程，没有选择随时间变化的热物理参数，结果当然也是不准确的。另外就是注意建模时的坐标，因为command里采用的是全局坐标系*SET,_FNCCSYS,0。我建模时的坐标：

一笑泯恩仇

      因为是表面堆焊，所以没有用到单元的杀死激活。
    最后贴出一个用ANSYS经典做的“三维平板堆焊焊接残余应力分析”的命令流，方便大家参考。

/FILNAME,weldingstress,0
/PREP7  
!定义焊接参数
L=1E-1      !焊件的长度
W=1E-1      !焊件的宽度
H=6E-3      !焊件的高度

U=20          !焊接电压
I=160         !焊接电流
V=0.01        !焊接速度   
YITA=0.7      !焊接热效率
R=0.007       !电弧有效加热半径
Q=U*I*YITA    !电弧热功率
Qm=3/3.1415/R**2*Q !加热斑点中心最大热流密度

ET,1,PLANE55
ET,2,SOLID70


MPTEMP,,,,,,,,  
MPTEMP,1,20
MPTEMP,2,200
MPTEMP,3,500
MPTEMP,4,750
MPTEMP,5,1000   
MPTEMP,6,1500   
MPTEMP,7,1700   
MPTEMP,8,2500
   
MPDATA,KXX,1,,50
MPDATA,KXX,1,,47
MPDATA,KXX,1,,40
MPDATA,KXX,1,,27
MPDATA,KXX,1,,30
MPDATA,KXX,1,,35
MPDATA,KXX,1,,40
MPDATA,KXX,1,,55
  
MPDATA,DENS,1,,7820
MPDATA,DENS,1,,7700
MPDATA,DENS,1,,7610
MPDATA,DENS,1,,7550
MPDATA,DENS,1,,7490
MPDATA,DENS,1,,7350
MPDATA,DENS,1,,7300
MPDATA,DENS,1,,7090

MPDATA,C,1,,460
MPDATA,C,1,,480
MPDATA,C,1,,530
MPDATA,C,1,,675
MPDATA,C,1,,670
MPDATA,C,1,,660
MPDATA,C,1,,780
MPDATA,C,1,,820   

MPDATA,EX,1,,2.05E11
MPDATA,EX,1,,1.87E11
MPDATA,EX,1,,1.5E11
MPDATA,EX,1,,0.7E11
MPDATA,EX,1,,0.2E11
MPDATA,EX,1,,0.19E2
MPDATA,EX,1,,0.18E2
MPDATA,EX,1,,0.12e2
  
MPDATA,PRXY,1,,0.28
MPDATA,PRXY,1,,0.29
MPDATA,PRXY,1,,0.31
MPDATA,PRXY,1,,0.35
MPDATA,PRXY,1,,0.4  
MPDATA,PRXY,1,,0.45
MPDATA,PRXY,1,,0.48
MPDATA,PRXY,1,,0.5

UIMP,1,REFT,,,20
MPDATA,ALPX,1,,1.1e-5   
MPDATA,ALPX,1,,1.22e-5  
MPDATA,ALPX,1,,1.39e-5  
MPDATA,ALPX,1,,1.48e-5  
MPDATA,ALPX,1,,1.34e-5  
MPDATA,ALPX,1,,1.33e-5  
MPDATA,ALPX,1,,1.32e-5  
MPDATA,ALPX,1,,1.31e-5  


TB,BISO,1,6,2,  
TBTEMP,20   
TBDATA,,220e6,0,,,,
TBTEMP,250  
TBDATA,,175e6,0,,,,
TBTEMP,500  
TBDATA,,80e6,0,,,,  
TBTEMP,750
TBDATA,,40E6,0,,,,   
TBTEMP,1000
TBDATA,,10E6,0,,,,   
TBTEMP,1500
TBDATA,,1E-5,0,,,,   



K,1,0,0,0
K,2,0,L,0
K,3,-W/2*0.15,L,0
K,4,-W/2*0.3,L,0
K,5,-W/2*0.5,L,0
K,6,-W/2,L,0
K,7,-W/2,0,0
K,8,-W/2*0.5,0,0
K,9,-W/2*0.3,0,0
K,10,-W/2*0.15,0,0
K,11,0,0,H

A,1,2,3,10
A,10,3,4,9
A,9,4,5,8
A,8,5,6,7


ESIZE,0.0012
AMESH,1

ESIZE,0.0025
AMESH,2

ESIZE,0.005
AMESH,3

ESIZE,0.0065
AMESH,4


TYPE,   2   
EXTOPT,ESIZE,2,0,   
EXTOPT,ACLEAR,1

EXTOPT,ATTR,1,0,0   
REAL,_Z4
ESYS,0  

VOFFST,1,H, ,  
VOFFST,2,H, ,
VOFFST,3,H, ,
VOFFST,4,H, ,     
EPLOT

NUMMRG,ALL, , , ,LOW


/SOL  
ANTYPE,4  
TRNOPT,FULL
LUMPM,0
*DEL,_FNCNAME   
*DEL,_FNCMTID   
*DEL,_FNC_C1
*DEL,_FNC_C2
*DEL,_FNC_C3
*DEL,_FNCCSYS   
*SET,_FNCNAME,'GAOSI'   
*DIM,_FNC_C1,,1
*DIM,_FNC_C2,,1
*DIM,_FNC_C3,,1
*SET,_FNC_C1(1),QM  
*SET,_FNC_C2(1),V   
*SET,_FNC_C3(1),R   
*SET,_FNCCSYS,0
! /INPUT,HANJIE.func,,,1
*DIM,%_FNCNAME%,TABLE,6,19,1,,,,%_FNCCSYS%  
!   
! Begin of equation: Qm*exp(-3*({X}^2+({Y}-V*{TIME})^2)/R^2)
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), %_FNC_C2(1)%
*SET,%_FNCNAME%(5,0,1), %_FNC_C3(1)%
*SET,%_FNCNAME%(6,0,1), 0.0
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 0, 0, 0, 0  
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 0, 0, -1
*SET,%_FNCNAME%(0,3,1),   0, -3, 0, 1, -1, 2, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -1, 0, 3, 0, 0, -3
*SET,%_FNCNAME%(0,5,1), 0.0, -2, 0, 1, -3, 3, -1
*SET,%_FNCNAME%(0,6,1), 0.0, -1, 0, 2, 0, 0, 2  
*SET,%_FNCNAME%(0,7,1), 0.0, -3, 0, 1, 2, 17, -1
*SET,%_FNCNAME%(0,8,1), 0.0, -1, 0, 1, 18, 3, 1
*SET,%_FNCNAME%(0,9,1), 0.0, -4, 0, 1, 3, 2, -1
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 0, 2, 0, 0, -4
*SET,%_FNCNAME%(0,11,1), 0.0, -5, 0, 1, -4, 17, -1  
*SET,%_FNCNAME%(0,12,1), 0.0, -1, 0, 1, -3, 1, -5   
*SET,%_FNCNAME%(0,13,1), 0.0, -3, 0, 1, -2, 3, -1   
*SET,%_FNCNAME%(0,14,1), 0.0, -1, 0, 2, 0, 0, 19
*SET,%_FNCNAME%(0,15,1), 0.0, -2, 0, 1, 19, 17, -1  
*SET,%_FNCNAME%(0,16,1), 0.0, -1, 0, 1, -3, 4, -2   
*SET,%_FNCNAME%(0,17,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%_FNCNAME%(0,18,1), 0.0, -2, 0, 1, 17, 3, -1   
*SET,%_FNCNAME%(0,19,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: Qm*exp(-3*({X}^2+({Y}-V*{TIME})^2)/R^2)  
TUNIF,20, !定义初始温度
!定义对流换热边界
SFA,15,1,CONV,30,20
SFA,20,1,CONV,30,20

SFA,9,1,CONV,30,20
SFA,14,1,CONV,30,20
SFA,19,1,CONV,30,20
SFA,24,1,CONV,30,20
SFA,23,1,CONV,30,20

SFA,7,1,CONV,30,20
SFA,12,1,CONV,30,20
SFA,17,1,CONV,30,20
SFA,22,1,CONV,30,20

SFA,1,1,CONV,30,20
SFA,2,1,CONV,30,20
SFA,3,1,CONV,30,20
SFA,4,1,CONV,30,20

!施加高斯热源  
SFA,5,1,HFLUX, %GAOSI%  
SFA,10,1,HFLUX, %GAOSI%  

OUTRES,ALL,ALL,

TIME,L/V !设置求解时间
AUTOTS,-1   
NSUBST,50,50,50
KBC,0   
TSRES,ERASE
LSWRITE,1,  !写入载荷文件为1
TIME,20
AUTOTS,1
NSUBST,20,20,20
KBC,0   
TSRES,ERASE
LSWRITE,2,

TIME,50
AUTOTS,1
NSUBST,30,30,30
KBC,0   
TSRES,ERASE
LSWRITE,3,

TIME,1100
AUTOTS,1
NSUBST,105,105,105
KBC,0     
TSRES,ERASE
LSWRITE,4,
  
LSSOLVE,1,4,1,  !开始求解

!进入热应力求解
/PREP7  
ETCHG,TTS !热到结构分析转换
/SOL
ANTYPE,4
TRNOPT,FULL
LUMPM,0
NLGEOM,1
NROPT,FULL, ,OFF
!定义热应力计算参考温度
TREF,20,

DA,6,SYMM

DL,13, ,UY,   
DL,10, ,UY,
DL,7, ,UY,   
DL,4, ,UY,  
DL,1, ,UZ,   
  

*DO,I,1,50
LDREAD,TEMP,,,0.2*I, ,'weldingstress','rth',' ' !读入热分析的计算结果
OUTRES,ALL,ALL,
TIME,0.2*I
DELTIM,0.2,0.075,0.2,1
SOLVE
*ENDDO

*DO,I,1,20
LDREAD,TEMP,,,10+I*0.5, ,'weldingstress','rth',' '
OUTRES,ALL,ALL,
TIME,10+I*0.5
DELTIM,0.5,0.5,1,1
SOLVE
*ENDDO

*DO,I,1,30
LDREAD,TEMP,,,20+I, ,'weldingstress','rth',' '
OUTRES,ALL,ALL,
TIME,20+I
DELTIM,1,1,1,1
SOLVE
*ENDDO

*DO,I,1,105
LDREAD,TEMP,,,50+10*I, ,'weldingstress','rth',' '
OUTRES,ALL,ALL,
TIME,50+10*I
DELTIM,10,10,10,1
SOLVE
*ENDDO

zhcaifeifei

一笑泯恩仇 发表于 2012-12-21 18:46
因为是表面堆焊，所以没有用到单元的杀死激活。
    最后贴出一个用ANSYS经典做的“三维平板堆焊焊接 ...

这个命令流是我的书上写的：有限元分析—ANSYS 13.0从入门到实战 谢谢支持

一笑泯恩仇

zhcaifeifei 发表于 2012-12-21 19:03
这个命令流是我的书上写的：有限元分析—ANSYS 13.0从入门到实战 谢谢支持

对的，很好的一本书，我前段时间买的。我在另一个帖子里注明过这个例子的出处：http://forum.simwe.com/forum.php?mod=viewthread&tid=833058&page=1#pid2936162。
我就是看到这个例子，突发奇想，用workbench做了一下。您是这本书的作者么？敬仰一下。

andy312500

一笑泯恩仇 发表于 2012-12-21 18:32
在瞬态结构分析模块里，设置好焊接约束条件，设置好时间和步长，读取每一步温度载荷作为热载荷进行结 ...

楼主大人。。。焊接约束条件你是怎样设置的呀？？？？

一笑泯恩仇

andy312500 发表于 2012-12-31 19:39
楼主大人。。。焊接约束条件你是怎样设置的呀？？？？

DL,13, ,UY,   
DL,10, ,UY,
DL,7, ,UY,   
DL,4, ,UY,  
DL,1, ,UZ,

我给的APDL里的约束，是约束底面两条线的Y轴，和焊缝处中心线的Z轴。

一笑泯恩仇

这个例子只是一个在workbench中实现焊接过程的模拟，真是焊接约束应该是对工件上下两个面约束。

andy312500

一笑泯恩仇 发表于 2012-12-31 20:46
这个例子只是一个在workbench中实现焊接过程的模拟，真是焊接约束应该是对工件上下两个面约束。 ...

我问的是你Workbench模拟的那个约束！你约束了上下两个面？？

一笑泯恩仇

andy312500 发表于 2012-12-31 21:22
我问的是你Workbench模拟的那个约束！你约束了上下两个面？？

我约束的是底面的两条线，但是这个约束对于焊接来说是不对的，只是一个过程示意。