..:: ANSYS专区-工程,拱坝,混凝土,施工期,温度场-【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流，{Simwe仿真论坛(forum.simwe.com)，CAE/CAD/CAM/，FEA/FEM/有限元分析论坛-(手机验证注册)}

kkkyyy 发表于 2003-11-18 06:10:45

【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

http://okok.org/cgi-bin/ut/topic_show.cgi?id=42320&h=1#192171

  帖一个某混凝土拱坝工程施工期及运行期温度场仿真分析数据流，供大家参考。
      附件中有两个文件：CA1*为计算数据流，DAQI.FUC为大气年变化的周期函数.
      计算简介:
      1.施工期共分37层,每层1.5米
      2.施工期及坝体建成后一个月的时间步长按天考虑,随后32个月时间步长按月计.
      3.计算中多年平均气温作为岩体初始温度场,各层砼浇筑温度作为其激活时的初始温度;
      4.岩体边界按绝热边界条件(第一类边界条件);大气与坝面按对流边界条件（第一类边界条件）施加;按分段线性插值函数计水化热。

====================
!!!!**********************************************************************
!!!!**********************************************************************
!!!!***************某拱坝温度施工期与运行期仿真分析数据流*****************
!!!!************************* ZH.EI ************************************
!!!!**********************************************************************

!!!**************注意事项**********************************
!!1.对流边界条件应先选节点,再将所加边界条件加在相应的单元上.
!!2.加对流条件时结点及相应单元必须都选.

!2003.03.01
!按施工单位提供的浇筑方案.浇筑温度等于月平均温度.温控措施,上游水温取河水温度，保温.

FINISH
/SOLU
LSCLEAR,ALL
ANTYPE,4
TRNOPT,FULL
LUMPM,0
NROPT,FULL
!ESTIF,1e-0024,

!加岩石的初温
ALLSEL,ALL
LSCLEAR,ALL
VSEL,S,MAT,,3
VSEL,a,MAT,,2
ESLV,S
NSLE,S
IC,all,TEMP,17.3,
!加岩石的绝热边界条件
allsel,all
NSEL,S,LOC,Z,-39,-41
NSEL,A,LOC,X,-458,-457
NSEL,A,LOC,X,317,318
NSEL,A,LOC,y,49,51
NSEL,A,LOC,y,449,451
SF,all,HFLUX,0
!~~~~~~~~~~~~~~~~~~~~~~~~~加初始条件~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!加坝体第1层初始条件
ALLSEL,ALL
ESEL,S,MAT,,1
NSLE,S
IC,all,TEMP,10.0,
EKILL,ALL !KILL WHOLE DAM

CMSEL,S,LAYER(1,1)
EALIVE,ALL
NSLE,S

!~~~~~~~~~~~~~~~~~~~~~~~~~加边界条件并计算~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!!#######################################LAYER 1,1-3DAY##################################

*DO,T,1,3,1
!加第三类边界条件
ESEL,A,MAT,,2
ESEL,A,MAT,,3
CMSEL,S,NBIAOMIAN
CMSEL,A,JCNODE
*DO,I,1,3,1
CMSEL,A,NLAYER(1,I)
*ENDDO

!SF,ALL,CONV,200, %DAQI%
SF,ALL,CONV,2016, %DAQI%
!加水化热
CMSEL,S,LAYER(1,1)
NSLE,S
T0=0
HE01=25538*((T-T0)/(3.19+T-T0)-(T-T0-1)/(3.19+T-T0-1))
BFE,ALL,HGEN, ,HE01
ALLSEL,ALL
!计算设置
TRNOPT,FULL
LUMPM,0
TIME,T
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE
OUTRES,ALL,ALL,
SOLVE
*ENDDO

!!#######################################LAYER2-37##################################
!施工弟M层计算
*DO,M,2,37,1

!删对流边界条件
/SOLU
SFEDELE,ALL,ALL,CONV
SFDELE,ALL,CONV
!激活第M层单元
CMSEL,S,LAYER(M,1)
NSLE,S
EALIVE,ALL

*DO,T,3*(M-1)+1,3*M,1

