随温度变化的热流怎么设置。求解

wuleishengli

求搞定下这个：真心不会做。根据下表做个换热系数

1先做一个换热系数VS温度的函数
2在把函数导入做成表变量
3然后定义换热系数的时候选择这个表变量

。

qusthkx

这个算比较基础，可以找本书照做。在网上不好说清楚

wuleishengli

qusthkx 发表于 2012-5-26 23:35
这个算比较基础，可以找本书照做。在网上不好说清楚

那在命令流中。随温度变化的对流系数怎么设置啊。比如mpdata，1，kxx，，，，，，，，这种

qusthkx

mpdata后面先写kxx

fancyfreer

GUI的MP不好么
然后FLOTRAN设置流体属性的时候选择MP table并且可变

liudapengsnd

/filename,Themal
/title,themal_analysis  !标题
/PREP7                  !前处理

!定义单元类型
ET,1,SOLID70

!设置材料属性
   !材料1为混凝土  
MP,KXX,1,280.43      
MP,C,1,0.976            
MP,DENS,1,2450         
MAT,1                  
   !材料2为基础土  
MP,KXX,2,287.53        
MP,C,2,1.45            
MP,DENS,2,1670         
MAT,2                  

!输入参数
   
   !输入外界气温表
*DIM,qiwen,TABLE,21,1,1,TIME, , ,  !外界气温表名为qiwen
QIWEN(1,0,1) = 0
QIWEN(1,1,1) = 16.5
QIWEN(2,0,1) = 0.5  
QIWEN(2,1,1) = 21.4
QIWEN(3,0,1) = 1
QIWEN(3,1,1) = 18   
QIWEN(4,0,1) = 1.5  
QIWEN(4,1,1) = 26.2
QIWEN(5,0,1) = 2
QIWEN(5,1,1) = 18.3
QIWEN(6,0,1) = 2.5  
QIWEN(6,1,1) = 28.6
QIWEN(7,0,1) = 3
QIWEN(7,1,1) = 15   
QIWEN(8,0,1) = 3.5  
QIWEN(8,1,1) = 33   
QIWEN(9,0,1) = 4
QIWEN(9,1,1) = 16.7
QIWEN(10,0,1) = 4.5
QIWEN(10,1,1) = 29  
QIWEN(11,0,1) = 5   
QIWEN(11,1,1) = 16.5
QIWEN(12,0,1) = 5.5
QIWEN(12,1,1) = 26  
QIWEN(13,0,1) = 6   
QIWEN(13,1,1) = 11.6
QIWEN(14,0,1) = 6.5
QIWEN(14,1,1) = 32.6
QIWEN(15,0,1) = 7   
QIWEN(15,1,1) = 16  
QIWEN(16,0,1) = 7.5
QIWEN(16,1,1) = 34.2
QIWEN(17,0,1) = 8   
QIWEN(17,1,1) = 11.6
QIWEN(18,0,1) = 8.5
QIWEN(18,1,1) = 30.8
QIWEN(19,0,1) = 9   
QIWEN(19,1,1) = 15.4
QIWEN(20,0,1) = 9.5
QIWEN(20,1,1) = 31  
QIWEN(21,0,1) = 10  
QIWEN(21,1,1) = 13
   !输入热生成率函数
*SET,_FNCNAME,'heats'   
*DIM,%_FNCNAME%,TABLE,6,16,1
   ! Begin of equation: 2450*0.7462*227.2246*0.13*exp(-0.7426*{TIME})  
