【分享】;ansys几个小算例！（焊接方面）
事先声明，可能有的算例以前贴子有，但这次我综合在一块了，这几个例子值的好好看看！1.单元生死
问题描述
等截面杆两端固定，承受均匀的温度载荷时将其中间1/3段移去。过程是将其应变自由化并移去均匀温度。分析其热应力和应变情况。
/PREP7
/TITLE, ELEMENT BIRTH/DEATH IN A FIXED BAR WITH THERMAL LOADING
ET,1,LINK1 !二维杆单元
MP,EX,1,30E6 !材料特性
MP,ALPX,1,.00005
MP,EX,2,30E6
MP,ALPX,2,.00005 !重新‘出生’单元的特性
MP,REFT,2,100 !单元出生的参考温度
R,1,1.0
N,1
N,4,10
FILL
E,1,2
EGEN,3,1,-1 !生成三个单元
FINISH
/SOLU
ANTYPE,STATIC
D,1,ALL,,,4,3 !固定杆的两端
TREF,0 !参考温度0度
TUNIF,100 !均匀温度载荷
NROPT,FULL
OUTPR,BASIC,ALL
SOLVE
EKILL,2 !‘杀死’中间的单元
SOLVE
EALIVE,2 !重新激活中间单元
MPCHG,2,2 !将材料特性改为2以生成自由应变单元
SOLVE
TUNIF,0 !删除温度载荷
SOLVE
回复： 【分享】;ansys几个小算例！（焊接方面）
2.直接法焊接分析（推荐）!下面的命令流进行的是一个简单的二维焊接分析, 利用ANSYS单元生死和热-结构耦合分析功能进
!行焊接过程仿真, 计算焊接过程中的温度分布和应力分布以及冷却后的焊缝残余应力。
/title,Weld Analysis by "Element Birth and Death"
/prep7
/unit,si ! 采用国际单位制
!
et,1,13,4 ! 13号二维耦合单元, 同时具有温度和位移自由度
et,2,13,4
!
! 1号材料是钢
! 2号材料是铝
! 3号材料是铜
! 铝是本次分析中的焊料, 它将钢结构部分和铜结构部分焊接起来
! 下面是在几个温度点下, 各材料的弹性模量
mptemp,1,20,500,1000,1500,2000
mpdata,ex,1,1,1.93e11,1.50e11,0.70e11,0.10e11,0.01e11
mpdata,ex,2,1,1.02e11,0.50e11,0.08e11,0.001e11,0.0001e11
mpdata,ex,3,1,1.17e11,0.90e11,0.30e11,0.05e11,0.005e11
!
! 假设各材料都是双线性随动硬化弹塑性本构关系
! 下面是各材料在各温度点下的屈服应力和屈服后的弹性模量
tb,bkin,1,5
tbtemp,20,1
tbdata,1,1200e6,0.193e11
tbtemp,500,2
tbdata,1, 933e6,0.150e11
tbtemp,1000,3
tbdata,1, 435e6,0.070e11
tbtemp,1500,4
tbdata,1, 70e6,0.010e11
tbtemp,2000,5
tbdata,1, 7e6,0.001e11
!
tb,bkin,2,5
tbtemp,20,1
tbdata,1,800e6,0.102e11
tbtemp,500,2
tbdata,1,400e6,0.050e11
tbtemp,1000,3
tbdata,1, 70e6,0.008e11
tbtemp,1500,4
tbdata,1, 1e6,0.0001e11
tbtemp,2000,5
tbdata,1,0.1e6,0.00001e11
!
tb,bkin,3,5
tbtemp,20,1
tbdata,1,900e6,0.117e11
tbtemp,500,2
tbdata,1,700e6,0.090e11
tbtemp,1000,3
tbdata,1,230e6,0.030e11
tbtemp,1500,4
tbdata,1, 40e6,0.005e11
tbtemp,2000,5
tbdata,1, 4e6,0.0005e11
!
! 材料密度(假设为常值)
mp,dens,1,8030
mp,dens,2,4850
mp,dens,3,8900
! 热膨胀系数(假设为常值)
mp,alpx,1,1.78e-5
mp,alpx,2,9.36e-6
mp,alpx,3,1.66e-5
! 泊松比(假设为常值)
mp,nuxy,1,0.29
mp,nuxy,2,0.30
mp,nuxy,3,0.30
! 热传导系数(假设为常值)
mp,kxx,1,16.3
mp,kxx,2,7.44
mp,kxx,3,393
! 比热(假设为常值)
mp,c,1,502
mp,c,2,544
mp,c,3,385
! 热膨胀系数(假设为常值)
! 由于该13号单元还有磁自由度, 此处假设一磁特性, 但并不影响我们所关心的结果
mp,murx,1,1
mp,murx,2,1
mp,murx,3,1
! 假设焊料(铝)焊上去后的初始温度是1500℃
mp,reft,1,20
mp,reft,2,1500
mp,reft,3,20
!
! 下面建立几何模型
csys,0
k,1,0,0,0
k,2,0.5,0,0
k,3,1,0,0
k,4,0,0.3,0
k,5,0.35,0.3,0
k,6,0.65,0.3,0
k,7,1,0.3,0
a,1,2,5,4
a,2,6,5
a,2,3,7,6
! 划分单元
esize,0.025
type,2
mat,2
amesh,2
esize,0.05
type,1
mat,1
amesh,1
mat,3
amesh,3
eplot
!
/solu
antype,4 ! 瞬态分析
trnopt,full
!
! 在模型的左边界加位移约束
nsel,all
*get,minx,node,,mnloc,x
nsel,s,loc,x,minx
d,all,ux,0
*get,miny,node,,mnloc,y
nsel,r,loc,y,miny
d,all,uy,0
!
! 假设在模型的左右边界处温度始终保持在20℃, 其它边界条件如对流、辐射等都可
! 施加，此处因只是示意而已，故只施加恒温边界条件。
nsel,all
*get,minx,node,,mnloc,x
nsel,s,loc,x,minx
d,all,temp,20
nsel,all
*get,maxx,node,,mxloc,x
nsel,s,loc,x,maxx
d,all,temp,20
!
! 由于第二个面是焊料所在区域，因此，首先将该区域的单元"死"掉
nna=2
esel,all
*get,emax,elem,,num,max
asel,s,area,,nna
esla
*get,nse,elem,,count
*dim,ne,,nse
*dim,nex,,nse
*dim,ney,,nse
*dim,neorder,,nse
mine=0
! 下面的DO循环用于将焊料区的单元按其形心Y坐标排序，以便后面
! 模拟焊料由下向上逐步"生长"的过程
*do,i1,1,nse
esel,u,elem,,mine
*get,nse1,elem,,count
ii=0
*do,i,1,emax
*if,esel(i),eq,1,then
ii=ii+1
ne(ii)=i
*endif
*enddo
*do,i,1,nse1
*get,ney(i),elem,ne(i),cent,y
*get,nex(i),elem,ne(i),cent,x
*enddo
miny=1e20
minx=1e20
*do,i,1,nse1
*if,ney(i),lt,miny,then
miny=ney(i)
minx=nex(i)
mine=ne(i)
*else
*if,ney(i),eq,miny,then
*if,nex(i),lt,minx,then
miny=ney(i)
minx=nex(i)
mine=ne(i)
*endif
*endif
*endif
*enddo
neorder(i1)=mine
*enddo
!
max_tem=1500 ! 按照前面假设，焊料的初始温度为1500℃
dt1=1e-3 ! 用于建立初始条件的一个很小的时间段
dt=5 ! 焊接一个单元所需的时间
t=0 ! 起始时间
esel,all
eplot
/auto,1
/replot
*do,i,1,nse
ekill,neorder(i)
esel,s,live
eplot
*enddo
allsel,all
outres,all,all
ic,all,temp,20
kbc,1
timint,0,struct
timint,1,therm
timint,0,mag
tintp,0.005,,,1,0.5,0.2
!
!
nsub1=2
nsub2=40
*do,i,1,nse
ealive,neorder(i)
esel,s,live
eplot
esel,all
! 下面的求解用于建立温度的初始条件
t=t+dt1
time,t
nsubst,1
*do,j,1,4
d,nelem(neorder(i),j),temp,max_tem
*enddo
solve
! 下面的求解用于保证初始的升温速度为零
t=t+dt1
time,t
solve
! 下面的步骤用于求解温度分布
*do,j,1,4
ddele,nelem(neorder(i),j),temp
*enddo
t=t+dt-2*dt1
time,t
nsubst,nsub1
solve
*enddo
t=t+50000
time,t
nsubst,nsub2
solve
finish
/post1
! 下面的一系列命令用于生成应力的动画文件
/seg,dele
/cont,1,15,0,1200e6/16,1200e6
/dscale,1,1.0
avprin,0,0
avres,1
/seg,multi,stress,0.1
esel,all
*do,i,1,nse
esel,u,elem,,neorder(i)
*enddo
*do,i,1,nse
esel,a,elem,,neorder(i)
set,(i-1)*3+1,1
plnsol,s,eqv
*do,j,1,nsub1
set,(i-1)*3+3,j
plnsol,s,eqv
*enddo
*enddo
*do,i,1,nsub2
set,(nse-1)*3+4,i
plnsol,s,eqv
*enddo
/seg,off,stress,0.1
/anfile,save,stress,avi
! 下面的一系列命令用于生成温度的动画文件
/seg,dele
/cont,1,15,0,1500/16,1500
/dscale,1,1.0
avprin,0,0
avres,1
/seg,multi,temp,0.1
esel,all
*do,i,1,nse
esel,u,elem,,neorder(i)
*enddo
*do,i,1,nse
esel,a,elem,,neorder(i)
set,(i-1)*3+1,1
plnsol,temp
*do,j,1,nsub1
set,(i-1)*3+3,j
plnsol,temp
*enddo
*enddo
*do,i,1,nsub2
set,(nse-1)*3+4,i
plnsol,temp
*enddo
/seg,off,temp,0.1
/anfile,save,temp,avi
finish
回复： 【分享】;ansys几个小算例！（焊接方面）
3.焊接/prep7
/UNITS,si
et,1,solid70
mp,c,1,544.28
mp,kxx,1,15.06
mp,dens,1,4500
block,0,30,0,15,0,3
esize,1
vmesh,all
FINISH
/SOLU
!PARAMETER TABLE TO INPUT HEAT FLUX AS A MOVING SOURCE
!SPEED OF HEAT SOURCE IN X DIRECTION v=(200/60)m/s
!GAUSS VARIATION ASSUMED IN X & Y DIRECTION AS q=qmax/EXP(K*R**2)
!TOTAL HEAT INPUT Q=3.14*qmax/K
!DIMENSIONING TABLE NAMED "FLUX2"
v=1
L=30
NUM_TIME=L/v+1
NUM_X=L/v+1
*DIM,FLUX2,TABLE,NUM_TIME,NUM_X,7,TIME,X,Y
*DO,K,1,7,1
*DO,I,1,NUM_TIME,1
FLUX2(I,0,K)=(I-1)
*ENDDO
*DO,J,1,NUM_X,1
FLUX2(0,J,K)=(J*v-v)
*ENDDO
Q=1000
KAPA=1/4
qmax=((Q*KAPA)/3.14159)
PERCENT=0.98
RADIUS=ABS(SQRT(1/KAPA*LOG(1/(1-PERCENT))))
!N=
*DO,ANTIME,1,NUM_TIME,1
*DO,N,0,15,1
XDIST=(N*v)
*IF,(ANTIME-N),GT,0,THEN
*IF,SQRT((XDIST)**2+((RADIUS/6)*(K-1))**2),LE,RADIUS,THEN
!
GAUSS=qmax/EXP(KAPA*((XDIST)**2+((RADIUS/6)*(K-1))**2))
FLUX2(ANTIME,ANTIME-N,K)=GAUSS*10e5
!
*ELSE
*ENDIF
*ENDIF
!
*IF,(ANTIME+N),LE,NUM_TIME,THEN
*IF,SQRT((XDIST)**2+((RADIUS/6)*(K-1))**2),LE,RADIUS,THEN
!
GAUSS=qmax/EXP(KAPA*((XDIST)**2+((RADIUS/6)*(K-1))**2))
FLUX2(ANTIME,ANTIME+N,K)=GAUSS*10e5
!
*ELSE
*ENDIF
*ENDIF
*ENDDO
*ENDDO
!
!INPUT Y DIRECTION DIVISIONS
!---------------------------
FLUX2(0,0,K)=(K-1)*(RADIUS/6)
*ENDDO
antype,trans
tunif,20
kbc,1
*SET,delt,1
timint,on
autots,off
*do,tm,1e-6,30,0.5
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
FLST,2,1,5,ORDE,1
FITEM,2,2
/GO
!*
TIME,tm
AUTOTS,0
DELTIM, , , ,1
KBC,0
!*
TSRES,ERASE
FLST,2,1,5,ORDE,1
FITEM,2,2
/GO
!*
!*
SFA,P51X,1,HFLUX, %FLUX2%
/STATUS,SOLU
SOLVE
OUTRES,ALL,ALL,
/PSF,hflux,,2
/replot
*enddo
OUTRES,ALL,ALL,
FINISH
回复： 【分享】;ansys几个小算例！（焊接方面）
4.薄板屈曲prep7
!定义单元类型，实常数，材料特性
ET,1,SHELL143
R,1,31.75, , , , ,
MP,EX,1,2.1e5
MP,NUXY,1,0.3
!双线性随动强化模型
TB,BKIN,1,1,2,1
TBDATA,,235,0,,,,
!定义节点,初始挠度为双正弦曲线,6*8网格
*do,i,1,7
*do,j,1,9
k=(i-1)*9+j
x=317.5*(j-1)
y=370.416667*(i-1)
z=2.54*sin(3.1415926*y/2222.5)*sin(3.1415926*x/2540)
n,k,x,y,z
*enddo
*enddo
!定义单元
*do,i,1,5
*do,j,1,8
k1=(i-1)*9+j
k2=k1+1
k3=k2+9
k4=k3-1
e,k1,k2,k3,k4
*enddo
*enddo
*do,i,6,6
*do,j,1,8
k1=(i-1)*9+j
k2=k1+1
k3=k2+9
k4=k3-1
e,k4,k3,k2,k1
*enddo
*enddo
!定义边界条件,四边简支,采用了等效边界条件
*do,i,1,9
d,i,uz,0
d,i+54,uz,0
*enddo
*do,j,1,7
k=(j-1)*9+1
d,k,uz,0
d,k+8,uz,0
*enddo
d,32,ux,0
d,32,uy,0
!定义荷载
*do,i,1,8
SFE,i,3,PRES,1,7461.25,7461.25,0,0
SFE,i,3,PRES,2,0,0,0,0
SFE,i+40,3,PRES,1,7461.25,7461.25,0,0
SFE,i+40,3,PRES,2,0,0,0,0
*enddo
!输出每个子步的结果
OUTRES,ALL,ALL,
antype,0 !分析类型
!设定大变形，应力刚化
NLGEOM,1
SSTIF,ON
NSUBST,20
!下面用弧长法求解下降段
arclen,ON
arctrm,u,120,32,uz
finish
/solu
SOLVE
/POST26
NSOL,2,32,U,Z,
Xvar,2
PLVAR,1, , , , , , , , , ,
回复： 【分享】;ansys几个小算例！（焊接方面）
5。ansys70进行焊接分析 留名 关注 很好的帖子 定 很不错，正在研究焊接值得学习啊 焊接模拟学习中谢谢分享!:lol 楼主总结的很全面。
给大家提供了很好的学习素材，谢谢啦！ 谢谢提供下载学习了！
致谢
感谢楼主的:) 热心hehe
收藏关注 谢谢分享！正在学习焊接的模拟 学习了 谢谢学习了
不错的资料 非常感谢分享，认真学习了 全是命令流啊，看不懂 楼主够意思 感谢提供！
顺便问一句：有没有关于起重机 大梁分析的例子？
大梁为板材焊接结构、箱型