..:: ANSYS专区-仿真,建模,连续梁,原创-原创: 连续梁桥仿真分析建模，{Simwe仿真论坛(forum.simwe.com)，CAE/CAD/CAM/，FEA/FEM/有限元分析论坛-(手机验证注册)}

一飞冲天 发表于 2005-3-27 11:45:17

原创: 连续梁桥仿真分析建模

这是我最近做的一个箱梁悬臂施工仿真分析的模型,跨度不大,45+80+45,考虑到三向预应力钢筋,刚开始用面切割体来做钢筋,做出来的模型实在是太大了,0号块就有10万个自由度,做整桥的施工分析就不行了,下面是做的一个简化的模型,思路是:
1:用SOLID65来做混凝土,LINK8来模拟三向预应力筋.
2:建立特征截面,把箱梁简化成几个参数,通过循环生成整桥
3:划分特征截面的单元,控制网格的生成,通过扫掠来桥梁的有限元模型
4:考虑在特征截面上的接点固定钢筋,循环生成各施工段的钢筋.
以下是命令流,请各位老师指教
fini
/clear
/prep7
/title,BRIDGE DAM SIMULATION,DEVELOPED BY YIFEICHONGTIAN

ET,1,SOLID65
ET,2,LINK8
MP,PRXY,1,0.1667
MP,DENS,1,2600
MP,EX,1,3.5E10
MP,EX,2,1.95E11
MP,DENS,2,7800
MP,PRXY,2,0.3
!预应力钢筋的特性
!纵向钢筋,直径15.24mm,标准强度1860MPA，单根张拉控制吨位195.5kN
areagjx=1.81e-4 !纵向，横向单根钢筋面积
areahgjx=8.038e-4 !竖向单根钢筋面积
*dim,gjarea,array,3
gjarea(1)=16*areagjx
gjarea(2)=3*areagjx
gjarea(3)=areahgjx
*dim,F,array,3
F(1)=195.5e3
F(2)=586e3
F(3)=480e3
E=1.95E11
L=0.5
*dim,delt,array,3
delt(1)=F(1)*L/(E*areagjx)
delt(2)=F(2)*L/(E*gjarea(2))
delt(3)=F(3)*L/(E*gjarea(3))
*dim,istrn,array,3
istrn(1)=delt(1)/(delt(1)+L)
istrn(2)=delt(2)/(delt(2)+L)
istrn(3)=delt(3)/(delt(3)+L)
r,2,gjarea(1),istrn(1)
r,3,gjarea(2),istrn(2)
r,4,gjarea(3),istrn(3)

V_NUM=46
DUN_NUM=2
*DIM,DUN_BEGIN,ARRAY,DUN_NUM
*DIM,DUN_END,ARRAY,DUN_NUM
DUN_BEGIN(1)=9,33,
DUN_END(1)=13,37,

!箱梁截面的几何参数
*DIM,B1,ARRAY,V_NUM+1
*DIM,B2,ARRAY,V_NUM+1
*DIM,B3,ARRAY,V_NUM+1
*DIM,B4,ARRAY,V_NUM+1
*DIM,H1,ARRAY,V_NUM+1
*DIM,H2,ARRAY,V_NUM+1
*DIM,H3,ARRAY,V_NUM+1
*DIM,H4,ARRAY,V_NUM+1
*DIM,H5,ARRAY,V_NUM+1
*DIM,H6,ARRAY,V_NUM+1
*DIM,Z0,ARRAY,V_NUM+1

*DO,I,1,47,1
B1(I)=3
B3(I)=1.3
H1(I)=0.2
H2(I)=0.37
H4(I)=0.32
H5(I)=0.35
*ENDDO

B4(1)=2.21,2.21,2.188,2.167,2.145,2.123,2.101,2.08,2.063,2.047,
B4(11)=2.02,2.02,2.02,2.047,2.063,2.08,2.101,2.123,2.145,2.167,
B4(21)=2.188,2.21,2.21,2.21,2.21,2.21,2.188,2.167,2.145,2.123,
B4(31)=2.101,2.08,2.063,2.047,2.02,2.02,2.02,2.047,2.063,2.08,
B4(41)=2.101,2.123,2.145,2.167,2.188,2.21,2.21,

B2(1)=0.36,0.36,0.382,0.403,0.425,0.447,0.469,0.49,0.507,0.523,
B2(11)=0.55,0.55,0.55,0.523,0.507,0.49,0.469,0.447,0.425,0.403,
B2(21)=0.382,0.36,0.36,0.36,0.36,0.36,0.382,0.403,0.425,0.447,
B2(31)=0.469,0.49,0.507,0.523,0.55,0.55,0.55,0.523,0.507,0.49,
B2(41)=0.469,0.447,0.425,0.403,0.382,0.36,0.36,

