【讨论】典型的网格划分练习

pengfm

一空心半球体，其内半径为1500mm，外半径为2000mm。现要沿其径向粘贴CFRP(Ex=235000Mpa, Ey=2000Mpa, u=0.3), 沿环向粘贴GFRP(Ex=150000Mpa, Ey=1000Mpa, u=0.3)。球体采用solid45单元，CFRP和GFRP均采用shell 41单元，CFRP与GFRP与球体完全粘结(即节点重合)，且CFRP与GFRP间隔粘贴，其水平投影如图所示。如何建立其有限元模型，请各位附上各自的命令流。要求：尽量用mapped mesh. 沿环向分成36个单元，沿厚度方向分成2个单元，沿径向分成5个单元。并求其承载能力在粘贴CFRP和GFRP前后改变多少？

htbbzzg

    1 你是在寻求帮助还是在出考题？是你正在做的题目吗？
   2 你给出的原始参数不够完整：CFRP 和 GFRP 的具体尺寸，沿轴向的大小、位置以及如何间隔粘贴的均不清楚。空心球体的厚度和材料性能也未给出。载荷和约束也不知道。如何满足你的要求？
   3 根据我的经验，采用 MAP 方式分网格是没有问题的。如果是你自己正在做的题目，请你将遇到的问题再表达得清楚一些。

pengfm

谢谢htbbzzg老师：
     我是请教这种问题的模型如如何建立，具体参数可以假设。我的思路是这样的：(1)先建立面，划分成二维网格；(2)旋转生成三维体单元；(3)粘贴CFRP时，先用create>elements>thru nodes，选择体单元外表面的4个节点，然后改变坐标标系至球坐标系下，copy elements.(4)用类似的方法粘贴GFRP. (5) 合并节点
    不知是否可以？？

pjwseu

（呵呵，这问题我在okok上6号已经回答过了，转过来吧。）
这题目是你自己想的吧？  
条件没给全：  
1、cfrp和gfrp的各向异性的材性没给全，只好随便猜了。  
2、cfrp和gfrp的厚度没给，只好随便取了0.1mm。  
3、半球体的材性没给，随便取了一个值。  
4、既然是弹性分析，何来“承载能力”之说？  
  
模型建好了，命令流如下，还没仔细检查，请指正。  
  
fini  
/clear,start  
/prep7  
/uis,msgpop,3 !不显示任何警告  
  
!定义局部坐标系  
LOCAL,12,2,0,2,0, ,90, ,1,1,  
  
!定义单元、材性  
et,1,41  
et,2,45  
  
r,1,0.0001 !假设FRP厚0.1mm  
  
mp,ey,1,235e9 !CFRP的材性(注意此处为ey)  
mp,ex,1,2e9  
mp,ez,1,2e9  
mp,prxy,1,0.03  
mp,pryz,1,0.3  
mp,prxz,1,0.03  
MP,GXY,1,100E9  
MP,GYZ,1,100E9  
MP,GXZ,1,100E9  
!1.0-prxy**2*ey/ex-pryz**2*ez/ey-prxz**2*ez/ex-2.0*prxy*pryz*prxz*ez/ex>0  
  
mp,ex,2,150e9 !GFRP的材性  
mp,ey,2,1e9  
mp,ez,2,1e9  
mp,prxy,2,0.3  
mp,pryz,2,0.3  
mp,prxz,2,0.3  
MP,GXY,2,50E9  
MP,GYZ,2,50E9  
MP,GXZ,2,50E9  
  
mp,ex,3,200e9 !假设半球的材性  
mp,prxy,3,0.3  
  
!建半球剖面并分网  
*do,i,1,10  
    CYL4,0,0,1.5,(i-1)*9,1.75,i*9  
    CYL4,0,0,1.75,(i-1)*9,2,i*9  
*enddo  
aglue,all  
  
LESIZE,all,, ,1, , , , ,0  
amesh,all  
  
!旋转成半球体  
EXTOPT,ESIZE,1,0  
EXTOPT,ACLEAR,1  
  
TYPE,2  
MAT,3  
VROTAT,all, , , , , ,75, 78,360,36  
CM,qiu,volu !定义一个叫“球”的组  
  
!建GFRP  
csys,0  
ASEL,s,LOC,y,sin(18/180*3.14159)*2,sin(36/180*3.14159)*2  
ASEL,a,LOC,y,sin(54/180*3.14159)*2,sin(72/180*3.14159)*2  
csys,2  
ASEL,r,LOC,x,2,3  
CM,gfrp,area !定义一个叫“GFRP”的组  
csys,0  
  
TYPE,1  
MAT,2  
real,1  
amesh,all  
  
!建CFRP  
allsel,all  
CSYS,12,  
ASEL,s,LOC,y,0,10  
*do,i,3,36,2  
  ASEL,a,LOC,y,(i-1)*10,i*10  
*enddo  
csys,2  
ASEL,r,LOC,x,2,3  
csys,0  
  
CM,temp,AREA  
AGEN,2,all, , ,0,0,0, ,1  
CMSE,U,temp  
CM,cfrp,area !定义一个叫“CFRP”的组  
  
TYPE,1  
MAT,1  
real,1  
LESIZE,all,, ,1, , , , ,0  
amesh,all  
  
!耦合  
allsel,all  
cpintf,all  
  
/solu  
  
!加约束  
ASEL,s,LOC,y,0,0  
da,all,uy  
  
!加荷载  
csys,2  
ASEL,s,LOC,x,0,1.5  
csys,0  
SFA,all,1,PRES,1000 !假设荷载为1000牛/m^2  
/PSF,PRES,NORM,2,0,1  
  
allsel,all  
!solve

xxw163com

我顶，好冬冬

lyon1981

绝对好dd啊，，赚了

zyfnuaa

请问阁下，别人的图片下载之后都不会动了，只有这个可以动，什么原理呀，请赐教
谢谢了！

zhangzq

hao

ttyy

真是高手啊！！

sharpshooter

真厉害，佩服！

hqxxz

mp是定义材料属性的prxz指的是泊松比GXY指的是剪切模量