找回密码
 注册
Simdroid-非首页
查看: 1705|回复: 22

[ANSYS/LS-DYNA] 地震作用下水箱晃动分析(原创,附命令流和K文件)

[复制链接]
发表于 2014-2-13 18:50:39 | 显示全部楼层 |阅读模式 来自 江苏徐州
本帖最后由 shifang157300 于 2017-4-16 17:29 编辑

地震作用下水箱晃动分析(原创,附命令流和K文件)
问题探讨:作者 - 师访,QQ - 1549221758Email- pomato157300@126.com


最近用ANSYS LS-DYNA做了个地震载荷作用下(唐山地震数据)水箱晃动的练习,分享给大家。由于液面晃动不明显,所以采用Lagrange构型,没有用Euler或ALE,如有疑问,欢迎交流:QQ:1549221758
APDL命令流:
地震加速度数据,单位是cm/s^2:
k文件:
筒体为钢,shell163单元,水体为solid164,与筒体共节点。
水的状态方程参数取自文献:Numerical Simulation of 2D Sloshing by using ALE2D Technique of LS-DYNA and CCUP Methods

液面的晃动,z方向位移云图:


液面中心相对位移:


地震加速度载荷:

!****************************************************************
!----      师访,中国矿业大学力学与建筑工程学院,江苏徐州    ----
!----      SHI Fang, China University of Mining & Technology ----
!----      Website: www.betaxfem.com, QQ: 1549221758         ----
!----      Email: fshi@cumt.edu.cn / 15996873039@126.com     ----
!----      Date: February 11, 2014                           ----
!****************************************************************
finish
/clear
/FILNAME,Sloshing-of-the-water-tank-Lagrange,1
/prep7
/Titie,Sloshing of the water tank
/DSCALE,ALL,1
/eshape,1
!---------视角调整
/VIEW,1,1,1,1   
/ANG,1  
/REP,FAST   
/ANG,1,-120,ZS,1
/REP,FAST   
!---------背景色
/RGB,INDEX,100,100,100, 0   
/RGB,INDEX, 80, 80, 80,13   
/RGB,INDEX, 60, 60, 60,14   
/RGB,INDEX, 0, 0, 0,15  
/REPLOT
!****************************************************************
!---------------------------控制参数-----------------------------
!****************************************************************
ShockTime    = 5       !地震持续时间
TotalTime    = 10      !总时间
!---------
Thickness=10e-3  !筒体的厚度
HeightB=5        !筒体的高度
RadiusB=5        !筒体的半径
!---------
HeightW=2.5      !液面的高度
!---------
meshSize=HeightB/11  !网格控制,要确保原点位置处存在节点,也就是中心四边形的单元划分数为偶数
!---------
MassScale   =5e-7       !质量缩放控制
!****************************************************************
!--------------------------单元和实常数--------------------------
!****************************************************************
ET,1,SOLID164    !用于模拟水的实体单元
KEYOPT,1,1,1
KEYOPT,1,5,0     !Lagrange构型
ET,2,SHELL163    !用于模拟筒体的壳单元
R,1,5/6,2,Thickness,Thickness,Thickness,Thickness,
!****************************************************************
!----------------------------材料参数----------------------------
!****************************************************************
!---1:Steel---             !钢桶的材料属性
MP,DENS,1,7850
MP,EX,1,210e9
MP,NUXY,1,0.3  
TB,BKIN,1,,,,   
TBDAT,1,250e6,21e9
!---2:Water---             !水的材料属性
MP,DENS,2,1000
TB,EOS,2,,,2,1   
TBDAT,16,0  
TBDAT,17,2.002e9
TBDAT,18,8.436e9
TBDAT,19,8.010e9
TBDAT,20,0.4395
TBDAT,21,1.3937
TBDAT,22,0  
TBDAT,23,2.067e5
TBDAT,24,1  
!---3:桶底----             !桶底为刚体
EDMP,RIGI,3,0,0
MP,DENS,3,7850
MP,EX,3,210e9
MP,NUXY,3,0.3   
!****************************************************************
!--------------------------建模及网格划分------------------------
!****************************************************************
CYL4,0,0,RadiusB, , , ,HeightW  !建立水体
CSYS,4
wpro,45.0,,
BLC5,0,0,RadiusB/2,RadiusB/2,HeightW!建立立方体,用于切割,以便划分均匀大小的网格
VSBV,1,2
BLC5,0,0,RadiusB/2,RadiusB/2,HeightW
VGLUE,ALL
!---------
wpro,-45.0,,
wpro,,,90.000000
vsel,s,,,2,4,1
VSBW,all
wpro,,90.0,
allsel
vsel,s,,,3,4,1
VSBW,all
allsel
!---------
WPCSYS,-1,0
k,100,0,0,HeightW
k,101,0,0,HeightB
l,100,101
allsel
lsel,s,,,5,8,1
ADRAG,all, , , , , , 21   
allsel
!---------给水划分网格
vatt,2,,1,,,
MSHAPE,0,3D
MSHKEY,1
lesize,all,meshSize             !网格密度
vmesh,all
!---------给钢桶边划分网格
allsel
asel,s,,,7,8,1
asel,a,,,11,12,1
asel,a,,,17,20,1
MSHAPE,0,2D
MSHKEY,1
aatt,1,1,2,,,
amesh,all
!---------给钢桶底边划分网格
allsel
asel,s,,,1,3,2
asel,a,,,16,
asel,a,,,23,25,2
aatt,3,1,2,,,
amesh,all
!---------建立节点集合
allsel
cm,allstuff,node
!---------
allsel
asel,s,,,1,3,2
asel,a,,,16,
asel,a,,,23,25,2
CM,BottomA,AREA      !创建桶底面集合BottomA
NSLA,S,1
NSEL,R,LOC,X,0  
NSEL,R,LOC,Y,0  
CM,Bottom,node       !创建桶底集合Bottom,由于是刚体,所以只需一个节点
!****************************************************************
!----------------------------边界条件----------------------------
!****************************************************************
!
WPCSYS,-1,0
CSYS,0
DA,BottomA,UZ,         !约束桶底竖向位移
allsel
!
!---------建立加速度表
!---------重力加速度,施加到allstuff
*DIM,timeZ,ARRAY,2,1,1, , ,  
*SET,timeZ(2,1,1) , TotalTime
*DIM,ACCGZ,ARRAY,2,1,1, , ,  
*SET,ACCGZ(1,1,1) , 9.8  
*SET,ACCGZ(2,1,1) , 9.8  
edload,add,ACLZ,,allstuff,timeZ,ACCGZ
!
!---------地震加速度,施加到Bottom
tnum=TotalTime/0.01+1
dnum=ShockTime/0.01+1          !地震波数据间隔是0.01s,总数据个数为dnum
*dim,eqw,array,tnum,1,1,,,
*VREAD,eqw,Earthquake-wave,dat,,,,,,0,
(e16.0)
*dim,time,array,tnum,1,1,,,
*do,i,1,tnum,1
    time(i,1,1)=(i-1)*0.01
    *if,i,le,dnum,then
        eqw(i,1,1)=0.01*eqw(i,1,1) !加速度单位从cm/s^2转换成m/s^2
    *else
        eqw(i,1,1)=0
    *endif
