算例 电磁学

佛法无边512

!/BACH,LIST
/TITLE,2D SOLENOID Actuator Static Analysis ! 定义工作标题
/FILNAME,Emage_2D,1                         ! 定义工作文件名
KEYW,MAGNOD,1                               ! 指定磁场分析
/PREP7
ET,1,PLANE13                                ! 指定单元类型
KEYOPT,1,3,1                                ! 指定分析类型为轴对称
MP,MURX,1,1                                 ! 定义空气的材料特性
MP,MURX,2,1000                              ! 定义铁芯的材料特性
MP,MURX,3,1                                 ! 定义线圈的材料特性
MP,MURX,4,2000                              ! 定义衔铁的材料特性
N=650                                       ! 线圈匝数
I=1.0                                       ! 每匝电流
TA=0.75                                     ! 模型尺寸参数（厘米）
TB=0.75
TC=0.50
TD=0.75
WC=1
HC=2
GAP=0.25
SPACE=0.25
WS=WC+2*SPACE
HS=HC+0.75
W=TA+WS+TC
HB=TB+HS
H=HB+GAP+TD
ACOIL=WC*HC                               ! 线圈横截面积（cm2）
JDENS=N*I/ACOIL                           ! 电流密度（A/cm2）
/PNUM,AREA,1                              ! 打开面区域编号
RECTNG,0,w,0,tb                           ! 生成几何模型
RECTNG,0,w,tb,hb
RECTNG,ta,ta+ws,0,h
RECTNG,ta+space,ta+space+wc,tb+space,tb+space+hc
AOVLAP,ALL
SAVE
RECTNG,0,w,0,hb+gap
RECTNG,0,w,0,h
AOVLAP,ALL
NUMCMP,AREA                               ! 压缩编号
APLOT
SAVE,Emage_2D_geom.db                     ! 保存几何模型到文件
SAVE
ASEL,S,AREA,,2                            ! 给线圈区域赋予材料特性
AATT,3,1,1,0
ASEL,S,AREA,,1                            ! 给衔铁区域赋予材料特性
ASEL,A,AREA,,12,13
AATT,4,1,1,0
ASEL,S,AREA,,3,5                          ! 给铁芯区域赋予材料特性
ASEL,A,AREA,,7,8
AATT,2,1,1,0
/PNUM,MAT,1                               ! 打开材料编号
ALLSEL,ALL
APLOT
SMRTSIZE,4                                ! 设置智能化划分网格等级
AMESH,ALL                                 ! 划分自由网格
SAVE,Emage_2D_Mesh.db                     ! 保存网格单元数据到文件
SAVE
ESEL,S,MAT,,4                             ! 选择衔铁上的所有单元
CM,ARM,ELEM                               ! 生成一个组件
FMAGBC,'ARM'                              ! 给衔铁加力边界条件
ALLSEL,ALL
ARSCAL,ALL,,,0.01,0.01,1,,0,1             ! 改变单位制为MSK单位（米）
FINISH
/SOLU
ESEL,S,MAT,,3                              ! 选择线圈上的单元
BFE,ALL,JS,1,,,JDENS/(0.01**2)             ! 施加电流密度载荷
ALLSEL,ALL
NSEL,EXT                                   ! 选择外层节点
D,ALL,AZ,0                                 ! 施加磁力线平行边界条件
ALLSEL,ALL
MAGSOLV,0,3,0.001,,25                      ! 求解并运算
SAVE,Emage_2D_resu.db                      ! 保存计算结果
SAVE
FINISH
/POST1
PLF2D,27,0,10,1                            ! 显示磁力线图
FMAGSUM,'ARM'                             ! 对电磁力求和
PLVECT,B,,,,VECT,ELEM,ON,0                 ! 显示磁通密度矢量  
/GRAPHICS,POWER
AVRES,2
PLNSOL,B,SUM                               ! 显示磁通密度等值云图
FLISH

2208001017

好东西，怎么没有人光顾

sjtuzpf

好东西  不错 顶起来

2208001017

你这个注释都没有，像我这样的菜鸟看不懂

bowen550503

好像是某本书上的是吧？

guyan1349

是某本书上的是吧，其实就是里面的HELP的例子

monkey0012345

确实很像一本书上的，是不是孙明礼那本上面的？。。。

zjhiae

不错的例子。。。。。。。。。。。

liuer2004_82

有高频的吗?

eagle1208

谢谢              

panda_neiep

不错，简单易懂

奔跑的蜗牛

好东西啊

mashangguan

试试，看看有没有用，现在刚好在做这个三维模型

繁华散落一地啊

很好的例子。。

匆匆独行

不错的例子