- 积分
- 31
- 注册时间
- 2003-6-16
- 仿真币
-
- 最后登录
- 1970-1-1
|
发表于 2009-8-7 17:26:40
|
显示全部楼层
来自 河北石家庄
/TITLE,Orthotropic plate with edge load, Bifurcation Analysis, SHELL91
/UNITS,MPA ! Units are in mm, MPa, and Newtons
/PREP7 ! Pre-processor module
! Material properties for lamina
uimp,1,ex,ey,ez,145880,13312,13312
uimp,1,gxy,gyz,gxz,4386,4529,4386
uimp,1,prxy,pryz,prxz,0.263,0.470,0.263
ET,1,SHELL91,,1 ! Chooses Shell91 element for analysis
! Set KEYOPT(2)=1, then supply 12+(6*NL) const.
KEYOPT,1,1,12 ! Set KEYOPT(1)=12, Max number of layers = 12
KEYOPT,1,5,1 ! Set KEYOPT(5)=1, Element output: Middle layer
! Real constant set #1, [(0/90)3]s, NL=12, lamina thick=0.85 mm
R,1,12,1, ! 12 layers symmetrical
RMORE,,,,,,,
RMORE,1,0,0.85 ! 1st layer: mat. #1, 0 deg, Th=0.85 mm
RMORE,1,90,0.85 ! 2nd layer: mat. #1, 90 deg, Th=0.85 mm
RMORE,1,0,0.85 ! 3nd layer: mat. #1, 0 deg, Th=0.85 mm
RMORE,1,90,0.85 ! 4th layer: mat. #1, 90 deg, Th=0.85 mm
RMORE,1,0,0.85 ! 5th layer: mat. #1, 0 deg, Th=0.85 mm
RMORE,1,90,0.85 ! 6th layer: mat. #1, 90 deg, Th=0.85 mm
! Geometry and mesh
RECTNG,0,500,0,250 ! Creates a rectangle with x=1 m and y=1 m
ESIZE,50 ! 50 size element edge
AMESH,all ! Mesh the area
FINISH ! Exit pre-processor module
/SOLU ! Solution module, (i) STATIC ANALYSIS
ANTYPE,STATIC ! Set static analysis
PSTRESS,ON ! Calculate the stress stiffness matrix
DL,2,1,uz,0 ! Impose Simple Supported BC
DL,3,1,uz,0
DL,1,1,symm ! Impose Symmetry BC
DL,4,1,symm
!d,all,rotz ! Constraint rotations about z axes (optional)
!Load application
SFL,2,PRES,1 ! Apply uniform pressure in x=500 mm
SFL,3,PRES,1 ! Apply uniform pressure in y=250 mm
SOLVE ! Solve current load state
FINISH ! Exit solution module
/SOLU ! Solution module, (ii) find the BIFURCATION LOADS
ANTYPE,BUCK
BUCOPT,SUBSP,10 ! Find the first 10 bifurcations loads
SOLVE ! Solve
FINISH ! Exit solution module
/SOLU ! Solution module, (ii) find the BUCKLING MODES
EXPASS
MXPAND
SOLVE ! Solve
FINISH ! Exit solution module
/PREP7 ! Pre-processor module
ftr=(10.8/10) ! Multiplicator shape factor (Th/10)
UPGEOM,ftr,1,1,file,rst
! ftr: Multiplier for displacements added to coordinates
! 1,1 : Load step 1, substep=1, equivalent to mode =1
! file,rst: results file to obtain displacements
FINISH ! Exit pre-processor module
/SOLU ! Solution module, Continuation loads
ANTYPE,STATIC ! Set static analysis
NLGEOM,1 ! Use large displacements analysis
OUTRES,ALL,ALL ! Keep results of each substep
mult=225 ! Apply loads until N = 225 N/mm
SFL,2,PRES,1*mult ! Apply uniform pressure in x=500 mm
SFL,3,PRES,1*mult ! Apply uniform pressure in y=250 mm
ARCLEN,1,10,0.1 ! Use ARCLENG method to obtain solution
NSUBST,50,0,0 ! #Substeps
SOLVE ! Solve current load state
FINISH ! Exit solution module
/POST26 ! Post-processor module
LINES,1000 ! List without breaks between pages
NSOL,2,1,U,Z,UZ_node1 ! Load deflexion in central plate node
PLVAR,2 ! DISPLAY VARIABLES evolution
PRVAR,2 ! PRINT VARIABLES evolution
FINISH |
|