ansys屈曲分析荷载问题
屈曲分析中荷载怎么加?如果加了不收敛怎么办?我很迷茫~~~~忘高手赐教啊~~ 后屈曲过程中,施加的屈曲载荷是根据前屈曲(特征值屈曲)的结果得到的,可以再稍微设大一些,如果不收敛,说明发生屈曲,那么载荷应该有一个近似的水平段,其对应的载荷就是屈曲载荷 利用arc-length方法阿 有没有好一点的例题,书上的都极其简单,全是些杆件的例子,家的载荷也全部是单位载荷,如果一个体模型在上面加很多载荷,是否也像那样分析呢?楼主能否指教 是呀,ansys关于弧长法的例子很少的,对于复杂结构很难收敛 这个实例虽然比较简单,但是整个的分析过程很具有代表性对与掌握分析屈曲过程的步骤很有帮助,前两天刚做的
贴出来共享
!悬臂梁受端部轴向压力作用的屈曲分析
!先进行静力分析,在进行特征值屈曲分析,最后进行非线性分析
!静力分析
/prep7 !
*set,f1,-1e6 !设置轴向压力荷载参数
et,1,beam189 !
sectype,1,beam,I,,2 !设置截面参数
secoffset,cent !
secdata,0.15,0.15,0.25,0.015,0.015,0.015,0,0,0,0 !
mp,dens,1,7.85e3 !设置材料参数
mp,ex,1,2.06e11 !
mp,nuxy,1,0.2 !
k,1,0 !
k,2,2.5,0 !
k,3,1.25,1 !
lstr,1,2 !
latt,1,,1,,3,,1 !
lesize,1,,,10 !
lmesh,1 !
/view,1,1,1,1 !
/eshape,1.0 !
dk,1,,,,0,all, !
fk,2,fx,f1 !施加关键点压力
finish !
!
/solu !
antype,0 !
eqslv,spar !求解器设置稀疏矩阵直接法
postres,on !打开预应力开关
solve !
finish !
!特征值屈曲分析
/solu !
antype,1 !
bucopt,lanb,6,0 !取前六阶模态分析
mxpand,6,0,0,1,0.001 !
solve !
finish !
!
/post1 !
set,first !
pldisp,2 !
set,next !
pldisp,2 !
set,next !
pldisp,2 !
set,next !
pldisp,2 !
set,next !
pldisp,2 !
set,next !
pldisp,2 !
*get,freq1,mode,1,freq !
finish !
!非线性屈曲分析
/config,nres,200 !只记录两百步的结果 !
/prep7 !
tb,biso,1,1,2 !定义材料非线性
tbtemp,0 !
tbdata,,2.0e8,0 !
upgeom,0.01,1,1,'beam-flexure','rst' !对有限元模型进行一阶模态的位移结果0.01倍的修改
finish !
!
/solu !
antype,0 !
nlgeom,1 !打开大变形
outres,all,all !
arclen,1,0 !弧长法设置
arctrm,l !弧长法终止准则 达到第一个峰值是终止计算
nsubst,200,,,1 !
fk,2,fx,f1*freq1 !将轴向压力值放大,放大系数为第一阶模态的主频
solve !
finish !
!
/post26 !
nsol,2,2,u,y,deflection !提取自由端y方向的位移为变量deflection
rforce,3,1,f,x,reactionf !提取固定端x方向的支座反力为变量reactionf
/axlab,x,deflection !
/axlab,y,reactionf !
xvar,2 !
plvar,3 !
finish ! 学习下!呵呵 好东西
谢谢 就应该不收敛啊,说明中断地方的荷载值就是极限承载力,所以ansys算不下去了,已经达到了后屈曲分析的目的。 1# PETERASD 楼上的说的对吗?!
很疑惑! 载荷中既包括重力,弯矩,与力,不知怎么弄啊,高手指点一下啊!
页:
[1]