*enddo
edload,add,ax,0,Bottom,time,eqw
!edload,add,vx,0,Bottom,time,eqw
finish
!
!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
!-------------------------Solution-------------------------------
!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
!
/solution
time,TotalTime
!---------
!EDOPT,ADD,blank,LSDYNA
EDWRITE,BOTH
EDRST,200,   
EDHTIME,10
EDENERGY,1,1,1,1          !turn all energy options on
!EDCTS,-MassScale,        !质量缩放
!---------
solve
save
finish
!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
!----------------------------POST1-------------------------------
!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
/post1
set,last
!---------绘制位移云图(sum)
PLNSOL, U,SUM, 0,1.0
!---------保存动画
!PLNS,U,SUM  
!ANTIME,100,0.2, ,1,0,0,0
!/ANFILE,save,Usum,avi
finish
!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
!----------------------------POST26------------------------------
!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
/post26
!---------
!水面中心节点号
allsel
ESEL,S,MAT,,2   
NSLE,R  
NSEL,R,LOC,X,0  
NSEL,R,LOC,Y,0  
NSEL,R,LOC,Z,HeightW
*get,numWaterCer,Node,0,num,max
!---------
!钢桶底部中心节点号
allsel
ESEL,S,MAT,,3   
NSLE,R  
NSEL,R,LOC,X,0
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,0
*get,numBottCer,Node,0,num,max
!---------
allsel
NSOL,2,numWaterCer,U,X, UX_2        !水面中心的x方向绝对位移
NSOL,3,numWaterCer,V,X, VX_3        !水面中心的x方向绝对速度
NSOL,4,numWaterCer,A,X, AX_4        !水面中心的x方向绝对加速度
!---------
NSOL,22,numBottCer,U,X, UX_22       !钢桶底部中心的x方向绝对位移
NSOL,23,numBottCer,V,X, VX_23       !钢桶底部中心的x方向绝对速度
NSOL,24,numBottCer,A,X, AX_24       !钢桶底部中心的x方向绝对加速度
!---------计算相对值
ADD,25,2,22,,absWaUx,,,1,-1,1,      !水面中心的x方向相对位移
ADD,26,3,23,,absWaVx,,,1,-1,1,      !水面中心的x方向相对速度
ADD,27,4,24,,absWaAx,,,1,-1,1,      !水面中心的x方向相对加速度
!---------
XVAR,1  
!---------
PLVAR,25,


