请教： BF和BFE的区别

iomega

做了一个model,多层结构，apply heat generation on one of its layer.

发现
       NSEL选定nodes, BF,all,HGEN,%HTABLE%

和
      ESEL选定elements, BFE,all,HGEN,,%HTABLE%的结果相差很大。

(%HTABLE) 是x,y,z的函数

不知道谁知道它们之间的区别？ 谢谢

sunclark

针对scrunize的要求，把定义数组的一些过程详细说明一下：
     数组可按多个行、列与面的结构存储多个参数值，包含多个元素，ansys中的数组可分为3类：一维数组，二维数组和三维数组。需要注意的是，前两类和我们C语言中的数组有点不一样，首先他们是按列定义的，是个列向量，再者，二维数组可看成由多个一维数组即列矢量构成。三维数组由行、列和面组成，每个面相当于一个二维数组。
      此外，ansys中允许定义3种数组，ARRAY数值型数组，CHAR字符型数组，TABLE表，其中第三类是一种特殊的数值型数组，可以实现在数组元素之间的线性插值算法。
       定义数组用命令： *DIM，PAR，TYPE，IMAX，JMAX，KMAX，VAR1，VAR2，VAR3
       PAR是数组类型，可以是ARRAY（缺省），CHAR,TABLE ,STRING。IMAX，JMAX，KMAX分别是数组下标（I,J,K）的最大值
      VAR1，VAR2，VAR3是对应的行列面的变量名。
      如下：
      *DIM,A,,4
      *DIM,B,ARRAY,12,12
      *DIM,C,,4,3,3
      赋值时和C语言种又有所不同，如：
      定义一个维数为12×1的数组参数A，然后用“＝”赋值，命令如下：
      *DIM,A,,12，1，1
       A（1）＝1，2，3，4，5，6，7，8，9，10
       A（11）＝11，12
       说明：赋值只能最多10个
       *DIM,B，，4，3，1  ！定义一个4行3列数组
       B（1，1）＝11，21，31，41  ！定义第一列的4个元素
       B（1，2）＝12，22，32，42  ！定义第二列的4个元素
       B（1，3）＝13，23，33，43  ！定义第三列的4个元素
       对于表型数组，现定义第一个面内数组，然后再第二个面，不再赘述！！
      希望对大家有所帮助！！

iomega

Here is the answer got from ANSYS techsuport, it seems BFE is a better way to apply load...  ,

again, thanks for all the suggestions

Solution 6428:

==============

How are heat generation rates (HGEN) applied via BF versus BFE?

===============================================================

Q:  How are heat generation rates (HGEN) applied via the BF command

    versus the BFE command?

A:  If you specify a heat generation with the BF command, ANSYS will

    multiply that value by the weighted nodal volume of each element

    that touches that node.  However, if the BFE command is used, the

    specified value will be taken "as is" for the given elements.  

    Therefore, the BFE command is easier to work with.  A small

    example is shown below:

/prep7
/view,,1,2,3
/pnum,volu,1
block,0,1,0,1,0,11
block,2,3,0,1,0,11
mp,ex,1,1.93E+11     ! N/m^2
mp,nuxy,1,0.29       ! unitless
mp,dens,1,8030.0     ! kg/m^3
mp,kxx,1,16.3        ! W/m-C
mp,c,1,502.0         ! J/kg-C
et,1,solid70
esize,1.0
vmesh,all
fini
/solu
time,1
autots,on
nsubst,5,10,5

nsel,s,loc,z,0
nsel,r,loc,x,0,1     ! all nodes at end of bar #1
esln                 ! accompanying element
nsle                 ! corresponding nodes (8 of them)
bf,all,hgen,10000.0  ! 10,000 W/m^3 specified

nsel,s,loc,z,0
nsel,r,loc,x,2,3        ! all nodes at end of bar #2
esln                    ! accompanying element
nsle                    ! corresponding nodes (8 of them)
bfe,all,hgen,1,15000.0  ! 15,000 W/m^3 specified

esel,all
nsel,s,ext
nsel,r,loc,z,2,11    ! exterior nodes form z=2 to end of bars
sf,all,conv,0.1,0.0  ! hf=0.1 W/m^2-C and Tbulk=0 degrees C

nsel,all
save

solve   
fini  
/post1  
set,last
plnsol,temp

/eof

These two bars have equivalent loading.  The BF command is
used for the first bar and the BFE command is used for the
second bar.  Each element is 1.0 m^3, so the following holds:

Bar #1:
=======
Element #1 has 8 nodes that are loaded with 10,000.0 W/m^3
and element #2 (adjoining element) has 4 nodes with the
same loading.  ANSYS takes 1/8 of the element volume for
each node times the heat generation, which gives:

E1 => 8 nodes * (0.125 m^3 per node * 10,000 W/m^3) = 10,000 Watts

E2 => 4 nodes * (0.125 m^3 per node * 0 W/m^3)
    + 4 nodes * (0.125 m^3 per node * 10,000 W/m^3) = 5,000 Watts

Therefore, the total Load in bar #1 is 15,000 Watts
           

