自己作的基坑开挖

Abraham

我做了一个基坑分步开挖的算例，其中考虑了桩土接触。把命令流贴出来大家分享，希望有高手提意见和建议，不胜感谢。

fini
/clear

/prep7

et,1,plane183     !不需杀死的土体单元及砼单元
et,2,plane183     !挖去的第一批土体单元
et,3,plane183     !挖去的第二批土体单元
et,4,plane183     !挖去的第三批土体单元
et,5,link1        !-5m处的支承单元
et,6,link1        !-10m处的支承单元
et,7,169
et,8,172

mp,ex,1,80e6      !土体
mp,nuxy,1,0.3
mp,dens,1,2200
mp,mu,1,0.1

mp,ex,2,3e10      !砼
mp,nuxy,2,0.3
mp,dens,2,2500
mp,mu,2,0.1

mp,ex,3,2.0e11    !支撑
mp,nuxy,3,0.3
mp,dens,3,7850

r,1,0.031078      !支撑
r,2,0,0,1         !接触
r,3,0,0,1
r,4,0,0,1
r,5,0,0,1
r,6,5

k,1
k,2,80,0
k,3,81,0
k,4,91,0
k,5,92,0
k,6,172,0
k,7,81,-1
k,8,91,-1
k,9,81,-5
k,10,91,-5
k,11,81,-10
k,12,91,-10
k,13,80,-12
k,14,81,-12
k,15,91,-12
k,16,92,-12
k,17,0,-62
k,18,172,-62

k,19,80,0       !接触
k,20,80,-12
k,21,81,-12
k,22,81,0

k,23,91,0
k,24,91,-12
k,25,92,-12
k,26,92,0
k,27,81,-1
k,28,91,-1
k,29,81,-5
k,30,91,-5

l,1,2
l,19,22
l,3,4
l,23,26
l,5,6
l,1,17
l,2,13
l,3,7
l,4,8
l,5,16
l,6,18
l,8,7
l,7,9
l,8,10
l,9,10
l,9,11
l,10,12
l,11,12
l,11,14
l,12,15
l,13,14
l,14,15
l,15,16
l,13,17
l,16,18
l,17,18

l,19,13      !接触
l,22,27
l,27,29
l,29,14
l,23,28
l,28,30
l,30,15
l,26,16

al,1,7,24,6
al,2,28,29,30,21,27
al,3,9,12,8
al,4,34,23,33,32,31
al,5,11,25,10
al,12,14,15,13
al,15,17,18,16
al,18,20,22,19
al,21,22,23,25,26,24

lsel,s,,,1
lsel,a,,,24
lsel,a,,,6
lsel,a,,,25,26,1
lsel,a,,,11
lsel,a,,,5
lesize,all,2

lsel,invert
lesize,all,0.5

type,1
mat,1
real,6
amesh,1,9,4
amesh,8

type,2
mat,1
real,6
amesh,3

type,3
mat,1
real,6
amesh,6

type,4
mat,1
real,6
amesh,7

type,1
mat,2
real,6
amesh,2,4,2


allsel,all
numcmp,element
numcmp,node

lsel,s,,,7
nsll,s
type,8
real,2
mat,1
esurf

lsel,s,,,27
nsll,s
type,7
real,2
mat,2
esurf

lsel,s,,,8
lsel,a,,,13,19,3
nsll,s
type,8
real,3
mat,1
esurf

lsel,s,,,28,30,1
nsll,s
type,7
real,3
mat,2
esurf

lsel,s,,,9
lsel,a,,,14,20,3
nsll,s
type,8
real,4
mat,1
esurf

lsel,s,,,31,33,1
nsll,s
type,7
real,4
mat,2
esurf

lsel,s,,,10
nsll,s
type,8
real,5
mat,1
esurf

lsel,s,,,34
nsll,s
type,7
real,5
mat,2
esurf

allsel,all

fini

/solu

antype,static
deltim,0.01,0.001,0.02
autots,on
solc,on
nlgeom,on

outres,all,all

nsel,s,loc,y,-62
d,all,all

nsel,s,loc,x,0
nsel,a,loc,x,172
d,all,ux

allsel,all
acel,,9.8

solve

*do,tt,2,4,1
esel,s,type,,tt
ekill,all
allsel,all
solve
*enddo

fini

sl3913

值得看看！