找回密码
 注册
Simdroid-非首页
查看: 261|回复: 4

【原创】在同一个面上施加heat flux 和 conv的例子

[复制链接]
发表于 2010-7-17 02:18:07 | 显示全部楼层 |阅读模式 来自 美国
本帖最后由 iomega 于 2010-7-16 10:21 编辑

看到版上一直有人问如何在同一个面上施加heat flux 和 conv,所以用APDL写了一个例子来demo,以下是带注解的源程序。

用solid70 创建一个3D的block,
在z=4m的表面: (1) 用surf152施加H= 50W/m^-K的conv . (2)施加hflux在solid70 element上.
在z=0m的表面: 施加h=10的conv,  在solid70 element上。

Temperature Contour plot  显示: H=50W/m^2-K 和  H=10W/m^2-K

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FINISH
/CLEAR
/PREP7
SMRT,OFF
/TITLE, EXAMPLE OF USING SURFACE ELEMENT FOR CONVECTION

ET,1,SOLID70            ! 3-D THERMAL SOLID ELEMENT
ET,2,SURF152,,,,1,1     ! 3-D THERMAL SURFACE EFFECT ELEMENTS
KEYOPT,2,8,4            ! CONVECTION OPTION
KEYOPT,2,9,0            ! NO RADIATION OPTION

MP,KXX,1,10               ! ARBITRARY CONDUCTIVITY
BLOCK,0,2,0,2,0,4      ! DEFINE THE BLOCK GEOMETRY
TYPE,1
ESIZE,0.5
VMESH,all                    ! MESH WITH A SINGLE SOLID70 ELEMENT

TYPE,2
N,300,1,1,5                 !DEFINE AN EXTERNAL NODE
ASEL,S,LOC,z,4,4        
NSLA,S,1
ESLN,S,0
ESURF,300               !CREATE SURFACE ELEMENTS ON SURFACE OF Z=4
ALLSEL,ALL

FINISH

/SOLU
SOLCONTROL,0
ANTYPE,STATIC         ! STEADY STATE ANALYSIS
ALLSEL,ALL
T_AMB = 20
H= 10                           ! HEAT TRANSFER COEFFICIENT H =  50 W/m^2-K   



D,300,TEMP,T_AMB         ! SPECIFY SURROUNDING BULK TEMPERATURE FOR CONVECTION
ESEL,S,TYPE,,2
SFE,ALL,,CONV,,H
SFE,ALL,,CONV,2,T_AMB    !APPLY HEAT CONVECTION ON BLOCK AT Z = 4 USING SURFACE ELEMENTS


NSEL,S,LOC,Z,4,4
ESLN,S
ESEL,R,TYPE,,1
SFE,ALL,6,HFLUX,,1000    !APPLY HEAT FLUX ON BLOCK AT Z = 4 ON SOLID70


NSEL,S,LOC,Z,0,0
ESLN,S
SFE,ALL,1,CONV,,10
SFE,ALL,1,CONV,2,T_AMB   !APPLY HEAT CONVECTION ON BLOCK AT Z = 0



ALLSEL,ALL
SOLVE

/POST1  
/EFACET,1   
PLNSOL, TEMP,, 0
/VIEW,1,1,1,1   
/ANG,1  
/REP,FAST   
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

×
发表于 2014-9-19 17:21:50 | 显示全部楼层 来自 安徽
Simdroid开发平台
楼主,如何写一个循环加载载荷的APDL?
回复 不支持

使用道具 举报

发表于 2014-11-29 23:22:34 | 显示全部楼层 来自 安徽
请问,我在用经典界面定义表格载荷时,对流换热系数的“行标题”是什么呢?我用CONV后,提示missing paremeter=CONV,意思是ANSYS不认这个变量,请问这个变量名应该是什么啊。。。
谢谢!
回复 不支持

使用道具 举报

发表于 2015-1-26 21:43:43 | 显示全部楼层 来自 江苏苏州
感谢楼主啦!
回复 不支持

使用道具 举报

发表于 2017-11-9 10:59:54 | 显示全部楼层 来自 山东济南
:P:P:P:P
回复 不支持

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|小黑屋|联系我们|仿真互动网 ( 京ICP备15048925号-7 )

GMT+8, 2024-3-29 17:31 , Processed in 0.064759 second(s), 13 queries , Gzip On, MemCache On.

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表