%_FNCNAME%(0,0,1)= 0.0, -999
%_FNCNAME%(2,0,1)= 0.0  
%_FNCNAME%(3,0,1)= 0.0  
%_FNCNAME%(4,0,1)= 0.0  
%_FNCNAME%(5,0,1)= 0.0  
%_FNCNAME%(6,0,1)= 0.0  
%_FNCNAME%(0,1,1)= 1.0, -1, 0, 2450, 0, 0, 0
%_FNCNAME%(0,2,1)= 0.0, -2, 0, 0.7462, 0, 0, -1
%_FNCNAME%(0,3,1)=   1, -3, 0, 1, -1, 3, -2
%_FNCNAME%(0,4,1)= 0.0, -1, 0, 227.2246, 0, 0, -3   
%_FNCNAME%(0,5,1)= 0.0, -2, 0, 1, -3, 3, -1
%_FNCNAME%(0,6,1)= 0.0, -1, 0, 0.13, 0, 0, -2   
%_FNCNAME%(0,7,1)= 0.0, -3, 0, 1, -2, 3, -1
%_FNCNAME%(0,8,1)= 0.0, -1, 0, 0, 0, 0, 0   
%_FNCNAME%(0,9,1)= 0.0, -2, 0, 1, 0, 0, -1  
%_FNCNAME%(0,10,1)= 0.0, -4, 0, 1, -1, 2, -2
%_FNCNAME%(0,11,1)= 0.0, -1, 0, 0.7426, 0, 0, -4
%_FNCNAME%(0,12,1)= 0.0, -2, 0, 1, -4, 3, -1
%_FNCNAME%(0,13,1)= 0.0, -1, 0, 1, -2, 3, 1
%_FNCNAME%(0,14,1)= 0.0, -1, 7, 1, -1, 0, 0
%_FNCNAME%(0,15,1)= 0.0, -2, 0, 1, -3, 3, -1
%_FNCNAME%(0,16,1)= 0.0, 99, 0, 1, -2, 0, 0
   ! End of equation: 2450*0.7462*227.2246*0.13*exp(-0.7426*{TIME})


!创建几何体
BLOCK,,5,,7.5,,2.4          !创建混凝土块
BLOCK,,20,,20,-10,0         !创建基础土体
KWPLAN,-1,4,3,6             !定位工作坐标系1
VSBW,ALL                    !分割体1
KWPLAN,-1,3,1,7             !定位工作坐标系2
VSBW,ALL                    !分割体2
VGLUE,ALL                   !GLUE所有体元素
NUMMRG,ALL                  !合并所有重复元素
NUMCMP, ALL                 !压缩所有元素的编号
CSYS,0                      !返回全局坐标系

!进行网格划分
      !划分混凝土体
VSEL,S,,,1,1,1              !选择混凝土体
VATT,1,,1,0                 !指定混凝土材料
ALLSEL
VSEL,U,,,1,1,1              !选择基础土体
VATT,2,,1,0                 !指定基础土体材料
ALLSEL                      !选择所有料
LSEL,S,,,5,5,1              !选择混凝土短边
LESIZE,ALL,,,5              !混凝土短边划分为5
LSEL,S,,,8,8,1              !选择混凝土长边
LESIZE,ALL,,,10             !混凝土短边划分为10
LSEL,S,,,9,9,1              !选择混凝土高
LESIZE,ALL,,,6              !混凝土高划分为6
      !划分基础土体   
LSEL,S,,,1,1,1              !选择混凝土高
LESIZE,ALL,,,10
LSEL,S,,,4,4,1
LESIZE,ALL,,,5
LSEL,S,,,15,15,1  
LSEL,A,,,13,13,1
LSEL,A,,,24,39,15
LSEL,A,,,20,30,10
LSEL,A,,,37,40,3
LESIZE,ALL,,,6
LSEL,S,,,2,2,1
LESIZE,ALL,,,5
LSEL,S,,,3,3,1
LESIZE,ALL,,,10
ALLSEL
VMESH,ALL                   !映射划分网格
FINISH