!!选出坝体活单元和岩石及纵向围堰单元,使对流边界条件可加在岩石及纵向围堰与大气相交面,
!!并使与坝体活单元相连的岩石接触节点不加上对流边界条件.
CMSEL,S,LAYER(1,1)
*DO,I,1,M,1
CMSEL,A,LAYER(I,1)
*ENDDO
ESEL,A,MAT,,2
ESEL,A,MAT,,3

!!加第三类边界条件
!选岩石与大气接触节点
CMSEL,S,NBIAOMIAN
CMSEL,A,JCNODE
!选坝体与大气接触节点
*DO,I,1,M,1
*DO,J,1,2,1
CMSEL,A,NLAYER(I,J)
*ENDDO
*ENDDO
CMSEL,A,NLAYER(I,3)

!SF,ALL,CONV,200, %DAQI%
SF,ALL,CONV,2016, %DAQI%

!!加水化热
*DO,I,1,M,1
CMSEL,S,LAYER(I,1)
NSLE,S
T0=3*(I-1)
HE01=25538*((T-T0)/(3.19+T-T0)-(T-T0-1)/(3.19+T-T0-1))
BFE,ALL,HGEN, ,HE01
*ENDDO
                      
ALLSEL,ALL
            
!计算设置
TRNOPT,FULL
LUMPM,0
TIME,T
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE
OUTRES,ALL,ALL,
SOLVE
*ENDDO
*ENDDO

!!##############################LAYER1-37整体施工完毕计算一个月##########################
!!主要是为了使坝体水化热散发完毕
*DO,T,112,141,1
!!岩石及纵向围堰单元,使对流边界条件可加在岩石及纵向围堰与大气相交面.
ESEL,A,MAT,,2
ESEL,A,MAT,,3

!!加第三类边界条件
!选岩石与大气接触节点
CMSEL,S,NBIAOMIAN
!选坝体与大气接触节点
*DO,I,1,37,1
*DO,J,1,2,1
CMSEL,A,NLAYER(I,J)
*ENDDO
*ENDDO
CMSEL,A,NLAYER(37,3)

!SF,ALL,CONV,200, %DAQI%
SF,ALL,CONV,2016, %DAQI%

!!加水化热
*DO,I,1,37,1
CMSEL,S,LAYER(I,1)
NSLE,S
T0=3*(I-1)
HE01=25538*((T-T0)/(3.19+T-T0)-(T-T0-1)/(3.19+T-T0-1))
BFE,ALL,HGEN, ,HE01
*ENDDO
                      
ALLSEL,ALL
            
!计算设置
TRNOPT,FULL
LUMPM,0
TIME,T
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE
OUTRES,ALL,ALL,
SOLVE
*ENDDO

!!##############################LAYER1-37整体施工完毕按月计算##########################
!!主要是为了节省计算空间
*DO,M,1,32,1
T=142+(M-1)*30
!!岩石及纵向围堰单元,使对流边界条件可加在岩石及纵向围堰与大气相交面.
ESEL,A,MAT,,2
ESEL,A,MAT,,3

!!加第三类边界条件
!选岩石与大气接触节点
CMSEL,S,NBIAOMIAN
!选坝体与大气接触节点
*DO,I,1,37,1
*DO,J,1,2,1
CMSEL,A,NLAYER(I,J)
*ENDDO
*ENDDO
CMSEL,A,NLAYER(37,3)

!SF,ALL,CONV,200, %DAQI%
SF,ALL,CONV,2016, %DAQI%

                      
ALLSEL,ALL
            
!计算设置
TRNOPT,FULL
LUMPM,0
TIME,T
AUTOTS,-1
NSUBST,1, , ,1
KBC,0
TSRES,ERASE
OUTRES,ALL,ALL,
SOLVE
*ENDDO
===============================
<EquationData>

<Comments>

</Comments>

   <RegimeParameter>
      <Regime Var>
   </RegimeParameter>

   <AngularUnits type="0">
! 0 = radian, 1 = degrees
   </AngularUnits>

   <FunctionType type="SINGLE">
   </FunctionType>

   <Regime tab="0">
      <TabTitle>
         Function
      </TabTitle>
      <Equation>
          17.3+11.35*cos(0.01745*({TIME}-215))
      </Equation>
      <MaterialId active="0">
      </MaterialId>
   </Regime>

</EquationData>

ainite 发表于 2003-11-18 11:53:21

回复：【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

太棒了！

loujyxin 发表于 2003-12-2 11:10:56

