求助

zhuxunguo

在一份学习资料中看到一个隧道锚杆支护的例子，但是不能运行，请教哪位高手指点一下，到底是怎么回事情，谢谢。
命令流文件如下：
*====================================================
*
*  分析新奥法开发过程模拟，两层支护，顶部有钢筋锚固
*
*
*====================================================
DATABASE NEW SAVE=NO PROMPT=NO
FEPROGRAM ADINA
CONTROL FILEVERSION=V82
*====================================================
*
*  定义点坐标
*
*====================================================
COORDINATES POINT SYSTEM=0
@CLEAR
1 0.0 0.0 -0.30 0
6 0.0 0.0 21. 0
8 0.0 0.0 -40. 0
9 0.0 -18. 2.0 0
10 0.0 -18. 8.0 0
11 0.0 -12. 18. 0
12 0.0 -12. 0.50 0
19 0.0 12. 18. 0
20 0.0 18. 8.0 0
21 0.0 18. 2.0 0
22 0.0 12. 0.50 0
54 0.0 -4.0 14. 0
55 0.0 4.0 14. 0
56 0.0 -8.0 7.0 0
57 0.0 8.0 7.0 0
58 0.0 0.0 14. 0
59 0.0 0.0 7.0 0
60 0.0 -11.40 17.65 0
61 0.0 0.0 20.50 0
62 0.0 -17.10 8.150 0
63 0.0 -17.10 2.450 0
64 0.0 -11.40 1.025 0
65 0.0 0.0 0.2650 0
66 0.0 11.40 1.025 0
67 0.0 17.10 2.450 0
68 0.0 17.10 8.150 0
69 0.0 11.40 17.65 0
70 0.0 -10.944 17.384 0
71 0.0 0.0 20.12 0
72 0.0 -16.416 8.264 0
73 0.0 -16.416 2.792 0
74 0.0 -10.944 1.424 0
75 0.0 0.0 0.6944 0
76 0.0 10.944 1.424 0
77 0.0 16.416 2.792 0
78 0.0 16.416 8.264 0
79 0.0 10.944 17.384 0
101 0.0 -80. -40. 0
102 0.0 80. -40. 0
103 0.0 -80. 60. 0
104 0.0 80. 60. 0
105 0.0 -80. 8.0 0
106 0.0 80. 8.0 0
107 0.0 -30. -40. 0
108 0.0 30. -40. 0
109 0.0 0.0 60. 0
201 0.0 0.0 21.20 0
202 0.0 0.0 36.20 0
211 0.0 2.0 21. 0
212 0.0 5.5 36. 0
221 0.0 4.5 20.50 0
222 0.0 13. 35.50 0
231 0.0 7.2 20. 0
232 0.0 21. 35. 0
241 0.0 -2.0 21. 0
242 0.0 -5.5 36. 0
251 0.0 -4.5 20.50 0
252 0.0 -13. 35.50 0
261 0.0 -7.2 20. 0
262 0.0 -21. 35. 0
@
*====================================================
*
*  定义面
*
*====================================================
SURFACE VERTEX NAME=1 P1=11 P2=54 P3=6 P4=11
*
SURFACE VERTEX NAME=2 P1=54 P2=58 P3=6 P4=54
*
SURFACE VERTEX NAME=3 P1=6 P2=58 P3=55 P4=6
*
SURFACE VERTEX NAME=4 P1=6 P2=55 P3=19 P4=6
*
SURFACE VERTEX NAME=5 P1=54 P2=56 P3=59 P4=58
*
SURFACE VERTEX NAME=6 P1=58 P2=59 P3=57 P4=55
*
SURFACE VERTEX NAME=7 P1=55 P2=57 P3=20 P4=19
*
SURFACE VERTEX NAME=8 P1=57 P2=22 P3=21 P4=20
*
SURFACE VERTEX NAME=9 P1=59 P2=1 P3=22 P4=57
*
SURFACE VERTEX NAME=10 P1=56 P2=12 P3=1 P4=59
*
SURFACE VERTEX NAME=11 P1=56 P2=10 P3=9 P4=12
*
SURFACE VERTEX NAME=12 P1=56 P2=54 P3=11 P4=10
*
SURFACE VERTEX NAME=13 P1=11 P2=60 P3=61 P4=6
*
SURFACE VERTEX NAME=14 P1=11 P2=10 P3=62 P4=60
*
SURFACE VERTEX NAME=15 P1=10 P2=9 P3=63 P4=62
*
SURFACE VERTEX NAME=16 P1=9 P2=12 P3=64 P4=63
*
SURFACE VERTEX NAME=17 P1=64 P2=12 P3=1 P4=65
*
SURFACE VERTEX NAME=18 P1=65 P2=1 P3=22 P4=66
*
SURFACE VERTEX NAME=19 P1=66 P2=22 P3=21 P4=67
*
SURFACE VERTEX NAME=20 P1=67 P2=21 P3=20 P4=68
*
SURFACE VERTEX NAME=21 P1=68 P2=20 P3=19 P4=69
*
SURFACE VERTEX NAME=22 P1=69 P2=19 P3=6 P4=61
*
SURFACE VERTEX NAME=23 P1=61 P2=60 P3=70 P4=71
*
SURFACE VERTEX NAME=24 P1=60 P2=62 P3=72 P4=70
*
SURFACE VERTEX NAME=25 P1=62 P2=63 P3=73 P4=72
*
SURFACE VERTEX NAME=26 P1=73 P2=63 P3=64 P4=74
*
SURFACE VERTEX NAME=27 P1=74 P2=64 P3=65 P4=75
*
SURFACE VERTEX NAME=28 P1=75 P2=65 P3=66 P4=76
*
SURFACE VERTEX NAME=29 P1=76 P2=66 P3=67 P4=77
*
SURFACE VERTEX NAME=30 P1=77 P2=67 P3=68 P4=78
*
SURFACE VERTEX NAME=31 P1=79 P2=78 P3=68 P4=69
*
SURFACE VERTEX NAME=32 P1=61 P2=71 P3=79 P4=69
*
SURFACE VERTEX NAME=33 P1=103 P2=11 P3=6 P4=109
*
SURFACE VERTEX NAME=34 P1=103 P2=105 P3=10 P4=11
*
SURFACE VERTEX NAME=35 P1=105 P2=101 P3=9 P4=10
*
SURFACE VERTEX NAME=36 P1=101 P2=107 P3=12 P4=9
*
SURFACE VERTEX NAME=37 P1=12 P2=107 P3=8 P4=1
*
SURFACE VERTEX NAME=38 P1=1 P2=8 P3=108 P4=22
*
SURFACE VERTEX NAME=39 P1=22 P2=108 P3=102 P4=21
*
SURFACE VERTEX NAME=40 P1=20 P2=21 P3=102 P4=106
*
SURFACE VERTEX NAME=41 P1=104 P2=19 P3=20 P4=106
*
SURFACE VERTEX NAME=42 P1=109 P2=6 P3=19 P4=104
*====================================================
*
*  定义并施加约束
*  
*  
*====================================================
FIXITY NAME=Y-FIX
@CLEAR
'Y-TRANSLATION'
@
*
FIXITY NAME=Z-FIX
@CLEAR
'Z-TRANSLATION'
@
*
FIXBOUNDARY LINES FIXITY=ALL
@CLEAR
75  'Z-FIX'
77  'Z-FIX'
79  'Z-FIX'
81  'Z-FIX'
71  'Y-FIX'
73  'Y-FIX'
83  'Y-FIX'
86  'Y-FIX'
@
*====================================================
*
*  定义材料参数，支护为弹性，围岩为MC
*  
*  
*====================================================
MATERIAL ELASTIC NAME=2 E=2.0E+10 NU=0.20,
     DENSITY=2500.