我的帖子汇总:
(1)扩展有限元法(XFEM)漫谈(原创_持续更新):http://forum.simwe.com/thread-1245357-1-1.html
(2)ANSYS UPFs二次开发教程(原创,持续更新):http://forum.simwe.com/thread-1021888-1-1.html
(3)比特币(Bitcoin)价格波动曲线监控程序_基于Python编写__原创:http://forum.simwe.com/thread-1254734-1-1.html
(4)地震作用下水箱晃动分析(原创,附命令流和K文件):http://forum.simwe.com/thread-1098856-1-1.html
(5)ANSYS常用单元特性总结及简单实例(原创):http://forum.simwe.com/thread-1019487-1-1.html
(6)ANSYS计算受压闭合裂纹的应力强度因子实例命令流(原创):http://forum.simwe.com/thread-1102153-1-1.html
(7)(原创)利用Matlab对ANSYS数据进行后处理实例:http://forum.simwe.com/thread-1094497-1-1.html
(8)(原创)ANSYS跌落分析全命令流模板:http://forum.simwe.com/thread-1093360-1-1.html
(9)钢球入水后反弹CEL流固耦合3D模拟,附CAE文件(原创):http://forum.simwe.com/thread-1107014-1-1.html
(10)ANSYS16.0新增扩展有限元XFEM裂纹扩展仿真简介(原创):http://forum.simwe.com/thread-1121373-1-1.html
(11)FEAPpv简介、Linux下的编译及运行方法_原创: http://forum.simwe.com/thread-1136956-1-1.html
(12)基于ANSYS的结构地震分析教程 (静力+模态+反应谱+时程) http://forum.simwe.com/thread-1176187-1-1.html

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

×

评分

2

查看全部评分

发表于 2014-2-14 09:29:04 | 显示全部楼层 来自 山东淄博
Simdroid开发平台
很不错,原创精品,学习学习
回复 不支持

使用道具 举报

发表于 2014-4-30 19:51:58 | 显示全部楼层 来自 北京
大神你好,可否向你请教一些关于液面晃动模态和频率的问题?
你的这个“地震作用下水箱晃动分析”中有一条命令流在ANSYS中不能执行,需要进行手动操作。
*VREAD,eqw,Earthquake-wave,dat,,,,,,0,
(e16.0)
回复 不支持

使用道具 举报

 楼主| 发表于 2014-4-30 19:53:42 | 显示全部楼层 来自 上海
子沐轩神殇 发表于 2014-4-30 19:51
大神你好,可否向你请教一些关于液面晃动模态和频率的问题?
你的这个“地震作用下水箱晃动分析”中有一条 ...

*VREAD命令只能通过read input from执行,不能复制粘贴运行
回复 不支持

使用道具 举报

发表于 2014-4-30 20:09:20 | 显示全部楼层 来自 北京
嗯,是的。
想问你一些关于含液容器的晃动模态和频率的问题,我想通过模态分析来分析液体对自振频率的影响,但目前在网上找的算例都不能提取液体自由液面在振动中的振动变化。
请问版主有没有这方面的帖子和可用于学习的例子?
回复 不支持

使用道具 举报

 楼主| 发表于 2014-4-30 20:22:38 | 显示全部楼层 来自 上海
子沐轩神殇 发表于 2014-4-30 20:09
嗯,是的。
想问你一些关于含液容器的晃动模态和频率的问题,我想通过模态分析来分析液体对自振频率的影响 ...

这个我没做过
回复 不支持

使用道具 举报

