兩個懸臂樑接觸

timboytimboy

請問一下~

我mesh完 給完材料及solid185之後  想問要怎麼設定兩個樑互相產生接觸呢?????  (我是施力在一個樑然後再碰另一個樑，目前不知如呵產生接觸)

非常謝謝!!

zhanghong130

希望这个例子对你有帮助。

FINISH   
/CLEAR
/PREP7
ANTYPE,0                        ! STATIC ANALYSIS               
ET,1,BEAM188                    ! 3-D 2-NODE BEAM
KEYO,1,3,2                      ! QUADRATIC SHAPE FUNCTIONS ALONG THE LENGTH

ET,2,BEAM188                    ! 3-D 2-NODE BEAM
KEYO,2,3,2                      ! QUADRATIC SHAPE FUNCTIONS ALONG THE LENGTH

SECTYPE,   1, BEAM, RECT, , 0   
SECOFFSET, CENT
SECDATA,30,20,0,0,0,0,0,0,0,0   


R,2,15,15                     ! RADIUS ON THE TARGET AND CONTACT SIDES
RMODIF,2,3,-1.0E+8             ! NORMAL CONTACT STIFFNESS-ABSOLUTE VALUE
RMODIF,2,12,-1.0E+8            ! TANGENTIAL CONTACT STIFFNESS-ABSOLUTE VALUE

ET,3,CONTA176                   ! 3D LINE-TO-LINE CONTACT
KEYOPT,3,2,1                    ! PENALTY FUNCTION
KEYOPT,3,3,0                   ! paralled BEAMS

ET,4,TARGE170                   ! 3D TARGET SEGMENT
MP,EX,1,2e5                 ! YOUNG'S MODULUS

MP,PRXY,1,0.0                   ! POISSON'S RATIO
MP,MU,1,0.1                     ! FRICTION COEFFICIENT


K,1,0,0,0                       ! GEOMETRY OF BEAMS
K,2,500,0,0
K,3,490,40,0
K,4,990,40,0
L,1,2
L,3,4

TYPE,1                          ! left BEAM
MAT,1
SECNUM,1
LESIZE,1,,,10
LMESH,1

TYPE,2                          ! right BEAM
MAT,1
SECNUM,1
LESIZE,2,,,10
LMESH,2

TYPE,3                          ! CONTACT ON HORIZONTAL BEAM
REAL,2
MAT,1
ESEL,S,TYPE,,1
NSLE
ESURF

TYPE,4                          ! TARGET ON VERTICAL BEAM
REAL,2
MAT,1
ESEL,S,TYPE,,2
NSLE
ESURF

ALLSEL,ALL
DK,1,ALL                        ! CLAMPED left END OF left BEAM
DK,4,ALL                        ! CLAMPED right END OF right BEAM

DK,3,Uy,-20                   ! HORIZONTAL DISPLACEMENT OF left END of right beam

FINI
/SOLU
NLGEOM,ON
NSUBST,60,100,60
OUTRES,ALL,ALL
/ESHAPE,1.0
SOLVE
FINI

zhanghong130

C:/1.png