*
MATERIAL MOHR-COULOMB NAME=1 E=6.0E+08,
     NU=0.2 PHI=25.0 PSI=0.0,
     COH=8.0E+06 TCUT=2000000.00000000,
     DENSITY=2700.0 DILATION=NO
*
*====================================================
*
*  定义地应力场
*  并定义初始地应力场的主轴方向（否则加载在单元坐标系
*  上，通常不符合要求。）然后将定义的局部坐标系施加到
*  所有围岩的Surface上。
*
*====================================================
STRAIN-FIELD NAME=1 A=-1.63e6 B=27000.,
     C=0.3 D=0.0 E=0.0 F=0.0
*
*
AXES CONSTANT NAME=1 AX=1.0 AY=0.0,
     AZ=0.0 BX=0.0 BY=1.0,
     BZ=0.0
*
SET-AXES-STR SURFACES
@CLEAR
34 1 2 3
35 1 2 3
33 1 2 3
41 1 2 3
42 1 2 3
40 1 2 3
39 1 2 3
37 1 2 3
38 1 2 3
36 1 2 3
11 1 2 3
12 1 2 3
2 1 2 3
1 1 2 3
3 1 2 3
4 1 2 3
6 1 2 3
7 1 2 3
5 1 2 3
9 1 2 3
10 1 2 3
8 1 2 3
@
*====================================================
*
*  定义单元组，INITIALS=BOTH为有初始应力输入
*  STRAIN-F=1为地应力场输入1
*  
*====================================================
EGROUP TWODSOLID NAME=1 SUBTYPE=STRAIN,
     MATERIAL=1,
  INITIALS=BOTH STRAIN-F=1