H3(1)=1.467,1.467,1.499,1.592,1.748,1.967,2.249,2.593,2.893,3.228,
H3(11)=3.867,3.867,3.867,3.228,2.893,2.593,2.249,1.967,1.748,1.592,
H3(21)=1.499,1.467,1.467,1.467,1.467,1.467,1.499,1.592,1.748,1.967,
H3(31)=2.249,2.593,2.893,3.228,3.867,3.867,3.867,3.228,2.893,2.593,
H3(41)=2.249,1.967,1.748,1.592,1.499,1.467,1.467,

H6(1)=0.26,0.26,0.264,0.276,0.296,0.324,0.36,0.405,0.444,0.487,
H6(11)=0.57,0.57,0.57,0.487,0.444,0.405,0.36,0.324,0.296,0.276,
H6(21)=0.264,0.26,0.26,0.26,0.26,0.26,0.264,0.276,0.296,0.324,
H6(31)=0.36,0.405,0.444,0.487,0.57,0.57,0.57,0.487,0.444,0.405,
H6(41)=0.36,0.324,0.296,0.276,0.264,0.26,0.26,

!每个箱梁截面中顶点Z的坐标
Z0(1)=0,3,7,11,15,19,23,27,30,33,
Z0(11)=38,39,40,45,48,51,55,59,63,67,
Z0(21)=71,75,78,79,80,83,87,91,95,99,
Z0(31)=103,107,110,113,118,119,120,125,128,131,
Z0(41)=135,139,143,147,151,155,158,

!每个箱梁截面中顶点X,Y的坐标
X0=0
Y0=4.537
K_NUM=24

