求助：fluid116单元的例子中的问题？
请问：为什么下面例子中表示流体的线段比流体壁面长？管内流体的物理属性以及入口条件
导热系数 0.6W/(m*c)
密度 1000kg/m3
比热 4183J/(kg*c)
入口温度 20c
入口流速 3m/s
壁管的物理属性和几何属性
导热系数 100W/(m*c)
管外径 5/16inch
壁厚 0.083inch
长度 12inch
管外对流条件
环境温度 100c
对流系数 10000w/(m2*c)
管内对流条件
对流系数 15000w/(m2*c)
/prep7
!转换数据为SI
pi=acos(-1)
ri=((5/16)-0.083)*0.0254 !=0.0058293管内半径
r0=(5/16)*0.0254 !=0.0079375管外半径
l=12*0.0254 !=0.3048管长度
nthick=1 !径向单元个数
size=(r0-ri)/nthick !=0.0021082径向单元长度
nlength=nint(l/size) !=145长度方向单元个数
ktube=100 !管导热系数
kwater=0.6 !流体导热系数
denswatr=1000 !流体密度
cwater=4183 !流体比热
vinput=3 !入口流速
carea=pi*(ri**2) !流通面积
massflow=vinput*carea*denswatr !质量流率
tinlet=20 !流体入口温度
tbulk=100 !管外环境温度
hi=15000 !管内壁与流体的对流系数
h0=10000 !管外壁对流系数
!定义三类单元
et,1,116,1,1 !KEYOPT(1)＝1自由度为温度
!KEYOPT(2)＝1使用SURF151模拟管内对流
et,2,151,,,1,1,1 !KEYOPT(3)＝1，轴对称
!KEYOPT(4)＝1，无中间节点
!KEYOPT(5)＝1，有额外节点，在FLUID116上
keyopt,2,8,2 !KEYOPT(8)＝2，考虑对流
et,3,55,,,1 !KEYOPT(3)＝1，轴对称
r,1,2*ri,carea,1 !FLUID116的实常数
mp,kxx,1,kwater
mp,c,1,cwater
mp,dens,1,denswatr
mp,kxx,3,ktube
!建模
k,1,0,0,0
k,2,0,-l,0 !注意不是-1，而是-L
k,3,0,-(l+size),0 !注意不是-(1+size)，而是-(L+size)
l,1,2
l,2,3 !线1和2模拟管内流体流动
cm,waterlin,lines !创建组元，用于生成表面单元
rectng,ri,r0,0,-l !管壁,-L
type,1
real,1
mat,1
esize,,nlength
lmesh,1
esize,,1
lmesh,2
lsel,s,loc,x,(ri+r0)/2 !选择管两端
lesize,all,,,nthick !厚度方向单元个数
esize,,nlength !单元大小
type,3
mat,3
allsel,all
amesh,1
lsel,s,loc,x,ri !选择管内壁
cm,tubelin,lines
type,2
lfsurf,'tubelin','waterlin' !使用宏LFSURF创建表面效应单元
/solu
dk,1,temp,tinlet !流体入口温度
lsel,s,loc,x,r0
sfl,all,conv,h0,,tbulk !管外壁对流边界
esel,s,ename,,surf151
sfe,all,,conv,0,hi !管内壁对流系数
esel,s,ename,,fluid116
sfe,all,,hflux,,massflow !管内流体质量流率，以热流密度方式加载
allsel,all
solve
finish
/post1
nsel,s,loc,x,0 !选择FLUID116
prnsol,temp !列出流体温度分布
nsel,s,loc,x,r0 !选择管外壁节点
prnsol,temp !列出管外壁节点温度 问本帖原创作者nwpuyl吧
页:
[1]