*
EGROUP TWODSOLID NAME=4 SUBTYPE=STRAIN,
     MATERIAL=1
*
EGROUP TWODSOLID NAME=3 SUBTYPE=STRAIN,
     MATERIAL=1
*
EGROUP TWODSOLID NAME=2 SUBTYPE=STRAIN,
    MATERIAL=1,
  INITIALS=BOTH STRAIN-F=1
*
*====================================================
*
*  定义面的单元生死，围岩从10.1～210.1时刻死掉
*  
*====================================================
SURF-ELEMDAT TWODSOLID
@CLEAR
1 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     30.10  'NO' 0.0
2 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     50.10  'NO' 0.0
3 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     50.10  'NO' 0.0
4 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     10.10  'NO' 0.0
5 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     110.1  'NO' 0.0
6 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     120.1  'NO' 0.0
7 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     70.10  'NO' 0.0
8 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     130.1  'NO' 0.0
9 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     210.1  'NO' 0.0
10 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     190.1  'NO' 0.0
11 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     160.1  'NO' 0.0
12 0 0.0  'DEFAULT'  'DEFAULT' 0.0,
     90.10  'NO' 0.0
13 0 0.0  'DEFAULT'  'DEFAULT' 40.10,
     0.0  'NO' 0.0
14 0 0.0  'DEFAULT'  'DEFAULT' 100.1,
     0.0  'NO' 0.0
15 0 0.0  'DEFAULT'  'DEFAULT' 180.1,
     0.0  'NO' 0.0
16 0 0.0  'DEFAULT'  'DEFAULT' 170.1,
     0.0  'NO' 0.0
17 0 0.0  'DEFAULT'  'DEFAULT' 200.1,
     0.0  'NO' 0.0
18 0 0.0  'DEFAULT'  'DEFAULT' 220.1,
     0.0  'NO' 0.0
19 0 0.0  'DEFAULT'  'DEFAULT' 150.1,
     0.0  'NO' 0.0
20 0 0.0  'DEFAULT'  'DEFAULT' 140.1,
     0.0  'NO' 0.0
21 0 0.0  'DEFAULT'  'DEFAULT' 80.10,
     0.0  'NO' 0.0
22 0 0.0  'DEFAULT'  'DEFAULT' 20.10,
     0.0  'NO' 0.0
23 0 0.0  'DEFAULT'  'DEFAULT' 280.1,
     0.0  'NO' 0.0
24 0 0.0  'DEFAULT'  'DEFAULT' 290.1,
     0.0  'NO' 0.0
25 0 0.0  'DEFAULT'  'DEFAULT' 300.1,
     0.0  'NO' 0.0
26 0 0.0  'DEFAULT'  'DEFAULT' 310.1,
     0.0  'NO' 0.0
27 0 0.0  'DEFAULT'  'DEFAULT' 320.1,
     0.0  'NO' 0.0
28 0 0.0  'DEFAULT'  'DEFAULT' 230.1,
     0.0  'NO' 0.0
29 0 0.0  'DEFAULT'  'DEFAULT' 240.1,
     0.0  'NO' 0.0
30 0 0.0  'DEFAULT'  'DEFAULT' 250.1,
     0.0  'NO' 0.0
31 0 0.0  'DEFAULT'  'DEFAULT' 260.1,
     0.0  'NO' 0.0
32 0 0.0  'DEFAULT'  'DEFAULT' 270.1,
     0.0  'NO' 0.0
@
*====================================================
*
*  定义重力荷载并施加
*  
*  
*====================================================
LOAD MASS-PROPORTIONAL NAME=1 MAGNITUD=9.8,
     AX=0.0 AY=0.0 AZ=-1.0,
     INTERPRE=BODY-FORCE
*
APPLY-LOAD BODY=0
@CLEAR
1  'MASS-PROPORTIONAL' 1  'MODEL' 0 0 1 0.0 0 -1 0 0 0  ,
'NO' 0.0 0.0 1 0
@
*====================================================
*
*  划分网格前进行划分单元密度的设置
*  第一个命令对整个模型设置等分数10
*  
*====================================================
SUBDIVIDE model MODE=DIVISIONS NDIV=10
SUBDIVIDE LINE NAME=41 MODE=DIVISIONS NDIV=3 RATIO=1.0,
     PROGRESS=GEOMETRIC CBIAS=NO
@CLEAR
41
43
45
48
50
61
63
66
28
30
59
39
37
57
35
55
53
33
31
51
@
*
SUBDIVIDE LINE NAME=69 MODE=DIVISIONS NDIV=10 RATIO=10.,
     PROGRESS=GEOMETRIC CBIAS=NO
