轴建模与受力分析_学习编出来的第一个程序，求高手指点

dengjiaquan

F=2084.6N，FQ=2751.7  M=131.8N.M

!轴建模与受力分析
/CLEAR
/FILNAME,DAI-LUN-ZHOU    !定义工作文件名
/TITLE,CHECKING SHAFT    !定义工作标题
/PREP7                   !进入前处理器
ET,1,PLANE82             !定义单元类型
ET,2,SOLID185
KEYOPT,1,3,1             !设置单元关键字
MP,EX,1,2.1E11           !输入弹性模量
MP,PRXY,1,0.3            !输入泊松比
K,1,0,0,0                !创建关键点
K,2,0.016,0,0
K,3,0.016,0.03,0
K,4,0.018,0.03,0
K,5,0.018,0.098,0
K,6,0.020,0.098,0
K,7,0.020,0.108,0
K,8,0.018,0.108,0
K,9,0.018,0.178,0
K,10,0.016,0.178,0
K,11,0.016,0.22,0
K,12,0.012,0.22,0
K,13,0.012,0.328,0
K,14,0,0.328,0
A,1,2,3,4,5,6,7,8,9,10,11,12,13,14    !由点生成面
VROTAT,1,,,,,,1,14,90,   !旋转90度生成实体
APLOT                    !显示面
ESIZE,0.002              !定义单元尺寸大小
AMESH,1                  !对面进行网格划分
VSWEEP,1,1,15,           !通过扫掠命令对体进行分格
EPLOT                    !显示单元
SAVE
NSEL,S,,,7191,7202       !选择节点7191—7202
CM,CM_1,NODE             !定义组件CM_1
LOCAL,11,1,0,0.254,0,0,-90,0,, !创建节点柱坐标系11
CSYS,11                  !激活节点柱坐标系
CMSEL,S,CM_1             !选择组件CM_1
NROTAT,ALL               !将节点坐标系旋转到激活坐标系的方向
F,CM_1,FY,48.4           !对组件CM_1施加集中力载荷
NSEL,S,,,5982,5993       !选择节点5982—5993      
CM,CM_2,NODE             !定义组件CM_2            
ALLSEL,ALL $CSYS,0 $WPCSYS,-1,0  !从原始直角坐标开始，工作面与原始坐标
系重合
LOCAL,12,1,0,0.064,0,0,-90,0,,   !创建节点柱坐标系12
CSYS,12
CMSEL,S,CM_2             !选择组件CM_2
NROTAT,ALL               !将节点坐标系旋转到激活坐标系的方向
F,CM_2,FY,16             !对组件CM_2施加集中力载荷
F,CM_2,FX,-24.9          !对组件CM_2施加集中力载荷
NSEL,S,,,5606,5617       !选择节点5606—5617
CM,CM_3,NODE             !定义组件CM_3
ALLSEL,ALL $CSYS,0 $WPCSYS,-1,0  !从原始直角坐标开始，工作面与原始坐标
LOCAL,13,1,0,0.008,0,0,-90,0,,   !创建节点柱坐标系13
CSYS,13                  !激活节点柱坐标系
CMSEL,S,CM_3             !选择组件CM_3
NROTAT,ALL               !将节点坐标系旋转到激活坐标系的方向
D,CM_3,ALL               !对组件CM_3施加位移约束
NSEL,S,,,6775,6786       !选择节点6775—6786
CM,CM_4,NODE             !定义组件CM_4
ALLSEL,ALL $CSYS,0 $WPCSYS,-1,0  !从原始直角坐标开始，工作面与原始坐标
LOCAL,14,1,0,0.186,0,0,-90,0,,   !创建节点柱坐标系14
CSYS,14                  !激活节点柱坐标系
CMSEL,S,CM_4             !选择组件CM_4
NROTAT,ALL               !将节点坐标系旋转到激活坐标系的方向
D,CM_4,ALL               !对组件CM_4施加位移约束
CSYS,0                   !将坐标系转换为直角坐标系
CSDELE,11,14,1           !删除节点坐标系
FINISH
SAVE
/SOLU                    !进入求解器
ANTYPE,STATIC            !指定分析类型
ALLSEL,ALL               !选中所有项目
SOLVE                    !开始求解运算
FINISH
SAVE
/POST1                   !进入后处理器
PLNSOL,S,X               !绘制X方向应力等值线图
PLNSOL,S,Y               !绘制Y方向应力等值线图
PLNSOL,S,Z               !绘制Z方向应力等值线图
PLNSOL,S,EQV             !绘制等效应力等值线图
/REPLOT                  !显示所有信息
FINISH

senja

楼主第一次编写命令，也还不错了的。
轴带有两个凹槽，不能这么简化为1/4模型，需要建立全模。
划分映射网格划分之后，使用plane单元划分的面网格需要删除。
主要是两点，其他的慢慢摸索，总体不错。

dengjiaquan

senja 发表于 2012-3-22 22:10
楼主第一次编写命令，也还不错了的。
轴带有两个凹槽，不能这么简化为1/4模型，需要建立全模。
划分映射网 ...

整体建模 无法用扫掠命令，老是出错，怎么回事呢~~不删除面网格和删除面网格区别大么，删除面网格的命令是哪个呢？谢谢谢谢了！！！

senja

dengjiaquan 发表于 2012-3-23 09:32
整体建模 无法用扫掠命令，老是出错，怎么回事呢~~不删除面网格和删除面网格区别大么，删除面网格的命令 ...

楼主现在可以去看看几种网格划分方法对几何模型的要求。扫略或者映射都对几何模型有要求的。
因为你扫略使用了plane82划分面，那么这个面具有plane82的属性（包括厚度），而实际上轴是solid，这有点干扰。删除面网：选择该面（asel），删去该面上网格（aclear）