请问移动荷载怎么施加？

imaix

请教各位高手，移动荷载怎么施加？在这里先谢谢了~~

zhafeiyang

通常情况下移动荷载需要用*循环来实现，然后进行瞬态分析
这是我的以前做的一个例子，你可以参考一下

梁上移动荷载的施加

*SET,long,40      !梁长度40
*SET,ne,20        !单元数量20
*SET,dl,long/ne   
*SET,nn,ne+1      !节点数量20+1
*SET,ff,5000      !集中力5000
*SET,vv,80        !移动速度80km/h
*SET,dt,dl/vv*3.6 !每个单元上的时间

! 建模
/PREP7   
ET,1,BEAM3   
R,1,0.5,0.041667,0.1, , , ,  
MP,EX,1,50e9   
MP,PRXY,1,0.2  
MP,DENS,1,2500

! 循环命令创建节点
*do,i,1,nn,1
n,i,(i-1)*dl
*enddo

!创建单元
*do,i,1,ne
e,i,i+1
*enddo
finish

!加载求解
/sol
ANTYPE,4            !分析类型为瞬态分析
TRNOPT,FULL         !解析方法为full法
OUTRES,BASI,ALL     !输出每一子步的基本结果
KBC,1.0             !指定荷载步变化为阶越
TIMINT,0            !不考虑瞬态影响
NSUBST,4,8,0        !子步数为4步，最大不超过8步
TIME,1e-10          !加载结束时间1e－10s
sstif,on            !应力钢化效应打开
ACEL,0,9.8,0,       !施加y方向的加速度9.8

FLST,2,2,1,ORDE,2   
FITEM,2,1   
FITEM,2,21  
D,P51X, , , , , ,ALL, , , , ,    !对梁两端的节点施加全约束

solve                     

timint,on           !考虑瞬态影响
NSUBST,5,0          !子步数为5
OUTRES,ALL,ALL


*do,ii,1,nn,1
time,ii*dt
fdele,all,all
nsel,s,loc,x,(ii-1)*dl
f,all,fy,-ff
allsel
solve
*enddo

FINISH  
/POST26
FILE,'f','rst','.'                             !! f为文件名
NSOL,2,nn/2+1,U,Y,uy_m  
PLVAR,2, , , , , , , , , ,  
DERIV,3,2, , , , , ,1,  
PLVAR,3, , , , , , , , , ,

imaix

多谢楼上的兄弟~~

imaix

还要问一下，上面的命令中，
/sol
ANTYPE,4            !分析类型为瞬态分析
TRNOPT,FULL         !解析方法为full法
OUTRES,BASI,ALL     !输出每一子步的基本结果
KBC,1.0             !指定荷载步变化为阶越
TIMINT,0            !不考虑瞬态影响
NSUBST,4,8,0        !子步数为4步，最大不超过8步
TIME,1e-10          !加载结束时间1e－10s
sstif,on            !应力钢化效应打开
ACEL,0,9.8,0,       !施加y方向的加速度9.8

FLST,2,2,1,ORDE,2   
FITEM,2,1   
FITEM,2,21  
D,P51X, , , , , ,ALL, , , , ,    !对梁两端的节点施加全约束

solve                     

timint,on           !考虑瞬态影响
NSUBST,5,0          !子步数为5
OUTRES,ALL,ALL


*do,ii,1,nn,1
time,ii*dt
fdele,all,all
nsel,s,loc,x,(ii-1)*dl
f,all,fy,-ff
allsel
solve
*enddo
不考虑瞬态影响与考虑瞬态影响的命令是连在一起的？还是当考虑瞬态影响时，前面的就不用输入了，直接输入后面的命令即可？

zhafeiyang

前面的是只有自重的影响，
如果不考虑自重就可以把它删掉了

imaix

谢谢了，还有一个问题哈~~
如果想看到该荷载从梁的左面移动到右面，梁的y向唯移变形动画应该怎么办？

zhafeiyang

plotctrl>Animate> Deform result里面可以

imaix

动画是不是只能在post1中显示？
另外，你用post26显示的结果具体是什么意思？能解释下吗？
还有   FLST,2,2,1,ORDE,2   
           FITEM,2,1   
           FITEM,2,21  
           D,P51X, , , , , ,ALL, , , , ,   
         
       这个命令与

          d,1,all
          d,21,all
        有什么区别吗？
      另外，D,P51X, , , , , ,ALL, , , , ,这个命令与D,P51X, all是不是没有区别？

我还是个新手哈，麻烦仁兄了！不胜感激！！！

[ 本帖最后由 imaix 于 2007-6-29 11:08 编辑 ]

imaix

该问题已经解决！

[ 本帖最后由 imaix 于 2007-7-2 10:25 编辑 ]

imaix

该问题已经解决！！！

[ 本帖最后由 imaix 于 2007-7-1 12:32 编辑 ]

imaix

该问题已经解决！！！

[ 本帖最后由 imaix 于 2007-7-1 12:36 编辑 ]

imaix

还是这个问题哈，
          FLST,2,2,1,ORDE,2   
           FITEM,2,1   
           FITEM,2,21  
           D,P51X, , , , , ,ALL, , , , ,   
         
       这个命令与

          d,1,all
          d,21,all
        有什么区别吗？
      另外，D,P51X, , , , , ,ALL, , , , ,这个命令与D,P51X, all是不是没有区别？
望仁兄不吝赐教~~

[ 本帖最后由 imaix 于 2007-7-2 11:05 编辑 ]