找回密码
 注册
Simdroid-非首页
查看: 727|回复: 11

[软件接口] dxfTOansys:用APDL生成DXF文件,再用AUTOCAD出图

[复制链接]
发表于 2007-8-17 22:01:02 | 显示全部楼层 |阅读模式 来自 北京朝阳
软件直接装换为 Ansys 输入格式。前处理状态下,选 Read Input From 菜单输入。
优点: 常用的非三维实体都能转换。由于转换Keypoint 初始值可选,你用AutoCAD建模时可以各部分单独建,在Ansys中单独输入!
缺点: 转换实体类型较少
(一)绘制计算结果图形,是我们都面临的问题,如何方便的绘制图形,用APDL生成DXF文件,再用AUTOCAD出图,是一种较好的办法.
下面,提供一个实例。
杆系结构非线性分析--结构变形图与AutoCAD的借口。
finish
/CLEAR,START
!这里定义何子步出图及变形放大比例.
!scalebx----变形放大或缩小系数,缺省为1
!zbcad------第几荷载步需要画出的定义,缺省为最后荷载步
!zbsub------该荷载步的第几子步,缺省为最后子步
!注:从post1中的results summary...中可以看到上述数值
!从对话框输入上述参数
multipro,'start',3 !对话框输入数值
  *cset,1,3,zbcad,'loadsetp number for drawing'
  *cset,4,6,zbsub, 'substep number for drawing'
  *cset,7,9,scbx1, 'displacement scale factor'
multipro,'end'
scalebx=1
*if,scbx1,ne,0,then
scalebx=scbx1
*endif
allsel,all
!预处理过程---------------------------------------
/prep7
*get,sumelem,elem,0,count
*dim,elemno,,sumelem
*get,elem1,elem,0,num,min
elemno(1)=elem1
*do,i,2,sumelem
elemno(i)=elnext(elemno(i-1))
*enddo

/post26
nsol,8,1,u,y
!为AutoCAD的DXF文件写头文件-----------------------
*if,zbcad,eq,0,then
name2='zh'
*else
name2=chrval(zbcad)
*endif
*if,zbsub,eq,0,then
name3='zh'
*else
name3=chrval(zbsub)
*endif
name4=strcat(name2,name3)
name1=strcat('ac',name4)

/post1
/nopr
/out,name1,dxf
*vwrite,'0'
(a1)
*vwrite,'SECTION'
(a7)
*vwrite,'2'
(a1)
*vwrite,'HEADER'
(a6)
*vwrite,'0'
(a1)
*vwrite,'ENDSEC'
(a6)
*vwrite,'0'
(a1)
*vwrite,'SECTION'
(a7)
!以上写头
*vwrite,'2'
(a1)
*vwrite,'TABLES'
(a6)
*vwrite,'0'
(a1)
*vwrite,'TABLE'
(a5)
*vwrite,'2'
(a1)
*vwrite,'LAYER'
(a5)
*vwrite,'70'
(a2)
*vwrite,'16'
(a2)
*vwrite,'0'
(a1)
*vwrite,'LAYER'
(a5)
*vwrite,'2'
(a1)
*vwrite,'1'
(a1)
*vwrite,'70'
(a2)
*vwrite,'64'
(a2)
*vwrite,'62'
(a2)
*vwrite,'1'
(a1)
*vwrite,'6'
(a1)
*vwrite,'CONTIN','UOUS'
(a6,a4)
*vwrite,'0'
(a1)
*vwrite,'LAYER'
(a5)
*vwrite,'2'
(a1)
*vwrite,'2'
(a1)
*vwrite,'70'
(a2)
*vwrite,'64'
(a2)
*vwrite,'62'
(a2)
*vwrite,'3'
(a1)
*vwrite,'6'
(a1)
*vwrite,'CONTIN','UOUS'
(a6,a4)
*vwrite,'0'
(a1)
*vwrite,'ENDTAB'
(a6)
*vwrite,'0'
(a1)
*vwrite,'ENDSEC'
(a6)
*vwrite,'0'
(a1)
*vwrite,'SECTION'
(a7)
!以上创建两个层
*vwrite,'2'
(a1)
*vwrite,'ENTITIES'
(a8)
!进入画图过程-----------------
!画原图---------------
*do,i,1,sumelem
i1=nelem(elemno(i),1)
j1=nelem(elemno(i),2)
*vwrite,'0'
(a1)
*vwrite,'LINE'
(a4)
*vwrite,'8'
(a1)
*vwrite,'1'
(a1)
*vwrite,'10'
(a2)
*vwrite,nx(i1)
(f19.9)
*vwrite,'20'
(a2)
*vwrite,ny(i1)
(f19.9)
*vwrite,'30'
(a2)
*vwrite,nz(i1)
(f19.9)
*vwrite,'11'
(a2)
*vwrite,nx(j1)
(f19.9)
*vwrite,'21'
(a2)
*vwrite,ny(j1)
(f19.9)
*vwrite,'31'
(a2)
*vwrite,nz(j1)
(f19.9)
*enddo
!画变形图--------------------------
*if,zbcad,eq,0,then
*if,zbsub,eq,0,then
   set,LAST
