流体与动态计算实例分析---堤坝
;流体与动态计算实例分析---大坝new
conf dyn fluid;设置动态与流体算法
set dyn off fluid off;关闭动态与流体算法
; generate foundation and embankment grids and attach interfaces
;生成基础和堤坝网格并粘贴接触面
gen zone bri p0 0,0,0 p1 40,0,0 p2 0,10,0 p3 0,0,10 size 20 5 5;基础
gen zone bri p0 22,0,10 p1 40,0,10 p2 22,10,10 p3 22,0,20 size 9,5,5;堤坝
;在z=10,x=15~22,y=0~10上生成接触面1
interface 1 face range x 15.0 22.0 y 0.0 10.0 z 9.9 10.1
;在x=22,z=10~21,y=0~10上生成接触面2
interface 2 face range x 21.9 22.1 y 0.0 10.0 z 10.0 21.0
;设置最大的边界长度为1.0
interface 1 maxedge 1.0
interface 2 maxedge 1.0
; generate block wall 生成挡水墙
gen zone bri p0 15,0.5,11 p1 21,0.5,11 p2 15,9.5,11 p3 15,0.5,20.9 siz 3 5 5
; name groups and move block on to soil
;命名群组并移动挡水墙到土壤上
group block range x=16,22 y=0,10 z=10,20
group 'soil embankment' range x=22,40 y=0,10 z=10,20
group 'dense soil foundation'range x=0,40y=0,10 z=0,10
;挡墙沿x方向增加一个单位
ini x add 1.0 range group block
;挡墙沿z方向增加一个单位
ini z add -1.0 range group block
; assign models to groups
;给群组设定计算模型
model mohr range group block not;除挡墙外的群组为摩尔库仑模型
model elas range group block;挡墙为弹性
; assign mechanical properties设置力学参数
prop shear=1e8 bulk=2e8 cohes=1e10 range group 'soil embankment'
prop shear=5e8 bulk=1e9 cohes=1e10 range group 'dense soil foundation'
prop shear=9.15e9 bulk=10e9 range group block
ini dens=2100range group block;初始化质量密度
ini dens=1800range group block not
interface 1 prop coh=0 fric 60. dil 0. kn=1e8 ks=1e8 ten 0.;接触面参数
interface 2 prop coh=0 fric 60. dil 0. kn=1e8 ks=1e8 ten 0.
model fl_iso;各项同性流体模型,计算流体必须的.
; mechanical boundary and initial conditions物理边界和初始条件
fix z range z=-.1 .1;固定z=0的面
fix x range x=-.1 .1
fix x range x=39.9 40.1;固定x=40的面
fix y range y=-.1 .1
fix y range y=9.9 10.1
;初始应力,垂直应力为水平的2倍,在z方向有梯度变化
ini szz -3.6e5 grad 0 0 1.8e4
ini sxx -1.8e5 grad 0 0 0.9e4
ini syy -1.8e5 grad 0 0 0.9e4
set grav 0 0 -10;设置重力加速度
;记录监测数据
hist unbal;不平衡力
hist gp zdisp 16,5,20;点(16,5,20)的z方向位移
hist gp zdisp 30,5,20
;求解
solve
save block1.sav;保存
; assign realistic strength properties设置现实的强度参数
propcohes=0 tens 0fric 35 range group 'soil embankment'
propcohes=0 tens 0fric 40 range group 'dense soil foundation'
solve
save block1.sav
;流体分析
rest block1.sav;调用保存的文件
; specify fluid properties设定流体参数
prop perm=1e-8 poros=0.3
ini fdens=1000;初始化流体密度
ini fmod=2e3;流体的体积模量
set fluid pcut on;设置流体进程,但pcut是??
; assign water table设置水位
water density 1000.;水的密度
water table face 0 0 20 0 10 20 40 10 20 40 0 20 ;水平面由四个节点创建
; block wall is impermeable挡墙不透水
fix pp 0 range group block;挡墙区域内孔隙水压力为0
;施加水压力
apply nstress -1e5 range x=0,16 y=0,10z=9.9,10.1;加在土坝上的
apply nstress -2e5grad 0,0,1e4range x=15.9,16.1y=0,10z=10,20;挡墙上的z向梯度变化
;启动流体算法
set fluid on
solve
save block2.sav
;动态分析
rest block2.sav
set dyn on;启动动态算法
set large;大变形
set dyn multi on;设置动态多步计算,有什么区别呢
;turns multi-stepping on or off. Multi-stepping speeds up calculations in dynamic models which have a large
;zone size or modulus contrast. Sub-stepping only works when dynamic mode is in operation (SET dyn on),
;and is effective only when the grid is nonuniform or there is a contrast in material properties.
;初始化速度,位移和状态
ini xvel 0 yvel 0 zvel 0
ini xdisp 0 ydisp 0 zdisp 0
ini state 0
;设置土中水的模量
; set fluid modulus for water in soils
ini fmod 250e6range group block not
;施加动态边界条件
; apply dynamic boundary conditions
def wave
wave = ampl * sin (2.0*pi*freq*dytime)
end
;释放边界z=0
free x y range z -.1 .1
;施加动态条件?
apply xvel 1.0 hist wave ran z -.1 .1
apply yvel 1.0 hist wave ran z -.1 .1
apply ff
set freq 10.0 ampl 0.5 ;设置频率和放大系数
;
; dynamic histories 动态历史记录
set dyn time 0
hist reset
hist dytime
hist gp xvel 20,10,0
hist zone pp 19,5,5 ;记录点孔隙压力
hist zone pp 30,5,5
hist zone pp 30,5,15
hist zone pp 19,5,9
hist gp xdis 16,5,20
;
set dyn damp local .125 ;设置动态本地衰减为.125
solve age 5.0 ;求解的动态计算时间
save block3.sav
ret
Re:流体与动态计算实例分析---堤坝
计算模型见附件Re:流体与动态计算实例分析---堤坝
添加接触面后的模型Re:流体与动态计算实例分析---堤坝
顶Re:流体与动态计算实例分析---堤坝
好东东，定要好好学学～Re:流体与动态计算实例分析---堤坝
今天才看到，加分鼓励。Re:流体与动态计算实例分析---堤坝
谢谢版主了啊Re:流体与动态计算实例分析---堤坝
游侠骑士 wrote:请问模型的颜色是怎么设置的？
plo blo gro