回复：【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

太感谢了！！！

thinkpda 发表于 2007-7-1 21:23:34

非常好，很精彩！

schultznj 发表于 2007-11-19 11:40:41

re

这段能够表达17.3+11.35*cos(0.01745*({TIME}-215))函数吗？
FUNC
*DIM,%_FNCNAME%,TABLE,6,10,1
!
! Begin of equation: 17.3+11.35*cos(0.01745*({TIME}-215))
%_FNCNAME%(0,0,1)= 0.0, -999
%_FNCNAME%(2,0,1)= 0.0
%_FNCNAME%(3,0,1)= 0.0
%_FNCNAME%(4,0,1)= 0.0
%_FNCNAME%(5,0,1)= 0.0
%_FNCNAME%(6,0,1)= 0.0
%_FNCNAME%(0,1,1)= 1.0, -1, 0, 215, 0, 0, 1
%_FNCNAME%(0,2,1)= 0.0, -2, 0, 1, 1, 2, -1
%_FNCNAME%(0,3,1)= 0, -1, 0, 0.01745, 0, 0, -2
%_FNCNAME%(0,4,1)= 0.0, -3, 0, 1, -1, 3, -2
%_FNCNAME%(0,5,1)= 0.0, -1, 10, 1, -3, 0, 0
%_FNCNAME%(0,6,1)= 0.0, -2, 0, 11.35, 0, 0, -1
%_FNCNAME%(0,7,1)= 0.0, -3, 0, 1, -2, 3, -1
%_FNCNAME%(0,8,1)= 0.0, -1, 0, 17.3, 0, 0, -3
%_FNCNAME%(0,9,1)= 0.0, -2, 0, 1, -1, 1, -3
%_FNCNAME%(0,10,1)= 0.0, 99, 0, 1, -2, 0, 0
! End of equation: 17.3+11.35*cos(0.01745*({TIME}-215))
!-->

schultznj 发表于 2007-11-21 10:37:13

Re

请楼主赐教下段是什么意思？
我对Ansys中定义函数段内容不甚了解，垦请楼主赐教，谢谢！
===============================
<EquationData>

<Comments>

</Comments>

<RegimeParameter>
   <Regime Var>
</RegimeParameter>

<AngularUnits type="0">
! 0 = radian, 1 = degrees
</AngularUnits>

<FunctionType type="SINGLE">
</FunctionType>

<Regime tab="0">
   <TabTitle>
      Function
   </TabTitle>
   <Equation>
      17.3+11.35*cos(0.01745*({TIME}-215))
   </Equation>
   <MaterialId active="0">
   </MaterialId>
</Regime>

</EquationData>

pingping301106 发表于 2009-5-15 10:52:20

好东西如果有一整套的仿真的命令流就更好了有点奢求

pingping301106 发表于 2009-5-18 15:30:01

小弟跪求一套分析碾压混凝土拱坝温度场、温度应力的ANSYS-APDL命令流，
我在分析一个拱坝的仿真分析，从不分缝到分缝考虑，完整模拟施工期过程，可不考虑水管冷却，急需一套完整的命令流，价格详谈
跪谢各位大哥大姐了，QQ：190373590 Email:hgp0828@163.com

da2001881 发表于 2009-11-25 16:08:49

8# pingping301106

我有，可以给你，不用钱

feiren 发表于 2010-9-6 23:45:23

难得这么大方的人啊，可以请教吗？怎么联系啊

jbsu 发表于 2013-1-20 21:37:09

da2001881 发表于 2009-11-25 16:08 static/image/common/back.gif
8# pingping301106

你好！我现在也在做温度场和应力场有限元分析，我之前在中华钢结构论坛中也关注过这方面的帖子，他们也没有提供一整套的命令流，我特别希望da2001881老师能够提供给我，供我学习交流，谢谢！email：hr_cslg02@163.com

qinqiang1008 发表于 2016-4-17 17:28:35

楼上　你的问题解决了吗

页: [1]

Simwe仿真论坛(forum.simwe.com)，CAE/CAD/CAM/，FEA/FEM/有限元分析论坛---(手机验证注册)'s Archiver

【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

回复： 【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

回复： 【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

re

Re

回复：【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流

回复：【转帖】某混凝土拱坝工程施工期及运行期温度场仿真分析数据流