SUBDIVIDE LINE NAME=68 MODE=DIVISIONS NDIV=10 RATIO=0.10,
     PROGRESS=GEOMETRIC CBIAS=NO
@CLEAR
85
84
82
80
78
74
72
76
@
*====================================================
*
*  划分单元，采用映射自动划分
*  
*  
*====================================================
GSURFACE NODES=4 PATTERN=AUTOMATIC NCOINCID=BOUNDARIES,
     GROUP=1
@CLEAR
33
34
35
36
37
38
39
40
41
42
@
*
GSURFACE NODES=4 PATTERN=AUTOMATIC NCOINCID=BOUNDARIES,
     GROUP=4
@CLEAR
13
22
21
20
19
18
17
16
15
14
@
*
GSURFACE NODES=4 PATTERN=AUTOMATIC NCOINCID=BOUNDARIES,
     GROUP=3     
@CLEAR
23
32
31
30
29
28
27
26
25
24
@
*
GSURFACE NODES=4 PATTERN=AUTOMATIC NCOINCID=BOUNDARIES,
     GROUP=2
@CLEAR
1
2
3
4
5
6
7
8
9
10
11
12
@
*
GSURFACE NODES=4 PATTERN=AUTOMATIC NCOINCID=BOUNDARIES,
     GROUP=4
*
*====================================================
*
*  生成锚杆的线段，锚杆位于顶部
*  
*  
*====================================================
LINE STRAIGHT NAME=88 P1=262 P2=261
*
LINE STRAIGHT NAME=89 P1=252 P2=251
*
LINE STRAIGHT NAME=90 P1=242 P2=241
*
LINE STRAIGHT NAME=91 P1=202 P2=201
*
LINE STRAIGHT NAME=92 P1=212 P2=211
*
LINE STRAIGHT NAME=93 P1=222 P2=221
*
LINE STRAIGHT NAME=94 P1=232 P2=231
*
*====================================================
*
*  设置锚杆的截面大小，在相应的土体开挖后，激活锚杆
*  
*  
*====================================================
LINE-ELEMDAT TRUSS
@CLEAR
88 0 0.0090  'DEFAULT'  'DEFAULT' 30.10,
     0.0 0.0  'NO' 0.0
89 0 0.0090  'DEFAULT'  'DEFAULT' 30.10,
     0.0 0.0  'NO' 0.0
90 0 0.0090  'DEFAULT'  'DEFAULT' 30.10,
     0.0 0.0  'NO' 0.0
91 0 0.0090  'DEFAULT'  'DEFAULT' 10.10,
     0.0 0.0  'NO' 0.0
92 0 0.0090  'DEFAULT'  'DEFAULT' 10.10,
     0.0 0.0  'NO' 0.0
93 0 0.0090  'DEFAULT'  'DEFAULT' 10.10,
     0.0 0.0  'NO' 0.0
94 0 0.0090  'DEFAULT'  'DEFAULT' 10.10,
     0.0 0.0  'NO' 0.0
@
*====================================================
*
*  定义锚杆材料
*  
*  
*====================================================
MATERIAL PLASTIC-BILINEAR NAME=3 HARDENIN=ISOTROPIC,
     E=2.0E+11 NU=0.3,
     YIELD=5.0E+08 ET=1.E+09,
     DENSITY=7800.
*====================================================
*
*  在定义锚杆的EG时，指定锚杆作为Rebar单元使用
*  （不需用户划分网格）
*  
*====================================================
REBAR-LINE NAME=1
@CLEAR
88
89
90
91
92
93
94
@
*====================================================
*
*  在定义锚杆的EG时，指定锚杆作为Rebar单元使用
*  （不需用户划分网格）
*  
*====================================================
EGROUP TRUSS NAME=5 SUBTYPE=GENERAL MATERIAL=3,
     INT=DEFAULT GAPS=NO INITIALS=NONE CMASS=DEFAULT,
     OPTION=REBAR RB-LINE=1
*====================================================
*
*  指定锚杆的单元密度
*  
*  
*====================================================
SUBDIVIDE LINE NAME=88 MODE=DIVISIONS NDIV=10
@CLEAR
89
90
91
92
93
94
@
*
meshplot
*
TIMESTEP
@CLEAR
40 10.0
@
*====================================================
*
*  打开大位移开关
*  
*====================================================
Kinematics displacement=large
*====================================================
*
*  自动施加步长分析，单元刚度过渡时间为20，
*  只有YZ自由度，设置输入初始应变作为导致变形的初始应力
*  
*====================================================
MASTER ANALYSIS=STATIC AUTOMATI=ATS TRELEASE=20.,
       IDOF=100111 INITIALS=DEF
*====================================================
*  结束
*
*  在观察结果时，最后时刻系统变形完全稳定。
*
*
*====================================================