我加了个圆角
居然收敛了。
哈哈
谢谢,
附
FINISH
/CLEAR,NOSTART
/COM, Structural
!*********** parameter setup **************
B_WIDTH=0.46 !WIDTH & THICKNESS & LENGTH OF THE BEAM
B_LEN=13.7
B_THK=0.3
S_WIDTH=0.6 !WIDTH & THICKNESS & LENGTH OF THE SUPPORT
S_LEN=0.4
S_THK=0.3
Round=0.05
DISTANCE=-1-B_THK/2-S_THK/2 !distance between beam and support surface.
MESH_OFFSET=0.8
DISP_OFFSET=4.5
YIELD=700
TANG_MODE=800
COF=0
!control the element size
THK_DIVISOIN=4
WIDTH_DIVISION=3
V_CONTACTG_SIZE=0.1
V_TRANS_SIZE=0.2
V_BEAN_SIZE=0.2
!*********** parameter setup end **************
/PREP7
!*****Material Setup
ET,1,SOLID45
EX,1,1.126E5
NUXY,1,0.35
!TB,BISO,1,1,2,
!TBDATA,1,YIELD,TANG_MODE,,,
!*****Create Model
!CREATE BEAM
BLC5,0,0,B_WIDTH,B_THK,B_LEN
!CREATE SUPPORT
BLC5,0,0,S_WIDTH,S_THK,S_LEN
WPAVE,0,0,S_LEN
BLC5,0,Round*(-0.5),S_WIDTH,S_THK-Round,Round
WPAVE,S_WIDTH/2,(S_THK/2-Round),S_LEN
WPRO,,,-90
CYL4,0,0,Round,,,,S_WIDTH
VADD,2,3
VADD,4,5
/PNUM,KP,0
/PNUM,LINE,1
/PNUM,AREA,1
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,TABN,0
/PNUM,SVAL,0
/NUMBER,0
!*
/PNUM,ELEM,0
VGEN, ,2, , , ,DISTANCE, , , ,1 !MOVE SUPPORT TO NEW LOCATION
WPAVE,0,0,0
WPCSYS,-1,0,
WPAVE,0,0,DISP_OFFSET
VSBW,ALL !get the displacement apply position
WPAVE,0,0,0
WPCSYS,-1,0
WPAVE,0,0,MESH_OFFSET
VSBW,ALL !get contact surface offset area.
!element size Setup
LESIZE,1, , ,THK_DIVISOIN
LESIZE,2, , ,WIDTH_DIVISION
LESIZE,9, V_CONTACTG_SIZE
LESIZE,61,V_TRANS_SIZE
LESIZE,50,V_BEAN_SIZE
!*****mesh
VSEL,S,LOC,Y,-0.5,1
VSWEEP,ALL
!create the contact pair.
MP,MU,1,COF !set cof
MAT,1
R,3
REAL,3
ET,2,170
ET,3,174
KEYOPT,3,9,0
KEYOPT,3,10,2
R,3,0.02,0,0.1,0.1,0.0
! Generate the target surface
ASEL,S,,,15
ASEL,A,,,30
ASEL,A,,,17
!CM,_TARGET,AREA
AATT,-1,3,2,-1
TYPE,2
AMESH,ALL
!Generate the contact surface
ASEL,S,,,6
ASEL,A,,,1
TYPE,3
NSLA,S,1
ESLN,S,0
ESURF
!*****apply the load
/SOL
DL,30, ,UY,-2
NSEL,S,LOC,Z,B_LEN
D,ALL,ALL,
ANTYPE,0
NLGEOM,1
NSUBST,100,1000,25
OUTRES,ERASE
OUTRES,ALL,ALL
TIME,1
ALLSEL,ALL
/VIEW,1,1,2,3
/ANG,1
/REPLOT
/VIEW, 1, -0.777520041429 , 0.375984275955 , -0.504081748739
/ANG, 1, 3
save
!*****solve
solve
!*****POST
/POST1
SET,,, ,,, ,1
PLNS,S,EQV
ANTIME,10,0.5, ,1,0,0,1
[ 本帖最后由 alex_shoal 于 2007-4-19 09:50 编辑 ] |