两根导体在钢板上的感应加热(二维模型),哪位高手能够解决其中的问题?
两根导体在钢板上的感应加热(二维模型),哪位高手能够解决其中的问题?我这里有个自己作的东西,两根导体在平面钢板上的感应加热问题,建立了二维模型,磁热耦合作出的结果是正确的,但是在计算结构时却出现问题,不知何故?
这里是热分析版,虽然有磁热耦合的东西,但也是与热变形有关问题,希望这里的高手指点一二。先行谢过!
下面是命令流:
FINI
/CLEA
/CONFIG,NRES,5000
/batch,list
/filenam, induc
/prep7
shpp,off
/title, induction heating of flat plate
/com,
et,1,13,,,0 ! PLANE13, axisymmetric, AZ dof
et,2,13,,,0
PLNGTH=200E-3
PTHCK=20E-3
CAP=3E-3
HL_LOC=PLNGTH/2
!COIL DIMENSION
CWDTH=10E-3
!CLNGTH=100E-3
CTHCK=1.5E-3
!MAGNETIZER DIMENSION
MHIGH=20E-3
MDIST=40E-3
AIRHIGH=80E-3
freq=24000 ! frequency (Hz.)
IAC=700
CAREA=(CWDTH*CWDTH)-(CWDTH-2*CTHCK)*(CWDTH-2*CTHCK)
IJS=IAC/CAREA
pi=4*atan(1) ! pi
cond=.392e7 ! maximum conductivity
muzero=4e-7*pi ! free-space permeability
mur=200 ! maximum relative permeability
skind=sqrt(1/(pi*freq*cond*muzero*mur)) ! skin depth
ftime=90 ! final time
tinc=0.1 ! time increment for harmonic analysis
time=0 ! initialize time
delt=0.5 ! maximum delta time step
emunit,mks ! set magnetic units
mp,murx,1,1 ! air relative permeability
mp,murx,3,1 ! coil relative permeability
mptemp,1,25.5,160,291.5,477.6,635,698 ! temps for relative permeability
mptemp,7,709,720.3,742,761,1000
mpdata,murx,2,1,200,190,182,161,135,104 ! steel relative permeability
mpdata,murx,2,7,84,35,17,1,1
mptemp
mptemp,1,0,125,250,375,500,625 ! temps for resistivity
mptemp,7,750,875,1000
mpdata,rsvx,2,1,.184e-6,.272e-6,.384e-6,.512e-6,.656e-6,.824e-6
mpdata,rsvx,2,7,1.032e-6,1.152e-6,1.2e-6 ! steel resistivity
MP,MURX,4,10000 ! FLUX CONCENTRATOR relative permeability
rectng,0,PLNGTH,0,PTHCK ! billet
rectng,0,PLNGTH,PTHCK,PTHCK+CAP ! air-gap
rectng,HL_LOC-CWDTH,HL_LOC,PTHCK+CAP,PTHCK+CAP+CWDTH ! coil 1
rectng,HL_LOC,HL_LOC+CWDTH,PTHCK+CAP,PTHCK+CAP+CWDTH ! coil 2
rectng,HL_LOC-MDIST/2,HL_LOC+MDIST/2,PTHCK+CAP,PTHCK+CAP+MHIGH ! flux concentrator
rectng,HL_LOC-CWDTH+CTHCK,HL_LOC-CTHCK,PTHCK+CAP+CTHCK,PTHCK+CAP+CWDTH-CTHCK ! AIR IN coil 1
rectng,HL_LOC+CTHCK,HL_LOC+CWDTH-CTHCK,PTHCK+CAP+CTHCK,PTHCK+CAP+CWDTH-CTHCK ! AIR IN coil 2
rectng,0,PLNGTH,PTHCK+CAP,PTHCK+CAP+AIRHIGH ! outer air
aovlap,all
numcmp,area
ksel,s,loc,Y,PTHCK ! select keypoints at outer radius of workpiece
kesize,all,skind/2 ! set meshing size to 1/2 skin depth
ksel,s,loc,Y,0 ! select keypoints at center
kesize,all,40*skind ! set meshing size
lsel,s,loc,X,HL_LOC ! select vertical lines
LSEL,R,LOC,Y,0,PTHCK
lesize,all,CWDTH!,,8 ! set 1 division through thickness
lsel,all
ASEL,S,LOC,Y,PTHCK/2
aatt,2,1,1 ! set attributes for billet region
LSEL,S,LOC,X,HL_LOC
LSEL,R,LOC,Y,PTHCK+CAP,PTHCK+CAP+CWDTH
ASLL,S,0
CM,COI2,AREA
aatt,3,1,2 ! set attributes for coil region
asel,s,area,,2,5,1
aatt,1,1,2 ! set attributes for air region
ASEL,S,AREA,,6
CM,CONC,AREA
AATT,4,1,2 ! set attributes for flux concentrator region
asel,all
mshape,0,2d
mshk,1
amesh,1 ! mesh billet area
ASEL,S,AREA,,COI2
ASEL,A,AREA,,CONC
LSLA,S
lesize,all,CTHCK
mshk,0
AMESH,COI2
AMESH,CONC
ALLS
AMESH,2
AMESH,3
ALLS
LSEL,S,LOC,Y,PTHCK+CAP
lesize,all,CWDTH
LSEL,S,LOC,Y,PTHCK+CAP/2
lesize,all,,,1,1
mshk,0
AMESH,5 ! mesh AIR CAP AREA
LSEL,S,LOC,Y,PTHCK+CAP+AIRHIGH
lesize,all,CWDTH
LSEL,S,LOC,X,0
LSEL,A,LOC,X,PLNGTH
LSEL,R,LOC,Y,PTHCK+CAP,PTHCK+CAP+AIRHIGH
lesize,all,CWDTH
AMESH,4
nsel,s,loc,Y
d,all,az,0 ! apply flux-normal b.c.
nsel,all
ASEL,S,AREA,,COI2
ESLA,S
bfe,all,js,,,,IJS ! apply current density to coil
ALLS
NUMCMP,ALL
finish
/solu
antyp,harm
harfrq,FREQ
physics,write,emag ! write emag physics file
finish
/prep7
lsclear,all ! clear all b.c.'s and options
et,1,55,,,0 ! PLANE55 thermal element, axisymmetric
et,2,0 ! null element type for coil and air region
mptemp
mptemp,1,0,730,930,1000 ! temps for conductivity
mpdata,kxx,2,1,60.64,29.5,28,28
mptemp ! temps for enthalpy
mptemp,1,0,27,127,327,527,727
mptemp,7,765,765.001,927
mpdata,enth,2,1,0,91609056,453285756,1.2748e9,2.2519e9,3.3396e9
mpdata,enth,2,7,3.548547e9,3.548556e9,4.3520e9
finish
/solu
TMPINIT=23
antype,trans
toffst,273
tunif,TMPINIT ! initial uniform temperature
!环境系数定义
HUP=3 !5e-6 !upper surface film coefficient of convection
TMPUP=TMPINIT !upper surface temperature of convection
HDOWN=1 !5e-6 !bottom surface film coefficient of convection
TMPDOWN=TMPINIT !bottom surface temperature of convection
HVER=5.97 !5e-6 !side surface film coefficient of convection
TMPVER=TMPINIT !side surface temperature of convection
NSEL,S,LOC,Y,PTHCK
SF,ALL,CONV,HUP,TMPUP
NSEL,S,LOC,Y,0
SF,ALL,CONV,HDOWN,TMPDOWN
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0,PTHCK
SF,ALL,CONV,HVER,TMPVER
NSEL,S,LOC,X,PLNGTH
NSEL,R,LOC,Y,0,PTHCK
SF,ALL,CONV,HVER,TMPVER
ALLS
cnvtol,heat,1 ! convergence tolerance
kbc,1 ! step loads
trnopt,full
autos,on ! auto time-stepping
deltim,0.1,0.05,delt,on ! time step control
outres,basic,all ! save all load step information
physics,write,thermal ! write thermal physics file
finish
*do,i,1,ftime/tinc ! solution *do loop
time=time+tinc ! increment time
physics,read,emag ! read emag physics file
/solu
*if,i,eq,1,then
tunif,100 ! initial temperature
*else
ldread,temp,last,,,,,rth ! read thermal analysis temperatures
*endif
solve ! solve harmonic analysis
finish
physics,read,thermal ! read thermal physics file
/assign,esav,therm,esav ! redirect files for use in thermal restart
/assign,emat,therm,emat
/solu
*if,i,gt,1,then
antype,trans,rest ! thermal restart
*endif
time,time ! time at end of thermal run
esel,s,mat,,2 ! select billet region
ldread,hgen,,,,2,,rmg ! apply coupled joule heating load from emag
esel,all
solve
finish
/assign,esav ! reassign files to default
/assign,emat
*enddo ! end of solution looping
finish
save,wendu,db
!以下的是计算变形的,但是收敛值非常小,老是出现低于收敛容差很多的警告,结果也不对。哪位高人能够指出问题出在哪里?
!欢迎修改命令流
!计算变形
fini
/FILNAM,DEFORM
/CONFIG,NRES,5000
/PREP7
BFDELE,ALL,ALL ! DELETE THERMAL ANALYSIS HEAT GENERATION LOADS
SFDELE,ALL,ALL ! DELETE THERMAL ANALYSIS CONVECTION LOADS
DDELE,ALL,ALL ! DELETE THERMAL ANALYSIS TEMP. CONSTRAINTS
ET,1,42
et,2,0
MP,EX,1,2.18E11,-1.40E8
MP,EX,2,2.18E11,-1.40E8
MPTEMP
MPTEMP,1,0,100,200,300,400,500
MPTEMP,7,600,700,750
MPDATA,PRXY,1,1,0.288,0.290,0.294,0.298,0.302,0.310
MPDATA,PRXY,1,7,0.318,0.328,0.332
MPTEMP
MPTEMP,1,0,50,200,250,300,400
MPTEMP,7,450,500,600,650,700,750
MPDATA,ALPX,1,1,12E-6,12.5E-6,14E-6,14.25E-6,14.65E-6,15.35E-6
MPDATA,ALPX,1,7,15.7E-6,15.85E-6,16.4E-6,16.6E-6,16.7E-6,16.8E-6
TB,BISO,1
TBTEMP,0
TBDATA,1,3E8,4.4E9
TBTEMP,200
TBDATA,1,2.84E8,4.17E9
TBTEMP,400
TBDATA,1,0.95E8,2.8E9
TBTEMP,600
TBDATA,1,0.3E8,4.17E9
TBTEMP,800
TBDATA,1,0.2E8,4.17E9
FINISH
/SOLU
ANTYPE,STATIC
CNVTOL,F,,,,0.02
LSCLEAR,ALL
EQSLV,SPARSE,1E-5
TREF,TMPINIT
NLGEOM,ON
KBC,0
NSUBST,1,5,1
OUTRES,NSOL,LAST
nsel,s,loc,x,0
nsel,r,loc,y,0
d,all,all,0
nsel,s,loc,x,plngth
nsel,r,loc,y,0
d,all,all,0
ALLS
TIME=0
*DO,I,1,FTIME/TINC
TIME=TIME+TINC
OUTRES,ALL,LAST
LDREAD,TEMP,,,TIME,0,induc,RTH,
TIME,TIME
SOLVE
*ENDDO
save
页:
[1]