找回密码
 注册
Simdroid-非首页
查看: 650|回复: 4

[问题讨论] 【转帖】梁壳体连接情况的讨论

[复制链接]
发表于 2002-9-15 21:03:19 | 显示全部楼层 |阅读模式 来自 湖北武汉
梁壳体连接情况的讨论  
1 按“杆梁壳体”的顺序,只要后一种单元的自由度完全包容了前一种单元的自由度,则有公用结点即可,不需要约束方程。例如:  
     杆与梁、壳、体有公用结点即可,不需要写约束方程;  
     梁与壳有公用结点即可,不需要写约束方程;  
     梁与体则要同位置的不同结点,需要耦合自由度和约束方程;  
     壳与体则要同位置的不同结点,需要耦合自由度和约束方程;  
2 壳梁自由度数目相同,自由度也相同,尽管壳的rotz是虚的自由度,也不妨碍二者之间的关系,这有点类同于梁与杆的关系。  
3 尽管可以采用耦合自由度和约束方程,但建议尽量不同时采用多种单元于一个结构中,除非你对结果的正确性有十足的把握。  
4 当然,采用约束方程可能存在应力集中点,不必在意此点的应力。  
5 我自认为是正确的,希望各位大侠批评指正。  
6 为说明上述说法的正确性,这里提供有5个小例子。例1是全“壳单元”,例2是“梁壳单元”;例3是全“体单元”,例4是“体梁单元”,例5是“体壳单元”。  
7 运行于ansys6.1下,三月雨提供。  
!**********************************************  
!梁壳的耦合问题小算例  
!采用壳单元时exam1  
/prep7  
et,1,shell63  
mp,ex,1,3e5  
mp,prxy,1,0.0  
r,1,1.0  
wprota,0,90  
blc4,,,120,10  
aesize,all,2  
mshape,0,2d  
mshkey,1  
amesh,all  
/view,1,1,1,1  
/ang,1  
eplot  
nsel,s,loc,x,0  
d,all,all  
nsel,s,loc,x,120  
*get,nhzs,node,,count  
f,all,fy,-3/nhzs  
allsel,all  
/solu  
solve  
!**********************************************  
!梁壳的耦合问题小算例  
!采用梁壳单元时exam2  
/prep7  
et,1,shell63  
et,2,beam4  
mp,ex,1,3e5  
mp,prxy,1,0.0  
r,1,1.0  
r,2,10.0,10/12.0,1000/12.0,10.0,1.0  
wprota,0,90  
blc4,,,60,10  
wpoff,,5  
wprota,,90  
asbw,all  
k,100,120,0,5  
ksel,s,loc,x,60,120  
ksel,r,loc,z,5  
*get,kp1,kp,,num,min  
kp2=kpnext(kp1)  
l,kp1,kp2  
ksel,all  
wpcsys,-1  
lsel,s,loc,x,60,120  
latt,1,2,2  
lesize,all,,,10  
lmesh,all  
asel,all  
aatt,1,1,1  
aesize,all,2  
mshape,0,2d  
mshkey,1  
amesh,all  
allsel,all  
/view,1,1,1,1  
/ang,1  
eplot  
finish  
!------------------------  
/solu  
nsel,s,loc,x,0  
d,all,all  
nsel,s,loc,x,120  
f,all,fy,-3.0  
allsel,all  
solve  
/post1  
etable,zl1,smisc,1  
etable,zl2,smisc,7  
etable,jly1,smisc,2  
etable,jly2,smisc,8  
etable,jlz1,smisc,3  
etable,jlz2,smisc,9  
etable,mx1,smisc,4  
etable,mx2,smisc,10  
etable,my1,smisc,5  
etable,my2,smisc,11  
etable,mz1,smisc,6  
etable,mz2,smisc,12  
!**********************************************  
!梁壳体的耦合问题小算例  
!全部采用体单元时exam3  
/prep7  
et,1,solid95  
mp,ex,1,3e5  
mp,prxy,1,0.0  
r,1  
blc4,,,20,7,10  
blc4,20,3,100,1,10  
vglue,all  
wpoff,0,3  
wprota,0,90  
vsbw,all  
wpoff,0,0,-1  
vsbw,all  
wpstyle  
/view,1,1,1,1  
/ang,1  
vplot  
esize,1  
mshape,0,2d  
mshkey,1  
vmesh,all  
finish  
/solu  
asel,s,loc,x,0  
da,all,all  
allsel,all  
nsel,s,loc,x,119.6,120  
nsel,r,loc,y,4  
*get,nhzs,node,,count  
f,all,fy,-3/nhzs  
allsel,all  
solve  
!**********************************************  
!梁壳体的耦合问题小算例  
!采用体单元和梁单元时exam4  
/prep7  
et,1,solid95  
et,2,beam4  
mp,ex,1,3e5  
mp,prxy,1,0.0  
r,1  
r,2,10.0,10/12.0,1000/12.0,10.0,1.0  
blc4,,,20,7,10  
wpoff,0,3.5  
wprota,0,90  
vsbw,all  
wpoff,0,5  
wprota,0,90  
vsbw,all  
wpcsys,-1  
k,100,20,3.5,5  
k,101,120,3.5,5  
l,100,101  
lsel,s,loc,x,21,130  
latt,1,2,2  
lesize,all,,,10  
lmesh,all  
vsel,all  
vatt,1,1,1  
esize,1  
mshape,0,2d  
mshkey,1  
vmesh,all  
allsel,all  
/view,1,1,1,1  
/ang,1  
eplot  
finish  
!------------------------  
/solu  
asel,s,loc,x,0  
da,all,all  
allsel,all  
fk,101,fy,-3.0  
cp,1,ux,1,21  
cp,2,uy,1,21  
cp,3,uz,1,21  
ce,1,0,626,ux,1,2328,ux,-1,1,roty,-abs(nz(626)-nz(2328))  
ce,2,0,67,ux,1,4283,ux,-1,1,rotz,-abs(ny(67)-ny(4283))  
ce,3,0,67,uz,1,4283,uz,-1,1,rotx,-abs(ny(67)-ny(4283))  
allsel,all  
solve  
finish  
!------------------------  
/post1  
etable,zl1,smisc,1  
etable,zl2,smisc,7  
etable,jly1,smisc,2  
etable,jly2,smisc,8  
etable,jlz1,smisc,3  
etable,jlz2,smisc,9  
etable,mx1,smisc,4  
etable,mx2,smisc,10  
etable,my1,smisc,5  
etable,my2,smisc,11  
etable,mz1,smisc,6  
etable,mz2,smisc,12  
!**********************************************  
!梁壳体的耦合问题小算例  
!采用体壳单元时exam5  
/prep7  
et,1,solid95  
et,2,shell63  
mp,ex,1,3e5  
mp,prxy,1,0.0  
r,1  
r,2,1.0  
blc4,,,20,7,10  
wpoff,0,3.5  
wprota,0,90  
vsbw,all  
wpoff,20  
blc4,,,100,10  
wpcsys,-1  
vsel,all  
vatt,1,1,1  
esize,2  
mshape,0,2d  
mshkey,1  
vmesh,all  
asel,s,loc,x,21,120  
aatt,1,2,2  
aesize,all,2  
mshape,0,2d  
mshkey,1  
amesh,all  
allsel,all  
/view,1,1,1,1  
/ang,1  
eplot  
asel,s,loc,x,0  
da,all,all  
allsel,all  
cpintf,ux  
cpintf,uy  
cpintf,uz  
ce,1,0,1226,rotz,-abs(ny(197)-ny(742)),197,ux,1,742,ux,-1  
ce,2,0,1276,rotz,-abs(ny(201)-ny(971)),201,ux,1,971,ux,-1  
ce,3,0,1277,rotz,-abs(ny(205)-ny(969)),205,ux,1,969,ux,-1  
ce,4,0,1278,rotz,-abs(ny(209)-ny(967)),209,ux,1,967,ux,-1  
ce,5,0,1279,rotz,-abs(ny(213)-ny(965)),213,ux,1,965,ux,-1  
ce,6,0,1170,rotz,-abs(ny(194)-ny(701)),194,ux,1,701,ux,-1  
  