!************************************************************************
*DO,J,0,V_NUM,1
!形成点
K,1+J*K_NUM,XO-(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1),Z0(J+1)
K,2+J*K_NUM,XO-(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0,Z0(J+1)
K,3+J*K_NUM,XO-(B2(J+1)+B3(J+1)+B4(J+1)),Y0,Z0(J+1)
K,4+J*K_NUM,XO-(B3(J+1)+B4(J+1)),Y0,Z0(J+1)
K,5+J*K_NUM,XO-B4(J+1),Y0,Z0(J+1)
K,6+J*K_NUM,XO+B4(J+1),Y0,Z0(J+1)
K,7+J*K_NUM,XO+(B3(J+1)+B4(J+1)),Y0,Z0(J+1)
K,8+J*K_NUM,XO+(B2(J+1)+B3(J+1)+B4(J+1)),Y0,Z0(J+1)
K,9+J*K_NUM,XO+(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0,Z0(J+1)
K,10+J*K_NUM,XO+(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1),Z0(J+1)
K,11+J*K_NUM,XO+(B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1),Z0(J+1)
K,12+J*K_NUM,XO+(B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
K,13+J*K_NUM,XO+(B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
K,14+J*K_NUM,XO+(B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
K,15+J*K_NUM,XO-(B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
K,16+J*K_NUM,XO-(B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
K,17+J*K_NUM,XO-(B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
K,18+J*K_NUM,XO-(B2(J+1)+B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1),Z0(J+1)
K,19+J*K_NUM,XO-(B3(J+1)+B4(J+1)),Y0-H4(J+1)-H5(J+1),Z0(J+1)
K,20+J*K_NUM,XO-B4(J+1),Y0-H4(J+1),Z0(J+1)
K,21+J*K_NUM,XO+B4(J+1),Y0-H4(J+1),Z0(J+1)
K,22+J*K_NUM,XO+(B3(J+1)+B4(J+1)),Y0-H4(J+1)-H5(J+1),Z0(J+1)
K,23+J*K_NUM,XO+(B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
K,24+J*K_NUM,XO-(B3(J+1)+B4(J+1)),Y0-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)

!形成线
L_NUM=36
L,1+J*K_NUM,2+J*K_NUM,2
L,2+J*K_NUM,3+J*K_NUM,4
L,3+J*K_NUM,4+J*K_NUM,2
L,4+J*K_NUM,5+J*K_NUM,2
L,5+J*K_NUM,6+J*K_NUM,4
L,6+J*K_NUM,7+J*K_NUM,2
L,7+J*K_NUM,8+J*K_NUM,2
L,8+J*K_NUM,9+J*K_NUM,4
L,9+J*K_NUM,10+J*K_NUM,2
L,10+J*K_NUM,11+J*K_NUM,4
L,11+J*K_NUM,12+J*K_NUM,5
L,12+J*K_NUM,13+J*K_NUM,2
L,13+J*K_NUM,14+J*K_NUM,2
L,14+J*K_NUM,15+J*K_NUM,5
L,15+J*K_NUM,16+J*K_NUM,2
L,16+J*K_NUM,17+J*K_NUM,2
L,17+J*K_NUM,18+J*K_NUM,5
L,18+J*K_NUM,19+J*K_NUM,2
L,19+J*K_NUM,20+J*K_NUM,2
L,20+J*K_NUM,21+J*K_NUM,4
L,21+J*K_NUM,22+J*K_NUM,2
L,22+J*K_NUM,23+J*K_NUM,5
L,23+J*K_NUM,24+J*K_NUM,5
L,24+J*K_NUM,19+J*K_NUM,5
L,18+J*K_NUM,1+J*K_NUM,4
*DO,I,26,30,1
L,I-23+J*K_NUM,I-8+J*K_NUM,2
*ENDDO
L,11+J*K_NUM,8+J*K_NUM,2
L,23+J*K_NUM,12+J*K_NUM,2
L,23+J*K_NUM,14+J*K_NUM,2
L,24+J*K_NUM,15+J*K_NUM,2
L,24+J*K_NUM,17+J*K_NUM,2
L,11+J*K_NUM,22+J*K_NUM,2
*ENDDO

!建立A_LINE线集合，
CM,A_LINE,LINE

!截面上体的个数
VV_NUM=12

!形成体
*DO,K,0,V_NUM-1,1
V,1+K*K_NUM,2+K*K_NUM,3+K*K_NUM,18+K*K_NUM,1+(K+1)*K_NUM,2+(K+1)*K_NUM,3+(K+1)*K_NUM,18+(K+1)*K_NUM
V,3+K*K_NUM,4+K*K_NUM,19+K*K_NUM,18+K*K_NUM,3+(K+1)*K_NUM,4+(K+1)*K_NUM,19+(K+1)*K_NUM,18+(K+1)*K_NUM
V,4+K*K_NUM,5+K*K_NUM,20+K*K_NUM,19+K*K_NUM,4+(K+1)*K_NUM,5+(K+1)*K_NUM,20+(K+1)*K_NUM,19+(K+1)*K_NUM
V,5+K*K_NUM,6+K*K_NUM,21+K*K_NUM,20+K*K_NUM,5+(K+1)*K_NUM,6+(K+1)*K_NUM,21+(K+1)*K_NUM,20+(K+1)*K_NUM
V,6+K*K_NUM,7+K*K_NUM,22+K*K_NUM,21+K*K_NUM,6+(K+1)*K_NUM,7+(K+1)*K_NUM,22+(K+1)*K_NUM,21+(K+1)*K_NUM
V,7+K*K_NUM,8+K*K_NUM,11+K*K_NUM,22+K*K_NUM,7+(K+1)*K_NUM,8+(K+1)*K_NUM,11+(K+1)*K_NUM,22+(K+1)*K_NUM
V,8+K*K_NUM,9+K*K_NUM,10+K*K_NUM,11+K*K_NUM,8+(K+1)*K_NUM,9+(K+1)*K_NUM,10+(K+1)*K_NUM,11+(K+1)*K_NUM
V,11+K*K_NUM,12+K*K_NUM,23+K*K_NUM,22+K*K_NUM,11+(K+1)*K_NUM,12+(K+1)*K_NUM,23+(K+1)*K_NUM,22+(K+1)*K_NUM
V,23+K*K_NUM,12+K*K_NUM,13+K*K_NUM,14+K*K_NUM,23+(K+1)*K_NUM,12+(K+1)*K_NUM,13+(K+1)*K_NUM,14+(K+1)*K_NUM
V,23+K*K_NUM,14+K*K_NUM,15+K*K_NUM,24+K*K_NUM,23+(K+1)*K_NUM,14+(K+1)*K_NUM,15+(K+1)*K_NUM,24+(K+1)*K_NUM
V,15+K*K_NUM,16+K*K_NUM,17+K*K_NUM,24+K*K_NUM,15+(K+1)*K_NUM,16+(K+1)*K_NUM,17+(K+1)*K_NUM,24+(K+1)*K_NUM
V,17+K*K_NUM,18+K*K_NUM,19+K*K_NUM,24+K*K_NUM,17+(K+1)*K_NUM,18+(K+1)*K_NUM,19+(K+1)*K_NUM,24+(K+1)*K_NUM
*ENDDO

CMSEL,U,A_LINE
LSEL,ALL
LESIZE,ALL,,,6
ALLSEL
VATT,1,1,1

*DO,I,1,V_NUM*VV_NUM,1
VSWEEP,I
*ENDDO

!定义预应力筋******************************************************************************
*GET,LMAX,LINE,,NUM,MAX
*DO,I,0,V_NUM,1
LSEL,NONE
L,4+K_NUM*I,15+K_NUM*I,1
!连接生成竖向预应力筋
L,7+K_NUM*I,14+K_NUM*I,1
LATT,2,4,2
LESIZE,ALL,,,1
LMESH,ALL
LSEL,NONE
L,1+K_NUM*I,10+K_NUM*I,1
!连接生成横向预应力筋
LATT,2,4,2
LESIZE,ALL,,,1
LMESH,ALL
LSEL,NONE
*ENDDO

!按施工进度方案定义每一阶段的纵向预应力钢索，竖向，横向预应力钢筋集合
!每8天浇注一段混凝土箱梁，拉伸纵向预应力钢索一次
ALLSEL
*DO,BADAY,0,9,1
LSEL,NONE
ESEL,NONE
*DO,I,1,2,1
L,18+(DUN_BEGIN(I)-BADAY)*K_NUM,18+(DUN_END(I)+BADAY)*K_NUM,
L,11+(DUN_BEGIN(I)-BADAY)*K_NUM,11+(DUN_END(I)+BADAY)*K_NUM,
*ENDDO
LATT,2,2,2
LESIZE,ALL,,,1
LMESH,ALL,
*DO,I,1,2
LSEL,A,,,LMAX+3*(DUN_BEGIN(I)-BADAY)-2,LMAX+3*(DUN_BEGIN(I)-BADAY+1),1
LSEL,A,,,LMAX+3*(DUN_END(I)+BADAY)-2,LMAX+3*(DUN_END(I)+BADAY+1),1
*ENDDO
ESLL,A
CM,Z_REBAR%BADAY%,ELEM
*ENDDO

ALLSEL
NUMMRG,NODE
SAVE,,,,MODEL

cquzy 发表于 2005-6-17 18:16:32

googie 发表于 2005-7-1 17:28:40

小东北 发表于 2005-7-3 12:36:01

Re:原创: 连续梁桥仿真分析建模

楼主，你的预应力如何加的？能继续贴一下求解的处理吗？是加初应变吗？还是加力？谢谢！

远航发表于 2007-9-26 16:21:21

不错!很好的东东

yjwwjy 发表于 2007-9-29 10:30:06

谢了先看看

yjwwjy 发表于 2007-9-29 10:30:20

有问题啊

maidou008 发表于 2009-5-10 14:33:08

学习中

baiyouyun 发表于 2009-5-17 19:55:17

学习了~~~~~~~~~~~~~~

wwgfwj 发表于 2009-6-1 12:53:35

挺好，收获很大

leozq601 发表于 2009-6-1 15:15:26

看看·········

忠诚憨厚 发表于 2009-7-12 16:45:41

非常希望有这样的资料，谢谢楼主了

jzw19840214 发表于 2009-10-7 15:32:30

楼主辛苦了，谢谢楼主！！

xing200603352 发表于 2009-11-18 18:00:21

十分感谢，很受鼓舞

850776307 发表于 2010-6-14 23:50:22

很好啊，以后毕业设计也许还能用呢，呵呵

buster 发表于 2010-6-20 22:31:05

正好学习一下

zcxboy 发表于 2010-7-18 16:58:49

楼主，你好，我也在做一个三跨连续刚构桥，50+85+50，因为我们这个资料不完整，想借鉴一下你的取值，你能把你这个桥的资料发给我看看吗？anligf@163.com

创世纪 发表于 2010-10-8 19:40:18

根据定义的实常数应该预应力是用初始应变加的，可是程序里后面就没写了，汗

xjj20082008 发表于 2010-10-11 15:50:37

学习一下，下来看看

lyp-luo 发表于 2011-11-9 16:58:46

有没有耦合？钢筋和混凝土

页: [1] 2

Simwe仿真论坛(forum.simwe.com)，CAE/CAD/CAM/，FEA/FEM/有限元分析论坛---(手机验证注册)'s Archiver

原创: 连续梁桥仿真分析建模

Re:原创: 连续梁桥仿真分析建模