发表于 2014-4-30 20:27:52 | 显示全部楼层 来自 北京

谢谢,买过你的那本ANSYS二次开发,还在学习中,以后还要向版主多多请教!
回复 不支持

使用道具 举报

 楼主| 发表于 2014-4-30 20:31:46 | 显示全部楼层 来自 上海
子沐轩神殇 发表于 2014-4-30 20:27
谢谢,买过你的那本ANSYS二次开发,还在学习中,以后还要向版主多多请教! ...

嗯,共同学习,一起进步
回复 不支持

使用道具 举报

发表于 2014-7-17 21:27:20 | 显示全部楼层 来自 江苏南京
仔细看了版主的作品,因为最近我也在做水箱晃动,我想用SPH去模拟水,还没摸透,我就想问下版主,为什么你这个例子没有设置接触呢?请教下大神
回复 不支持

使用道具 举报

 楼主| 发表于 2014-7-17 23:15:49 | 显示全部楼层 来自 江苏南京
shanghonglei1 发表于 2014-7-17 21:27
仔细看了版主的作品,因为最近我也在做水箱晃动,我想用SPH去模拟水,还没摸透,我就想问下版主,为什么你 ...

这个是共节点的,不是欧拉法
回复 不支持

使用道具 举报

发表于 2014-7-18 14:59:16 | 显示全部楼层 来自 江苏南京
shifang157300 发表于 2014-7-17 23:15
这个是共节点的,不是欧拉法

帖子里提到的lagrange构型是不是说在solid164中设置的?如果筒体与水不共节点,而是设置成两个part,然后设置接触,这样可行吗?回与帖子里的例子有什么不同?望指导下
回复 不支持

使用道具 举报

发表于 2014-9-3 18:38:56 | 显示全部楼层 来自 广东
学习了,楼主太牛了
回复 不支持

使用道具 举报

发表于 2014-10-14 09:54:13 | 显示全部楼层 来自 吉林长春
楼主请教一下,求解完之后没有solution is done, 而且查看不了结果是怎么回事
回复 不支持

使用道具 举报

发表于 2014-11-10 21:58:25 | 显示全部楼层 来自 北京

北京科技大学,学报上有个文章,是关于这个问题的,你可以参考一下,液体对地震作用有削减,但是不是特别明显,我也在研究这个问题,qq445696385,可以共同探讨
回复 不支持

使用道具 举报

发表于 2015-8-10 20:02:15 | 显示全部楼层 来自 台湾
LS-DYNA 也能做這个呀??? 学習了。
不过想了想,用LS-DYNA做,和实务差多少呢?
回复 不支持

使用道具 举报

发表于 2015-11-4 11:12:34 | 显示全部楼层 来自 陕西西安
关于地震模拟有有另外一种加载方式,算自创的(自己琢磨的还是借鉴的给忘了),分享一下。
1.观察k文件地震载荷数组规律,发现列数据之间有一个制位表(一个tab,即四个字符),第一列数前有两个制位表。
2.将地震数据(excel格式),第一列时间,第二列数组处理,并在格式里面设定12位的科学数。
3.此地震数据另存为制位表txt格式,在notepad++中打开,选定全体,设置制位表占位符数位4,全体缩进两个tab,即可生成与之前k文件相同格式的地震载荷数组,替换之即可。
本人成功用此法模拟6,7,8,9度地震。
本评论旨在交流,希望高人能给于指点与批评。
回复 不支持

使用道具 举报

发表于 2016-5-18 22:09:15 | 显示全部楼层 来自 江苏南京
楼主,请教下如果用ALE做的话,罐底和水是否需要共节点(罐子侧面和水呢)
回复 不支持

使用道具 举报

发表于 2016-12-9 23:46:39 | 显示全部楼层 来自 天津
楼主知道在ABAQUS里怎么实现你现在这个研究吗
回复 不支持

使用道具 举报

发表于 2017-9-28 12:36:30 | 显示全部楼层 来自 四川成都
大神,你好,我想请教一下,为啥dyna中r5.0中还有*SECTION_SOLID_ALE,而到了6.0中就将这个关键字删除掉了呢?那在6.0中要用ALE来做流固耦合该怎么做呢?能赐教一下吗?
回复 不支持

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|小黑屋|联系我们|仿真互动网 ( 京ICP备15048925号-7 )

GMT+8, 2024-3-29 19:56 , Processed in 0.063136 second(s), 15 queries , Gzip On, MemCache On.

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表