ce,7,0,1226,rotx,-abs(ny(197)-ny(742)),197,uz,1,742,uz,-1  
ce,8,0,1276,rotx,-abs(ny(201)-ny(971)),201,uz,1,971,uz,-1  
ce,9,0,1277,rotx,-abs(ny(205)-ny(969)),205,uz,1,969,uz,-1  
ce,10,0,1278,rotx,-abs(ny(209)-ny(967)),209,uz,1,967,uz,-1  
ce,11,0,1279,rotx,-abs(ny(213)-ny(965)),213,uz,1,965,uz,-1  
ce,12,0,1170,rotx,-abs(ny(194)-ny(701)),194,uz,1,701,uz,-1  
nsel,s,loc,x,120  
*get,nhzs,node,,count  
f,all,fy,-3/nhzs  
allsel,all  
/solu  
solve  
**********有一定见解88888**************
三月雨
发表于 2008-12-12 22:58:10 | 显示全部楼层 来自 德国
Simdroid开发平台
非常好的资料,正在学习中
回复 不支持

使用道具 举报

发表于 2011-9-14 12:56:22 | 显示全部楼层 来自 上海
虽然时间很久了 不过还是值得学习
回复 不支持

使用道具 举报

发表于 2013-10-5 23:18:10 | 显示全部楼层 来自 北京
有总结有算例,真棒
回复 不支持

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|小黑屋|联系我们|仿真互动网 ( 京ICP备15048925号-7 )

GMT+8, 2024-3-28 17:56 , Processed in 0.033348 second(s), 14 queries , Gzip On, MemCache On.

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表