Spinski分形三角形问题（代码优化问题）【已解决】

treemantan

有哪位大侠能看看吗，(Spinski分形三角形)

我只会用Block,我开始觉得一行应该能搞定，应该用迭代NestList就可以，但最后用了Block，还有我觉得不该出现的Do：

1. v0 = {{0, 0}, {1, 0}, {0.5, Sqrt[3]/2}}
   
2. Manipulate[
   
3. Block[{x = {0, 0}, i = 0, v = {}},
   
4.   Do[i = RandomInteger[{1, 3}]; AppendTo[v, x];
   
5.    x = Mean[{x, v0[]}], {j, 1, counter, 1}];
   
6.   Graphics[Point[v]]], {counter, 1, 8000, 1}]

复制代码

chungyuandye

1. 
   
2. newpt[x_List] := {{x[[1]], Mean@{x[[1]], x[[2]]},
   
3.     Mean@{x[[1]], x[[3]]}}, {x[[2]], Mean@{x[[2]], x[[1]]},
   
4.     Mean@{x[[2]], x[[3]]}}, {x[[3]], Mean@{x[[3]], x[[1]]},
   
5.     Mean@{x[[3]], x[[2]]}}};
   
6. pt = {{0, 0}, {2, 0}, {1, Sqrt[3]}};
   
7. Stgraph[n_] :=
   
8. Graphics[{Red,
   
9.    Polygon /@
   
10.     Nest[Flatten[ParallelMap[newpt, #], 1] &, {pt}, n]}]; Manipulate[
    
11. Stgraph[i], {i, 1, 7, 1}]
    

复制代码

chyanog

lz的代码是想按照chao game的方法来画吧？

1. ListPlot@NestList[(# + RandomChoice[{{0, 0}, {1, 0}, {.5, .8}}])/2 &,  N@{0, 0}, 10^4]
   
2. 
   
3. (*着色的*)
   
4. With[{data =  NestList[(# + RandomChoice@{{0, 0}, {1, 0}, {.5, .8}})/2 &,  N@{0, 0}, 10^4]},
   
5. Graphics[Point[data, VertexColors -> ({1, #[[1]], #[[2]]} & /@ Rescale@data)]]]
   
6. 
   
7. (*推广到3D*)
   
8. Module[{v, pts, vc},
   
9. v = {{0, 0, 0.6}, {-0.3, -0.5, -0.2}, {-0.3, 0.5, -0.2}, {0.6,  0, -0.2}};
   
10. pts = NestList[(# + RandomChoice[v])/2 &, N@{0, 0, 0}, 10^4];
    
11. vc = ColorData["Pastel", #] & /@ Rescale@pts[[All, 3]];
    
12. Graphics3D@Point[pts, VertexColors -> vc]
    
13. ]

复制代码

用Polygon的画法，

1. triangle[{a_, b_, c_}] := {{a, (a + c)/2, (a + b)/2}, {(a + b)/2, b, (b + c)/2}, {(a + c)/2, (b + c)/2, c}};
   
2. d = Nest[Join @@ triangle /@ # &, N@{{{0, 0}, {1, 0}, {.5, .8}}}, 3];
   
3. Graphics[Polygon /@ d]
   
4. 
   
5. (*triangle=Map[Mean,Partition[Tuples[#,2],3],{2}]&;*)

复制代码