【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看看？
错误提示如下：specified dof constraint temp at unused node 600.
node 142 on element 1000 is unselected.
constraint from area 6 is not transferred to unselected node 576.
数字是我随机抄的，因为每一类的错误都有好多。
如果有哪位大虾有兴趣帮我看一下的话，请留下联系方式，我的水平太差了，不好意思把我的命令流放上来
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
这是我的命令流，希望能得到各位的指教，帮我找找毛病所在，先谢了！回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
*do,i,1,5time,j
deltim,0.11,0.11,0.11,
sfdele,all,hflux
nsel,s,loc,x,4,6
nsel,r,loc,y,10
nsel,r,loc,z,i,i+1
sf,all,hflux,1000
nsubst,1
outres,all,all
solve
j=j+1
*enddo
我沒執行過...問一些問題
你只選擇
nsel,s,loc,x,4,6
nsel,r,loc,y,10
nsel,r,loc,z,i,i+1
這些節點求解..是對的嗎?還是要對整體求解?
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
我做的是一个三维的立方体，在上表面加一移动热源，此命令行是为了选择一块区域施加热流的，这一部分没什么问题。但是在加其他边界条件时好像出了点毛病，加convection时我加在了四个面上，可运行的结果却是整体都是同一个温度了，热源加在上面一点作用都没起，我也不知道是什么原因，请赐教！回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
我還是覺得怪怪的....你只求解施加載荷的NODE到底用意為何??....這樣會得到整體溫度分布嗎??你試試在所有SOLVE前加個ALLSEL...看看ERROR會不會改善
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
bigbird大虾说的对，除了这个，你的surf152没什么大用处，所以我就删了，能求解了，可是结果不知道怎么会是一样的温度。你的载荷单位hflux的数量级不对。/FILNAME,thermalmoving1,0
/TITLE,3D moving heat
/PREP7
ET,1,SOLID70
KEYOPT,1,2,0
KEYOPT,1,4,0
KEYOPT,1,7,0
KEYOPT,1,8,0
!*
MPTEMP,1,0
MPDATA,KXX,1,,70
MPTEMP,1,0
MPDATA,C,1,,448
MPTEMP,1,0
MPDATA,DENS,1,,7833
BLOCK,0,10,0,10,0,10,
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
lesize,all,1
vmesh,all
/psf,hflu,,2,0
sfa,1,,conv,50,5,
sfa,2,,conv,50,5,
sfa,5,,conv,50,5,
sfa,6,,conv,50,5,
finish
/solu
antype,trans
trnopt,full
nropt,auto,,
eqslv,
solcontrol,on
autots,on
kbc,1 !step
outres,all,all,
!load step 1, initial conditions 25 c
time,0.001
deltim,0.001,0.001,0.001
timint,off !time integration = off
tunif,25,
solve
!load step 2..... , apply moving heat flux
timint,on !time integration = on
j=1
allsel,all
*do,i,1,5
time,j
deltim,0.11,0.11,0.11,
sfdele,all,hflux
nsel,s,loc,x,4,6
nsel,r,loc,y,10
nsel,r,loc,z,i,i+1
sf,all,hflux,1000
nsubst,1
outres,all,all
allsel,all
solve
j=j+1
*enddo
finish
/post1
/eface,1
set,last
plnsol,temp,,0,
finish
save
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
谢谢两位大虾，我刚才试了一下，确实可以了，以前老出毛病的原因就是因为solve前忘了加allsel,all这个命令了，而且今天上午我刚看了书，hflux的大小必须在50－500w/mm/mm之间，我加的热流太小了，所以在结果中根本看不出变化。感激之情无法用言语表达！
另外想再问一个问题，也是困扰我多日的，我想在上表面一圆形区域中加热流，可我用
nsel,s,loc,x,5,7
nsel,r,loc,y,10
nsel,r,loc,z,5,6
sf,all,hflux,1000000
这个命令时只能选择一方形区域，是不是需要改成极坐标？该如何操作呢？请指教！
再次表示感谢！你们对我的帮助真是太大了。。。
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
前處理板...經常討論這類問題....去找找..應該會得到解答回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
我做了一下该题，虽然得到了动态结果，但我认为结果明显是错误的：1，不删除SUR152单元 不管CONV的值为多少（从50到50E6、200E6都试过），但结果一样，从（0---0.057E-03，也就是说温度还是基本为零。）2，删除SFUR152单元后，更改CONV结果还是一样，从0--0.005128，还是明显错误。
所以，我断定CONV在计算中没有用到。命令流和大家一样就不贴了。
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
我修改HFLUX后又做了一次，这次看起来差不多，温度范围：0----512.832。就心得总结如下：1，对流CONV和热流密度HFLUX都是面载荷，仅可加在实体和壳模型上，当CONV和FLUX加在同一外表面时，ANSYS只读取最后施加的面载进行计算，这就是CONV没有起作用的原因。2，删不删除单元SURF152，其结果一样。3，加载合理才能得到合理的结果。将我的命令流贴出共享，附有动态结果文件！/FILNAME,thermalmoving
/TITLE,3D moving heat
/PREP7
/UNITS,SI
ET,1,SOLID70
KEYOPT,1,2,0
KEYOPT,1,4,0
KEYOPT,1,7,0
KEYOPT,1,8,0
!*
ET,2,SURF152
KEYOPT,2,3,0
KEYOPT,2,4,0
KEYOPT,2,5,0
KEYOPT,2,6,0
KEYOPT,2,7,0
KEYOPT,2,8,0
KEYOPT,2,9,0
!*
MPTEMP,1,0
MPDATA,KXX,1,,70
MPTEMP,1,0
MPDATA,C,1,,448
MPTEMP,1,0
MPDATA,DENS,1,,7833
BLOCK,0,10,0,10,0,10,
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
lesize,all,1
vmesh,all
/psf,hflu,,2,0 !disply the surface load (2-contour)
type,2
asell,s,,,1,2,1
asell,a,,,5,6,1
nsll,s,1
sf,all,conv,100e6,5
allsel
finish
/solu
antype,trans
trnopt,full
nropt,auto,,
eqslv, !select the eqation solver
solcontrol,on
autots,on !specified whether to use automatic load step ortime step.
kbc,1 !specified ramped or stepped loadingwithin load step
outres,all,all, ! control the solution data into database
!load step 1, initial conditions 25 c
time,0.001
deltim,0.001,0.001,0.001
timint,off !time integration = off
tunif,25,
solve
!load step 2..... , apply moving heat flux
timint,on !time integration = on
j=1
allsel,all
*do,i,1,5
time,j
deltim,0.11,0.11,0.11
sfdele,all,hflux
nsel,s,loc,x,4,6
nsel,a,loc,y,10
nsel,a,loc,z,i,i+1
sf,all,hflux,100e6
allsel,all
nsubst,1
outres,all,all
solve
j=j+1
*enddo
finish
/post1
/eface,1
set,last
plnsol,temp,,0,
finish
save
好了，就这些，也不知道够不够的1分。
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
谢谢yjzhang_xaut，我一定要求管理员给你加分！回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
yjzhang_xaut,你好。我运行了一下你的命令流，发现了如下几个问题，和你探讨一下：1、asell,s,,,1,2,1
asell,a,,,5,6,1
nsll,s,1
sf,all,conv,100e6,5
其中的asell是否为asel?你是选了1256这四个面上的所有线加边界条件的吗？不能直接加在面上吗？100e6的对流系数是否太大？我查了一下，如果按国际单位的话应该为100左右才对
2、nsel,s,loc,x,4,6
nsel,a,loc,y,10
nsel,a,loc,z,i,i+1
sf,all,hflux,100e6
我觉得上面的a应该改为r，是reselect而不是also select，这样的话选择的区域就为表面上的一块区域了，热流应该加在面上的，对不对？
如果把这两个地方改一下的话，结果才更符合实际
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
下面是我做的一个尺寸方面比较贴近实际的三维移动载荷的例子，请指教（单位为mm，移动速度为500mm/min）
/FILNAME,3dmoving3,0
/TITLE,3D moving heat
/PREP7
ET,1,SOLID70
KEYOPT,1,2,0
KEYOPT,1,4,0
KEYOPT,1,7,0
KEYOPT,1,8,0
!*
MPTEMP,1,0
MPDATA,KXX,1,,0.07!70
MPTEMP,1,0
MPDATA,C,1,,448
MPTEMP,1,0
MPDATA,DENS,1,,7.8e-6!7800
BLOCK,0,50,0,3,0,500,
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
lesize,all,2
vmesh,all
/psf,hflu,,2,0
/PNUM,LINE,1
!sfa,1,,conv,50e-6,25,
!sfa,2,,conv,50e-6,25,
sfa,5,,conv,50e-6,25,
sfa,6,,conv,50e-6,25,
finish
/solu
antype,trans
trnopt,full
nropt,auto,,
eqslv,
solcontrol,on
autots,on
kbc,1 !step
outres,all,all,
!load step 1, initial conditions 25 c
time,0.001
deltim,0.001,0.001,0.001
timint,off !time integration = off
tunif,25,
solve
!load step 2..... , apply moving heat flux
timint,on !time integration = on
j=1
allsel,all
*do,i,10,50,2
time,j
deltim,0.001,0.001,0.001,
sfdele,all,hflux
nsel,s,loc,x,22,28
nsel,r,loc,y,3
nsel,r,loc,z,i,i+6
sf,all,hflux,100
ALLSEL,ALL
nsel,s,loc,x,23,27
nsel,r,loc,y,3
nsel,r,loc,z,i+1,i+5
sf,all,hflux,200
ALLSEL,ALL
nsel,s,loc,x,24,26
nsel,r,loc,y,3
nsel,r,loc,z,i+2,i+4
sf,all,hflux,400
ALLSEL,ALL
nsubst,1
outres,all,all
allsel,all
solve
j=j+0.24
*enddo
这个结果应该比较贴近实际了，你们运行一下看看
但是存在的问题是，
1、划分网格不够细，中间施加热源的地方和板厚应该划的再细一些，三维局部细化如何操作？
2、加的热源应该是一高斯分布的，我只是给近似的选成了方形区域（应该为圆的），如果选圆区域如何选？用函数的话怎么用？（这个问题我问过多遍了，可一直没人回答）
请高手指教！
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
今天碰到一个比我还认真的，jnjl,多谢你的提问，ASELL和ASEL命令一样，前一个是以前版本的命令，6.1也认，不然我的命令怎么能执行下去呢？我已经说过了，CONV不管是100还是100E6对结果都没影响，不信你可以试试。第二个问题，我认为用a和用r选择结果都一样（上表面上的一个2X1的矩形移动面）。你的程序我大概看了一下，还没有RUN，但有一个问题请注意，ANSYS的单位默认为SI，长度为m,时间为s,质量为Kg,你的程序中应该加一句：/UNITS，USER，MM，KG，S才和你的情况相符。
回复： 回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能
yjzhang_xaut wrote:CONV不管是100还是100E6对结果都没影响，不信你可以试试。
我认为用a和用r选择结果都一样（上表面上的一个2X1的矩形移动面）。
ANSYS的单位默认为SI，长度为m,时间为s,质量为Kg,你的程序中应该加一句：/UNITS，USER，MM，KG，S才和你的情况相符。
1.
conv大小應該是會有影響的...不知yjzhang_xaut是從何處判斷無影響??...
2.
我认为用a和用r选择结果都一样...在某些情況下是不同的....
3.
ansys是無單位制.../UNITS只是讓使用者了解是用啥單位...
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
FOR jnjl...雖然我都沒執行過...我還是冒昧請問一下...
不知你對你這求解流程是否清楚明瞭...為何你tunif設置為25...又在表面給個CONV..然後又以25度的空氣做對流...這個動作到底有何意義??...
內部溫度25..外部溫度也是25...無熱通量...又何來的conv...h值多寡也就無意義...不知你有否確認過...第二次以後求解時..conv是否還在...溫度分部是否合理??
針對你的問題...
可選擇的座標系還有...圓柱&球...這兩種應該都可達到你的要求...
LESIZE..有局部細化的功能..還請善用HELP..
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
谢谢两位的指点to bigbird
关于温度这个问题，我试过把空气的温度设为5度或25度都对结果没有影响，就像yjzhang_xaut所说的热流系数100和100e6对结果没有影响一样，我也不知道是怎么回事，一会我再试一下，多谢你的提醒，对好多问题我确实没有完全搞清楚，所以还请你们多多指教！
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
to yjzhang_xaut呵呵，都很认真嘛...
你运行一下我的命令流，结果和你的差别可是很大啊
放心，绝对没有错误 ：）
回复： 【讨论】我做了一个三维温度场移动载荷的例子，出了好多错误，谁能帮我看
同时施加对流和热流的时候,似乎应该使用表面效应单元吧?
页:
[1]
2