*else
   set,LAST,zbsub
*endif
*else
*if,zbsub,eq,0,then
   set,zbcad
*else
   set,zbcad,zbsub
*endif
*endif
*do,i,1,sumelem
i1=nelem(elemno(i),1)
j1=nelem(elemno(i),2)
*vwrite,'0'
(a1)
*vwrite,'LINE'
(a4)
*vwrite,'8'
(a1)
*vwrite,'2'
(a1)
*vwrite,'10'
(a2)
*vwrite,nx(i1)+ux(i1)*scalebx
(f19.9)
*vwrite,'20'
(a2)
*vwrite,ny(i1)+uy(i1)*scalebx
(f19.9)
*vwrite,'30'
(a2)
*vwrite,nz(i1)+uz(i1)*scalebx
(f19.9)
*vwrite,'11'
(a2)
*vwrite,nx(j1)+ux(j1)*scalebx
(f19.9)
*vwrite,'21'
(a2)
*vwrite,ny(j1)+uy(j1)*scalebx
(f19.9)
*vwrite,'31'
(a2)
*vwrite,nz(j1)+uz(j1)*scalebx
(f19.9)
*enddo
!关闭DXF文件
*vwrite,'0'
(a1)
*vwrite,'ENDSEC'
(a6)
*vwrite,'0'
(a1)
*vwrite,'EOF'
(a3)
/com
/out
/go
scbx1=
zbcad=
scalebx=
sumelem=
elemno(1)=
elem1=
i1=
j1=
zbsub=
name1=
name2=
name3=
name4=

评分

1

查看全部评分

发表于 2007-8-17 23:30:14 | 显示全部楼层 来自 黑龙江哈尔滨
Simdroid开发平台
谢谢LZ,和这个是一个东东吗?
http://www.cadcaecam.com/forum/htm_data/21/0606/116.html
回复 不支持

使用道具 举报

发表于 2007-8-20 15:12:52 | 显示全部楼层 来自 上海松江区
北极熊甲 版主贴上的那个网址倒是个很不错的东东哦,楼主的帖子也值得学习学习啊!
回复 不支持

使用道具 举报

发表于 2007-9-21 10:42:07 | 显示全部楼层 来自 北京
东西确实不错,谢谢了
回复 不支持

使用道具 举报

发表于 2007-9-21 13:12:16 | 显示全部楼层 来自 湖北武汉
原帖由 北极熊甲 于 2007-8-17 23:30 发表
谢谢LZ,和这个是一个东东吗?
http://www.cadcaecam.com/forum/htm_data/21/0606/116.html


帖子打不开啊
回复 不支持

使用道具 举报

发表于 2007-9-21 15:24:55 | 显示全部楼层 来自 湖北武汉
不错
回复 不支持

使用道具 举报

发表于 2008-6-9 17:06:52 | 显示全部楼层 来自 北京交通大学
谢谢楼主。
回复 不支持

使用道具 举报

发表于 2008-6-9 17:10:21 | 显示全部楼层 来自 北京交通大学
哪有dxftoansys?
回复 不支持

使用道具 举报

发表于 2008-7-24 21:36:20 | 显示全部楼层 来自 湖北武汉
谢谢楼主提供
回复 不支持

使用道具 举报

发表于 2008-7-24 23:54:14 | 显示全部楼层 来自 河北石家庄
回复 不支持

使用道具 举报

发表于 2009-1-12 10:48:38 | 显示全部楼层 来自 内蒙古包头
thx a lot
回复 不支持

使用道具 举报

发表于 2009-2-24 16:30:03 | 显示全部楼层 来自 浙江杭州
不错,用用看。
回复 不支持

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|小黑屋|联系我们|仿真互动网 ( 京ICP备15048925号-7 )

GMT+8, 2024-3-29 20:09 , Processed in 0.056521 second(s), 18 queries , Gzip On, MemCache On.

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表