热力耦合中,结构分析部分结果太差了,请各位大仙指点
做齿轮的加工分析,在齿面上施加HFLUX载荷,然后载荷延齿轴向移动,温度场分析完了之后,再分析结构部分(ps:命令流中'10.10.1','rth'为前部分温度场分析的结果)。结构部分将模型简化了,在齿面上施加PRES载荷,但是分析的结果总感觉太烂了,求各位大仙指点。
本人ansys新手,这个分析中,也参照了一些书上和网友的例子,可能也有不准确的地方,请路过的高手们批评指正啊
上命令流:
FINISH
/CLEAR,START
/VIEW,,1,1,1
/TRIAD,OFF
/PREP7
/UNITS,SI
ET,1,SOLID70
ET,2,SURF152
KEYOPT,2,8,4
MPTEMP,,,,,,,
MPTEMP,1,0
MP,KXX,1,41.8
MP,C,1,4.18e2
MP,DENS,1,7.85e3
*SET,H,1000 !设置比例尺
*SET,A,360/28 !计算出每个齿所占有的角度
X1=5.110/H
Y1=82.342/H
X2=5.411/H
Y2=80.820/H
LZ=10/H !Z向长度
N=20 !Z向载荷步数
V=0.1 !热源移动速度
LSIZE=LZ/N !每个载荷步的尺寸
TM=LZ/V !一次进程的时间
TINC=TM/N !一次载荷步时间
K,,5.428/H,76.307/H,, !生成第一个关键点
K,,5.534/H,77.803/H,,
K,,5.595/H,79.303/H,,
K,,5.411/H,80.820/H,,
K,,5.110/H,82.342/H,,
K,,4.694/H,83.869/H,,
K,,4.208/H,85.396/H,,
K,,3.623/H,86.920/H,,
K,,2.928/H,88.450/H,,
K,,2.214/H,90.00/H,, !生成第10个关键点
FLST,3,10,3 !拾取10个关键点生成样条曲线
*DO,I,1,10
FITEM,3,I
*ENDDO
BSPLIN,,P51X
LSYMM,X,1,,,,0,0 !生成样条曲线
LSTR,10,12 !连接齿顶圆的直线
CYL4,,,66/H,90-A/2,76.5/H,90+A/2 !生成部分圆弧命令,生成轮腹
A,1,10,12,11 !按顺序拾取4个关键点,生成齿轮
AADD,1,2 !轮齿面与轮腹面相加
LSTR,11,1
ASBL,3,4
LANG,6,11,90,0,0.7795985579962686
LANG,6,1,90,0,0.2212237566116800
ASBL,2,11
ASBL,4,13
LESIZE,5,,,15,,,,,1
LESIZE,7,,,15,,,,,1
LESIZE,11,,,15,,,,,1
LESIZE,13,,,15,,,,,1
LESIZE,3,,,10,,,,,1
LESIZE,4,,,10,,,,,1
LESIZE,12,,,10,,,,,1
LESIZE,6,,,3,,,,,1
LESIZE,8,,,3,,,,,1
LESIZE,1,,,40,,,,,1
ESIZE,0,20, !Z向划分网格数
VOFFST,1,LZ, ,
VOFFST,2,LZ, ,
VOFFST,3,LZ, ,
VOFFST,5,LZ, ,
ALLSEL,ALL
TYPE,1
VMESH,ALL
EPLOT !显示所选择的单元网格
ESEL,S,TYPE,,1 !选择单元类型号为1的单元
ASEL,S, , , 16 !选择面的子集
ASEL,A, , , 15
ASEL,A, , , 10
ASEL,A, , , 20
ASEL,A, , , 4
ASEL,A, , , 7
ASEL,A, , , 8
ASEL,A, , , 21
ASEL,A, , , 1
ASEL,A, , , 5
ASEL,A, , , 2
ASEL,A, , , 3
TYPE,2 !设置单元类型号2
AMESH,ALL !划分网格
ESEL,S,TYPE,,2 !选择单元类型号为2的单元
SF,ALL,CONV,5,20 !节点上加热对流,5换热系数,20参考温度
FINISH
/SOLU
ANTYPE,TRANS !指定分析类型为瞬态分析
TRNOPT,FULL !用完成法进行求解
TOFFST,273.16 !设置一个温度单位制
TUNIF,20 !设置初始均匀温度
I=0
*DO,t,1E-6,TM,TINC
Z1=I*LSIZE
Z2=I*LSIZE+LSIZE
TIME,t
AUTOTS,O !关闭自动时间步长
DELTIM,,,,1 !在本载荷步中指定时间步长
KBC,0 !设置加载方式为递增方式
TINTP,,,,1 !指定瞬态积分参数
OUTRES,ALL,ALL !设置输出
NSUBST,3 !设置子载荷步
ALLSEL !选取全部模型
ESEL,S,TYPE,,1 !选择单元类型号为1的单元
ASEL,R, , , 6 !选择面的子集
NSEL,R,LOC,X,X1,X2 !选择节点的子集
NSEL,R,LOC,Y,Y2,Y1
NSEL,R,LOC,Z,Z1,Z2
SF,ALL,HFLUX,1.535e8 !在节点上施加热流量载荷
ALLSEL !选取全部模型
ESEL,S,TYPE,,1 !选择单元类型号为1的单元
ASEL,R, , , 6 !选择面的子集
NSEL,R,LOC,X,X1,X2
NSEL,R,LOC,Y,Y2,Y1
NSEL,U,LOC,Z,Z1,Z2 !删除选择节点的子集
SF,ALL,CONV,20,20 !节点上加热对流,20换热系数,20参考温度
ALLSEL
SOLVE
ALLSEL
ESEL,S,TYPE,,1 !选择单元类型号为1的单元
ASEL,R, , , 6 !选择面的子集
SFDELE,ALL,HFLUX !删除所有的热流量载荷
SFDELE,ALL,CONV !删除所有的热对流载荷
I=I+1
*ENDDO
FINISH
/POST1
/PLOPTS,DATE,0
/TITLE,TEMPTERATURE CONTOURS
PLNSOL,TEMP
FINISH
!*
/COM,Structural
!热转化为结构分析命令如下:
/prep7
!单元转换的方式,下面:
LSCLEAR,ALL
ETCHG,TTS !单元转换
MP,EX,1,2.1E11 !输入材料弹性模量
MP,ALPX,1,17.79E-6 !线膨胀系数
MP,NUXY,1,0.3 !泊松比
MP,KXX,1,41.8 !导热系数
MP,C,1,4.18e2 !比热容
MP,DENS,1,7.85e3 !密度
FINISH
/SOLU !进入求解器
LDREAD,TEMP,,, , ,'10.10.1','rth',' ' !施加温度载荷
ALLSEL,ALL
FLST,2,2,5,ORDE,2 !施加对称约束
FITEM,2,17
FITEM,2,24
DA,P51X,SYMM
FLST,2,3,5,ORDE,3 !施加UY方向上的约束
FITEM,2,13
FITEM,2,18
FITEM,2,23
!*
/GO
DA,P51X,UY,
FLST,2,3,5,ORDE,3 !施加UZ方向上的约束
FITEM,2,13
FITEM,2,18
FITEM,2,23
!*
/GO
DA,P51X,UZ,
ALLSEL,ALL
ANTYPE,TRANS !指定分析类型为瞬态分析
TRNOPT,FULL !用完成法进行求解
!只加一次
TIME,TINC
AUTOTS,O !关闭自动时间步长
DELTIM,,,,1 !在本载荷步中指定时间步长
KBC,0 !设置加载方式为递增方式
TINTP,,,,1 !指定瞬态积分参数
NSUBST,10 !设置子载荷步
ALLSEL !选取全部模型
ESEL,S,TYPE,,1 !选择单元类型号为1的单元
ASEL,R, , , 6 !选择面的子集
NSEL,R,LOC,X,X1,X2 !选择节点的子集
NSEL,R,LOC,Y,Y2,Y1
SF,ALL,PRES,7.895E6 !在节点上施加压力
OUTRES,ALL,ALL
ALLSEL
SOLVE
上一张图
页:
[1]