本帖最后由 shifang157300 于 2010-3-15 20:39 编辑
水箱跌落分析
1.水箱从5米处跌落,接近跌落壁时的初速度约为10m/s。水箱由铝板制成。由于考虑到大变形容易引起负体积,而增加网格密度又会大大增加计算时间,故本例中水箱的壁面较厚,取为3厘米。这在命令流中有所体现。
铝的材料参数:
材料模型:Plastic Kinematic(塑性随动)
密度:2700
E:7.2E10
泊松比:0.334
Yield Stress:2.8E8
Tangent Modulus:1.4E8
Hardening Para:0.45 (0-1,0表示随动硬化,1表示各向同性硬化)
Strain Rate(C):6500
Strain Rate(P):4
Failure Strain:0.75 (失效应变)
2.由四部分组成:
Part号
| 单元类型
| 材料号
| 1(水箱)
| 2(SOLID)
| 1(铝)
| 2(水)
| 1(SOLID_ALE)
| 2(NULL)
| 3(空气)
| 1(SOLID_ALE)
| 3(NULL)
| 4(碰撞壁)
| 2(SOLID)
| 4(刚体)
|
注:上图中的欧拉流体棕色部分,是通过以下方法得到的,打开后处理器,ls-prepost,打开Ls-dyna Binary plot文件,然后打开第一个菜单卡片中的SelPar按钮,勾选Fluid选项即可。
3.水及空气均由ALE单物质单元组成,水箱壳与水体及空气体共节点,避免了进行耦合的步骤。本例中,先在ANSYS/LS-DYNA中前处理,生成K文件后进行调整。调整时推荐大家使用UltraEdit这个软件,由于K文件比较大,如果用记事本打开就会非常的卡。
4.注意事项
(1)K文件有固定的格式,多一个空格,少个空格,位置不对等等都会造成无法求解,所以推荐大家在数据之间添加逗号。
(2)注意负体积的产生,往往是由网格畸变造成的,这是加大网格密度是解决之道,或者是调整*CONTROL_TIMESTEP中的参数,将0.9调小。
(3)关于重力加速度的施加,大家会发现,本例中水箱是沿着Z轴负向跌落的,那为什么加速度会设为9.8,而不是-9.8呢,因为加速度是通过转化成力来处理的,也就是达朗贝尔原理。
(4)如果有人想要把水箱的材料设为刚体,这是需要提醒大家,再给刚体施加速度时,只能施加在一个节点上,不然求解时会出现约束过多的提示而无法继续求解。 5.命令流及其说明:
finish
/CLEAR
/units,si
/title,water_tank_drop_air_water by Pomato
/prep7
/view,1,0.12,-1,0.073 !调整视角,便于观察
/ang,1,-50
et,1,163 !随便加的,这个需要在K文件中修改
et,2,164
MeshSize1=0.025 !用于水,壳体及空气的网格划分
MeshSize2=0.1 !碰撞壁的网格划分
Height=-1.6 !用于调整跌落角度
!创建关键点
k,1,0,0,0
k,2,1,0,0
k,3,1,1,0
k,4,0,1,0
k,5,0,0,1
k,6,1,0,1
k,7,1,1,1
k,8,0,1,1
!定义水的材料
MP,DENS,1,1000
MP,EX,1,
MP,NUXY,1,
TB,EOS,1,,,2,1
TBDAT,1,-1E10
!定义空气材料
MP,DENS,2,2.79
MP,EX,2,
MP,NUXY,2,
TB,EOS,2,,,2,1
TBDAT,1,-1E10
!水箱壳的材料
MP,DENS,3,2700
MP,EX,3,7.2E10
MP,NUXY,3,0.334
TB,PLAW,3,,,1,
TBDAT,1,2.8E8
TBDAT,2,1.4E8
TBDAT,3,0.45
TBDAT,4,6500
TBDAT,5,4
TBDAT,6,0.75
!定义刚体材料,为跌落壁
EDMP,RIGI,4,0,0
MP,DENS,4,7900
MP,EX,4,210E9
MP,NUXY,4,0.3
v,1,2,3,4,5,6,7,8
!由关键点生成体
vsel,s,,,1,,
vatt,3,,2,,
esize,MeshSize1
!设置网格划分密度
vmesh,all
allsel,all
!选择水的区域,并改变材料
NSEL,S,LOC,Z,0.03,0.5000
NSEL,R,LOC,X,0.03,0.97
NSEL,R,LOC,Y,0.03,0.97
ESLN,S
MPCHG,1,all,
allsel,all
!选择空气的区域,并改变材料
NSEL,S,LOC,Z,0.4000,0.97
NSEL,R,LOC,X,0.03,0.97
NSEL,R,LOC,Y,0.03,0.97
ESLN,S
MPCHG,2,all,
allsel,all
!建立碰撞壁面
k,21,-1,-1,0.3
k,22 ,-1,2,0.3
k,23 ,2,2,Height
k,24 ,2,-1,Height
k,25,-1,-1,0.2
k,26 ,-1,2,0.2
k,27 ,2,2,Height-0.1
k,28 ,2,-1,Height-0.1
v,21,22,23,24,25,26,27,28
vsel,s,,,2,,
vatt,4,,2,,
esize,MeshSize2
vmesh,all
!下面建立PART,很重要的一步,只能在这个部位建立
edpart,create
partsel,'plot'
FLST,2,1,5,ORDE,1
!用来约束碰撞壁的所有自由度
FITEM,2,12
DA,P51X,ALL,
allsel,all
!下面考虑接触
ESEL,S,MAT,,3
NSLE,S !按材料选择水箱壳的节点
CM,WATER_TANK,NODE !建立WATER_TANK组件
allsel,all
ESEL,S,MAT,,4
NSLE,S
!选择碰撞壁的节点
CM,DROP_WALL,NODE !建立DROP_WALL组件
allsel,all
!建立节点到面得接触对
EDCGEN,ANTS,WATER_TANK,DROP_WALL,0.3,0.18,0,0,0, , , , ,0,10000000,0,0
!定义所有跌落物质节点组,为施加初速度和重力加速度
ESEL,S,MAT,,1
ESEL,A,MAT,,2
ESEL,A,MAT,,3
NSLE,S
CM,DROP_ALL,NODE
ALLSEL,ALL
!定义重力加速度曲线
*DIM,TIME,ARRAY,2,1,1, , ,
*SET,TIME(1,1,1) , 0
*SET,TIME(2,1,1) , 1
*DIM,ACC,ARRAY,2,1,1, , ,
*SET,ACC(1,1,1) , 9.81
*SET,ACC(2,1,1) , 9.81
!施加重力加速度
EDLOAD,ADD,AZ,0,DROP_ALL,TIME,ACC, 0, , , , ,
!施加初始速度
EDVE,VELO,DROP_ALL,0,0,-10,0,0,0, , , , , ,
TIME,1, !求解时间设为1秒
EDCTS,0,0.9,
EDRST,1000,
EDHTIME,100,
EDDUMP,1,
6.修改关键字文件
因这部分格式很重要,故见附件修改关键字关键字,关键字添加的位置无所谓,但要在相应的卡片内,比如材料设置要在材料卡片里
|