本帖最后由 jasonyfl 于 2013-1-20 20:03 编辑
FINISH
/CLEAR
/FILNAM,SingleCantilever_Piezo_Harvester !2013-01-19 只一根梁的!!!修改悬臂梁的形状成为宽质量块 ,耦合电阻
/TITLE,SingleCantilever_Piezo_Harvester_2013-01-19
/prep7
mp,DENS,1,7500 ! 密度, kg/m**3
mp,perx,1,3130 ! 介电常数
mp,pery,1,3130
mp,perz,1,3400
! 这里用的材料的系数是PZT-5H
tb,ANEL,1,1,,1 ! Anisotropic elastic stiffness, N/m^2 第一个1代表材料1号材料,第二个如是 1代表的是柔度矩阵,0代表的是刚度矩阵
TBDATA,1,16.5e-12,-4.78e-12,-8.45e-12 ! s11,s13,s12
TBDATA,7,16.5e-12,-8.45e-12 ! s33,s13
TBDATA,12,20.7e-12 ! s11
TBDATA,16,43.5e-12 ! s44
TBDATA,19,43.5e-12 ! s44
TBDATA,21,42.6e-12 ! s66
tb,PIEZ,1 ! 压电(应力)常数, C/m^2
TBDATA,3,-6.622 ! e31
TBDATA,6,-6.622 ! e31
TBDATA,9,23.24 ! e33
TBDATA,11,17.034 ! e15
TBDATA,13,17.394 ! e15
!*SET,V,100 !作为致动器模拟,其电压为100伏
!*SET,Uz,30e-6 !位移为30e-6米
!*SET,d31,2.2e-11
mp,dens,2,2330 !定义材料密度
EX,2,140e9 !定义材料杨氏模量
nuxy,2,0.23
*SET,L,2000e-6 !PZT的长度
*SET,W,100e-6 !PZT的宽度
*SET,H ,2e-6 !PZT的厚度
*SET,LK,600e-6 !PZT前端的质量块的的长度,K代表块
*SET,WK,200e-6 !PZT前端的质量块的的宽度
*SET,H2,10e-6 !硅的厚度 硅层的长度,宽度,前端的质量块的长度,宽度都与PZT相同
*SET,L1,600e-6 !硅质量块的长度
*SET,K1,200e-6 !硅质量块宽度
*SET,H1,190e-6 !硅质量块厚度
!电路元件参数
*SET,R,100e6 !R 代表电阻的阻值
!PZT层建模
block,0,L,0,W,0,H !x1,x2,y1,y2,z1,z2
block,L,L+LK,-0.5*(WK-W),0.5*(WK+W),0,H
!硅层建模
block,0,L,0,W,0,-H2
block,L,L+LK,-0.5*(WK-W),0.5*(WK+W),0,-H2
!硅质量块建模
block,L,L+LK,-0.5*(WK-W),0.5*(WK+W),-H2,-(H1+H2)
vglue,all !将梁同压电片粘结
et,1,solid226,1001 !定义压电单元 3-D coupled-field brick, piezo option
! et,1,SOLID5,3 ! lower order 3-D coupled-field brick, piezo option
et,2,solid95 !定义主结构单元
!et,1,solid5,3 !定义压电单元
!et,2,solid45 !定义主结构单元
LESIZE,ALL,3e-5, , , ,1, , ,1, !为线指定网格尺寸
mat,1 !PZT层(材料1)的网格划分
type,1 !对中间结构网格划分
Vsweep,1
mat,1
type,1 !对中间结构网格划分
Vsweep,8
mat,2
type,2 !对硅材料网格划分
Vsweep,6
mat,2
type,2 !对硅材料网格划分
Vsweep,7
mat,2
type,2 !对硅材料网格划分
Vsweep,9
nsel,s,loc,z,H
nsel,r,loc,x,L+LK
*get,ntip,node,0,num,min ! 获得梁1端部 控制点坐标 (顶端最上方点)
nsel,s,loc,x,0
*get,root,node,0,num,min ! 获得梁根部 控制点坐标
nsel,s,loc,z,H
nsel,r,loc,x,0.2*L
*get,midbeampt,node,0,num,min ! 获得梁根部 控制点坐标
nsel,s,loc,z,H
nsel,r,loc,x,0.5*L
*get,qudbeampt,node,0,num,min ! 获得梁根部 控制点坐标
nsel,s,loc,z,0 ! 定义下电极
cp,1,volt,all
*get,n_bot,node,0,num,min
nsel,s,loc,z,H ! 定义上电极
cp,2,volt,all
*get,n_top,node,0,num,min
! element types
et,3,circu94,0 ! 加一个电阻到电路中来
r,1,R !电阻实数值 R
!n,10556,-100e-6,w/2,-100e-6 !创建节点单元,节点号为1,坐标x=0,y=0
!n,10557,-100e-6,w/2, 100e-6
type,3 $ real 1 !给circu94单元,作为电阻赋初值
e,n_top,n_bot !电阻串联的节点
/ICSCALE,1,0.1 !; ; ; ;!Scale circuit elements to correct size
finish
/solu
ANTYPE,MODAL
MODOPT,LANB,6
MXPAND,6, , ,yes,,yes
nsel,s,loc,x,0
d,all,ux,0,,,,uy,uz
nsel,all
!d,n_top,volt,0 !上下层电极短路
d,n_bot,volt,0
nsel,all
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
*GET,FREQ4,MODE,4,FREQ
*GET,FREQ5,MODE,5,FREQ
*GET,FREQ6,MODE,6,FREQ
finish
|