/SOLU                       !进入求解器
ANTYPE,4                    !选择瞬态求解                 
TRNOPT,FULL
LUMPM,0
ESEL,S,MAT,,1               !选择混凝土体的所有结点
NSLE,S  
IC,all,TEMP,23.6            !混凝土的浇筑温度为23.6
ESEL,S,MAT,,2               !选择基础土体的所有结点
NSLE,S                     
IC,all,TEMP,16              !基础的初始温度为16
ALLSEL
SFA,4,1,CONV,616.32, %QIWEN%  !四周木模对流系数616.32
SFA,6,1,CONV,616.32, %QIWEN%
SFA,2,1,CONV,2054.4, %QIWEN%  !上面裸露对流系数616.32
BFV,1,HGEN, %HEATS%           !输入热生成率heats
ALLSE                         !选择所有
TRNOPT,FULL                   !设置计算方法
*DO,DAY,0.5,10,0.5            !设置循环计算
TIME,DAY                      !设置荷载步时间
AUTOTS,0                      !关闭自动时间步长
KBC,0                         !设置阶梯荷载步
TSRES,ERASE                   !Defines an array of keytimes at which the time-stepping strategy changes
OUTRES,ALL,ALL                !输出所有项
SOLVE                         !开始计算
*ENDDO                        !终止循环计算

!结构应力分析
/PREP7                                !前处理
ETCHG,TTS                             !转换热分析单元为结构单元
  
  !输入参数
!定义变化弹模EXX
*DIM,EXX,ARRAY,20
EXX(1,1,1) = 0.87e10   
EXX(2,1,1) = 1.05e10   
EXX(3,1,1) = 1.17e10   
EXX(4,1,1) = 1.26e10   
EXX(5,1,1) = 1.33e10   
EXX(6,1,1) = 1.39e10   
EXX(7,1,1) = 1.44e10   
EXX(8,1,1) = 1.48e10   
EXX(9,1,1) = 1.52e10   
EXX(10,1,1) = 1.56e10  
EXX(11,1,1) = 1.59e10  
EXX(12,1,1) = 1.61e10  
EXX(13,1,1) = 1.64e10  
EXX(14,1,1) = 1.67e10  
EXX(15,1,1) = 1.69e10  
EXX(16,1,1) = 1.71e10  
EXX(17,1,1) = 1.73e10  
EXX(18,1,1) = 1.75e10  
EXX(19,1,1) = 1.77e10  
EXX(20,1,1) = 1.79e10
!定义20种材料每0.5小时一种材料来反映弹模的改变
*DO,I,1,20,1                                   
    MP,DENS,I,2450        !混凝土 密度为2450
    MP,EX,I,EXX(I)        !混凝土 弹模为EXX(I)
    MP,PRXY,I,0.167       !混凝土 泊松比为0.167
    MP,ALPX,I,0.75E-5     !混凝土 热膨胀系数为0.75e-5
    MP,REFT,I,15          !定义参考温度
*ENDDO
VCLEAR, 2, 5, 1           !清除基础土体网格         
VDELE, 2, 5, 1, 1         !删除基础土体
ALLSEL                    !选择选择所有

/SOLU                     !进入求解器
NROPT,FULL                !Specifies the Newton-Raphson options in a full transient analysis
NLGEOM,ON                 !考虑大变形的影响
ASEL,S,,,1,1,1            !选择面1
NSLA,S,1                  !选择面1上的结点
D,all,ALL                 !加基础全约束
ALLSEL                    !选择选择所有
DA,3,SYMM                 !加对称约束
DA,5,SYMM                 !加对称约束
I=1
*DO,DAY,0.5,10,0.5
    ESEL, S, MAT, , I, I,1                    !选择混凝土材料号为I的元素
    ACEL,0,0,-9.8,                            !GRAVITY LOAD 施加重力荷载加速度
    LDREAD,TEMP,,,DAY, ,'themal','rth',' '    !TEMP LOAD Reads results from the results file and applies them as loads.
    TIME,DAY
    AUTOTS,0
    KBC,0                                     !设置阶梯荷载步
    TSRES,ERASE                               !Defines an array of keytimes at which the time-stepping strategy changes
    OUTRES,ALL,ALL,                           !输出所有的结果
    SOLVE                                     !计算
    I=I+1
    *IF,I,LE,20,THEN
        MPCHG,I,ALL
    *ENDIF
*ENDDO

zhang717556119

liudapengsnd 发表于 2012-6-25 14:31
/filename,Themal
/title,themal_analysis  !标题
/PREP7                  !前处理

liudapengsnd 受教了！