Bar #2:
=======
Element #12 has 8 nodes that are loaded with 15,000.0 W/m^3
via the BFE command, so the adjoining element (#13) does
not see the loading.   ANSYS takes 1/8 of the element volume
for each node times the heat generation, which gives:

E12 => 8 nodes * (0.125 m^3 per node * 15,000 W/m^3) = 15,000 Watts

Therefore, the total Load in bar #2 is 15,000 Watts, as well.

haiyo

当然有区别
f和fa还有区别呢

iomega

Then, which one is correct, hehe...

haiyo

条条大路通罗马

iomega

又不是赌马

nwpuyl

相逢是朋友，大家都友好一些嘛！
交流可以互助

weichaoxu

个人想法：
对三维问题，应该采用BFE，此时BF无法区分是哪个单元产生的。
对于二维问题，BFE和BF都可以。

scrunize

大家能把定义数组的过程说一下吗？我想请教大家一下，能不能举个例子 啊？？

littlewetboy

imoge老兄，先在这里谢谢你以前对我的帮助。
对于这个问题我的想法是：对于加载在ELEMENT的荷载，可能是以某种耦合形式（与单元种类有关）分配到ELEMENT的各个节点上。所以和直接加载到节点的载荷有区别。
说得不对请各位指正，共同探讨。

littlewetboy

也就是说，加载在单元上的载荷可能，最后转变成几个节点上载荷

nwpuyl

iomega不错嘛！还有ANSYS 的技术支持
今后多搞点有价值的techsuport上来哦
加分不含糊

haiyo

按照这个思路，将1＃bar的8个节点分为两组，z=0位置的一组加15,000 W/m^3，z=1的一组加7,500 W/m^3，那么两种加载方式就该等效哦：
Bar #1:
=======
E1 => 4 nodes * (0.125 m^3 per node * 15,000 W/m^3) ＋ 4 nodes * (0.125 m^3 per node * 7,500 W/m^3) = 10,250 Watts

E2 => 4 nodes * (0.125 m^3 per node * 0 W/m^3)
+ 4 nodes * (0.125 m^3 per node * 7,500 W/m^3) = 3,750 Watts

Therefore, the total Load in bar #1 is 15,000 Watts

Bar #2:
=======
E12 => 8 nodes * (0.125 m^3 per node * 15,000 W/m^3) = 15,000 Watts
但是计算出来的结果还是不一样，修改后的命令流如下：
/prep7
block,0,1,0,1,0,11
block,2,3,0,1,0,11
mp,ex,1,1.93E+11 ! N/m^2
mp,nuxy,1,0.29 ! unitless
mp,dens,1,8030.0 ! kg/m^3
mp,kxx,1,16.3 ! W/m-C
mp,c,1,502.0 ! J/kg-C
et,1,solid70
esize,1.0
vmesh,all
fini
/solu
time,1
autots,on
nsubst,5,10,5

nsel,s,loc,z,0
nsel,r,loc,x,0,1 !
bf,all,hgen,15000.0 !  

nsel,s,loc,z,1
nsel,r,loc,x,0,1 ! all nodes at end of bar #1
bf,all,hgen,7500.0 ! 7,500 W/m^3 specified

nsel,s,loc,z,0
nsel,r,loc,x,2,3 ! all nodes at end of bar #2
esln ! accompanying element
nsle ! corresponding nodes (8 of them)
bfe,all,hgen,1,15000.0 ! 15,000 W/m^3 specified

esel,all
nsel,s,ext
nsel,r,loc,z,2,11 ! exterior nodes form z=2 to end of bars
sf,all,conv,0.1,0.0 ! hf=0.1 W/m^2-C and Tbulk=0 degrees C

nsel,all
save

solve
fini
/post1
set,last
plnsol,temp

iomega

Good point, haiyo.
Actually the model you provided gives the same result as that from the ANSYS support. Bar#1 and Bar#2 have different temperature rises under the same power input.

I think the difference is that the heat generation distribution is different for Bar#1 and Bar#2.

For the ANSYS techsupport code:
For Bar#2, the volume that has HGEN is 1m^3. with HGEN of 15000W/m^3.
For Bar#1, the volume that has HGEN is 1m^3(from E1)+0.5m^3(from E2).
although total power input are the same, they yield different results becasue of different HGEN(x,y,z).  Same thing applies on your model.

haiyo

还是有点不明白，即使the heat generation distribution is different for Bar#1 and Bar#2.那也是在结构离散之前的状态
但是，经过离散之后的结构，载荷也离散到节点，生热率分布的差异已经不再起作用了吧，已经不会再受volume that has HGEN 的影响了吧？
有限元求解也是针对节点自由度进行的，既然节点上的载荷一样，两个模型的结果就应该相同吧？
这是我的愚见，欢迎讨论！

iomega

Here is my thought:

The unit of the HGEN is W/m^3, even the HGEN is applied on the nodes, it has to be transfered into the control volume around the nodes in the finite element model.

Recall for the finite difference (volume) method, the heat generation and heat flux are also applied on the control volume and its surface, not on the node itself.