螺栓连接接头分析（附APDL）

heukevin

小人最近正在做螺栓连接接头的强度分析，下面是我编的APDL，建模和计算时我遇见以下几个问题，希望哪位高人可以帮着解答下，小人将不胜感激！1、采用PRETS 179单元给螺施加预紧力，我在给螺栓画网格时将螺栓切成4份（如图所示1），但是这样切割完成后，我采用
psmesh,1,bolt1,,volu,12,0,z,0,,,,bolt_1   !建立预紧单元
psmesh,2,bolt2,,volu,13,0,z,0,,,,bolt_2   !建立预紧单元
psmesh,3,bolt3,,volu,14,0,z,0,,,,bolt_3   !建立预紧单元
psmesh,4,bolt4,,volu,15,0,z,0,,,,bolt_4   !建立预紧单元
将螺栓创建预应力截面时，只有第一组可以创建，再对的其它组创建预应力截面后会出现Node 32298 in the element group being split byPSMESH is already used by PRET179 element 32291.  You must delete attached pretension sectionsand any manually defined pretension elements before issuing or re-issuingPSMESH. The PSMESH command is ignored.的警告，这样螺栓剩下的3/4不能再创建预应力截面，整个螺栓只有其中的1/4创建了预应力截面。如果通过PRETS 179单元给螺施加预紧力这时是只加到螺栓的1/4 截面上，还是整个螺栓上都施加了预紧力？求高人指点？

2、计算时会出现precondictioned conjugate gradient solver error level1.Possibly,the model is unconstrained or additional inerations may be need.Try running with a multiplier MULT.1 in EQSLV command <3> mult>1的错误，请问这是怎么回事？求指点！


FINISH
/CLEAR
/FILNAME,single-bolt-20-50KN-100N-dengxiao
/PREP7
L1=0.15                          !钢搭板的长度
L2=0.15                          !复合材料板的长度
L3=0.1                           !搭接的长度
B=0.1                            !钢搭板和复合材料板的宽度
T1=0.01                          !钢搭板的厚度
T2=0.02                          !复合材料板的厚度
R0=0.01                          !螺栓孔的直径
R1=0.01                          !螺栓的直径
S=0.015                          !螺母的直径
K=0.01                           !螺母的厚度
FORC_BOLT=50000                  !螺栓预紧力
!***************************************************************               
! Define the element type,material properites and real constant!                  
!***************************************************************
ET,1,SOLID45
ET,2,SOLID46
MP,EX,1,1.35E11
MP,EY,1,8.8E9
MP,EZ,1,8.8E9
MP,EZ,1,8.8E9
MP,PRXY,1,0.3
MP,PRYZ,1,0.48
MP,PRXZ,1,0.3
MP,GXY,1,4.47E9
MP,GYZ,1,3.2E9
MP,GXZ,1,4.47E9
MP,DENS,1,1380
MP,EX,2,2.06E11
MP,PRXY,2,0.3
MP,DENS,2,7850
R,1
RMODIF,1,1,5,0,0,0                                            !solid46的实常数，分为5层，每层厚度7mm(总厚度应等于T2)   
RMODIF,1,13,1,0,0.004,1,45,0.004,   
RMODIF,1,19,1,90,0.004,1,-45,0.004,
RMODIF,1,25,1,0,0.004,
!***************************               
! Creat the geometry model!                 
!***************************
BLC5,(L3-L1)/2,0,L1,B,T1                                     !创建下钢打板，注意X坐标
WPOFFS,0,0,T1
BLC5,(L2-L3)/2,0,L2,B,T2                                     !创建复合材料板，注意X坐标
WPOFFS,0,0,T2
BLC5,(L3-L1)/2,0,L1,B,T1                                     !创建上钢打板，注意X坐标
WPOFFS,0,0,-(T1+T2)
CYL4,0,0,R0, , , ,(2*T1+T2)                                  !创建切割圆柱
*DO,I,1,3,1                                                  !切割下钢打板、复合材料板、上钢打板
VSBV,I,4,,DELETE,KEEP
*enddo
VDELE,4, , ,1
NUMCMP,ALL
wpoffs,0,0,-k
CYL4,0,0,R1, , , ,(2*T1+T2+2*k)                              !创建螺栓
CYL4,0,0,R1, ,S, ,K                                          !创建下螺母
WPOFFS,0,0,(K+2*T1+T2)
CYL4,0,0,R1, ,S, ,K                                          !创建上螺母
VGLUE,4,5                                                    !粘接螺母与螺栓
VGLUE,6,7                                                    !粘接螺母与螺栓
NUMCMP,ALL
wpoffs,-B/2,0,0                                              !
wprota,0,0,-90
vsbw,2
vsbw,3
wpoffs,0,0,-B                                                !
vsbw,1
NUMCMP,ALL
vsel,s,,,3,5,1  
vsel,a,,,7,9,1
allsel,below,volu
wpoffs,0,0,B/2
vsbw,all
wprota,0,90,0
vsbw,all
WPCSYS,-1,0
allsel
NUMCMP,ALL
!**********************            
!Endow the attributes!                 
!**********************
vsel,s,,,20,23,1
cm,cm_composite_bufen,volu
vsel,a,,,2
allsel,below,volu
cm,cm_composite,volu
vatt,1,1,2,,
allsel
cmsel,u,cm_composite
allsel,below,volu
cm,cm_steel,volu
vatt,2,,1,,
cmdele,cm_steel
allsel           
!***************************
!Define the volume compoent!
!***************************
vsel,s,,,12,15,1
cm,cm_luoshuan,volu
vsel,s,,,3,5,1
vsel,a,,,7,11,1
cm,cm_luomu,volu
vsel,s,,,16,19,1
cm,cm_xiadaban_bufen,volu
vsel,a,,,1
cm,cm_xiadaban,volu
vsel,s,,,24,27,1
cm,cm_shangdaban_bufen,volu
vsel,a,,,6
cm,cm_shangdaban,volu
allsel
!***********************************************
!Define the target and contact surface compoent!
!***********************************************
cmsel,s,cm_luomu
allsel,below,volu
asel,r,loc,z,(2*t1+t2)
CM,CM_target1,AREA
allsel
cmsel,s,cm_luomu
allsel,below,volu
asel,r,loc,z,0
CM,CM_target4,AREA  
allsel
cmsel,s,cm_shangdaban_bufen
allsel,below,volu
asel,r,loc,z,(2*t1+t2)
CM,CM_contact1,AREA
allsel
cmsel,s,cm_shangdaban_bufen
allsel,below,volu
asel,r,loc,z,(t1+t2)
CM,CM_target2,AREA
allsel
cmsel,s,cm_composite_bufen
allsel,below,volu
asel,r,loc,z,(t1+t2)
CM,CM_contact2,AREA
allsel
cmsel,s,cm_composite_bufen
allsel,below,volu
asel,r,loc,z,t1
CM,CM_contact3,AREA
allsel
cmsel,s,cm_xiadaban_bufen
allsel,below,volu
asel,r,loc,z,t1
CM,CM_target3,AREA
allsel
cmsel,s,cm_xiadaban_bufen
allsel,below,volu
asel,r,loc,z,0
CM,CM_contact4,AREA
allsel
csys,1
cmsel,s,cm_luoshuan
allsel,below,volu
asel,r,loc,x,r1
asel,r,loc,y,90,270
CM,CM_target5,AREA
allsel
cmsel,s,cm_composite_bufen
cmsel,a,cm_shangdaban_bufen
cmsel,a,cm_xiadaban_bufen
allsel,below,volu
asel,r,loc,x,r1
asel,r,loc,y,90,270
CM,CM_contact5,AREA
allsel
!*******************************
!Size control and mesh the bolt!
!*******************************
cmsel,s,cm_luoshuan
allsel,below,volu
cm,cm_l_luoshuan,line
lesize,cm_l_luoshuan,0.001, , , , , , ,1
lsel,u,loc,x,r1  
lsel,u,loc,x,0
cm,cm_l_luoshuan1,line
lesize,cm_l_luoshuan1,0.001, , ,0.4, , , ,1
cmdele,cm_l_luoshuan1
allsel
cmsel,s,cm_l_luoshuan
lsel,r,loc,x,r1
lsel,u,loc,z,-k
lsel,u,loc,z,0
lsel,u,loc,z,(2*t1+t2)
lsel,u,loc,z,(2*t1+t2+k)
cm,cm_l_luoshuan2,line
lesize,cm_l_luoshuan2,0.002, , , , , , ,0
cmdele,cm_l_luoshuan
cmdele,cm_l_luoshuan2
allsel
cmsel,s,cm_luoshuan
allsel,below,volu
VSWEEP,12,39,38
VSWEEP,13,42,38
VSWEEP,14,45,39
VSWEEP,15,45,42
!psmesh,1,bolt1,,volu,12,0,z,0,,,,bolt_1   !建立预紧单元
!psmesh,2,bolt2,,volu,13,0,z,0,,,,bolt_2   !建立预紧单元
!psmesh,3,bolt3,,volu,14,0,z,0,,,,bolt_3   !建立预紧单元
!psmesh,4,bolt4,,volu,15,0,z,0,,,,bolt_4   !建立预紧单元
allsel
!*******************************
!Size control and mesh the nut!
!*******************************
cmsel,s,cm_luomu
allsel,below,volu
lsel,u,loc,x,R1
cm,cm_l_luomu,line
lesize,cm_l_luomu,0.002, , , , , , ,1
lsel,r,loc,x,s
lsel,u,loc,z,-k
lsel,u,loc,z,0
lsel,u,loc,z,(2*t1+t2)
lsel,u,loc,z,(2*t1+t2+k)
cm,cm_l_luomu1,line
lesize,cm_l_luomu1,0.002, , , , , , ,1
cmdele,cm_l_luomu1
allsel
cmsel,s,cm_luomu
allsel,below,volu
VSWEEP,10,29,64
VSWEEP,9,65,24  
VSWEEP,11,29,65
VSWEEP,8,64,24  
VSWEEP,5,19,54  
VSWEEP,4,55,6   
VSWEEP,3,54,6   
VSWEEP,7,19,55
cmdele,cm_l_luomu
allsel
!***************************************
!Size control the overlap of the plate!
!***************************************
cmsel,s,cm_composite_bufen
cmsel,a,cm_shangdaban_bufen
cmsel,a,cm_xiadaban_bufen
allsel,below,volu
cm,cm_l_plate,line
lesize,cm_l_plate,0.002, , , , , , ,1
allsel
!**************************************
csys,0
lsel,s,loc,x,0.5*L3
lsel,a,loc,x,-0.5*L3
lsel,u,loc,y,0
lsel,u,loc,y,0.5*B
lsel,u,loc,y,-0.5*B
cm,cm_l_1,line
lesize,cm_l_1, , ,10, , , , ,0
cmdele,cm_l_1
allsel
!**************************************
cmsel,s,cm_l_plate
allsel,below,line
lsel,r,loc,y,0.5*B
lsel,u,loc,x,0
lsel,u,loc,x,0.5*L3
lsel,u,loc,x,-0.5*L3
cm,cm_l_2,line
lesize,cm_l_2, , ,9, , , , ,0
cmdele,cm_l_2
allsel
cmsel,s,cm_l_plate
allsel,below,line
lsel,R,loc,y,-0.5*B
lsel,u,loc,x,0
lsel,u,loc,x,0.5*L3
lsel,u,loc,x,-0.5*L3
cm,cm_l_3,line
lesize,cm_l_3, , ,9, , , , ,0
cmdele,cm_l_3
allsel
!**************************************
cmsel,s,cm_l_plate
allsel,below,line
lsel,r,loc,x,0
lsel,u,loc,y,R0
lsel,u,loc,y,-R0
lsel,u,loc,y,0.5*B
lsel,u,loc,y,-0.5*B
cm,cm_l_4,line
lesize,cm_l_4,0.003, , ,0.3, , , ,1
lsel,r,loc,z,0
cm,cm_l_5,line
lreverse,cm_l_5,0
cmdele,cm_l_5
allsel
cmsel,s,cm_l_4
lsel,r,loc,z,(2*t1+t2)
cm,cm_l_6,line
lreverse,cm_l_6,0
cmdele,cm_l_4
cmdele,cm_l_6
allsel
!**************************************
cmsel,s,cm_l_plate
allsel,below,line
lsel,r,loc,y,0
lsel,u,loc,X,R0
lsel,u,loc,X,-R0
lsel,u,loc,X,0.5*L3
lsel,u,loc,X,-0.5*L3
cm,cm_l_7,line
lesize,cm_l_7,0.003, , ,0.3, , , ,1
lreverse,cm_l_7,0
cmdele,cm_l_7
allsel
!******************************
!Mesh the overlap of the plate!
!******************************
cmsel,s,cm_shangdaban_bufen
allsel,below,volu
VSWEEP,24,91,131
VSWEEP,25,90,131
VSWEEP,26,137,90
VSWEEP,27,137,91
allsel
!******************************
cmsel,s,cm_composite_bufen
allsel,below,volu
VSWEEP,20,84,117
VSWEEP,21,117,85
VSWEEP,22,123,84
VSWEEP,23,85,123
allsel
!******************************
cmsel,s,cm_xiadaban_bufen
allsel,below,volu
VSWEEP,16,78,49
VSWEEP,17,79,49
VSWEEP,18,109,78
VSWEEP,19,109,79
allsel
!*****************************************
!Size control the other part of the plate!
!*****************************************
cmsel,u,cm_composite_bufen
cmsel,u,cm_shangdaban_bufen
cmsel,u,cm_xiadaban_bufen
cmsel,u,cm_luoshuan
cmsel,u,cm_luomu
allsel,below,volu
cm,cm_shengyu,volu
lsel,r,loc,y,0.5*B
lseL,u,loc,x,0.5*L3
lseL,u,loc,x,-0.5*L3
lseL,u,loc,x,(0.5*L3-L1)
lseL,u,loc,x,(L2-0.5*L3)
cm,cm_l_10,line
lesize,cm_l_10, , ,10, , , , ,0
cmdele,cm_l_10
allsel
!*********************************
!Mesh the other part of the plate!
!*********************************
cmsel,s,cm_shengyu
allsel,below,volu
vsweep,1
vsweep,2
vsweep,6
allsel
!*************************
!Define the contact pairs!
!*************************
!***************Create contact pair1***************!
r,2                           !定义接触实常数
real,2                        !指定接触实常数
mat,2                         !指定材料2
et,3,TARGE170                 !定义目标单元170
et,4,CONTA174                 !定义接触单元174
keyopt,4,9,0                  !包含初始化穿透
keyopt,4,10,2
!*****Generate the target surface*****!
cmsel,s,cm_target1            !选择目标面
type,3                        !指定单元接触类型
nsla,s,1                      !选择目标面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元  
allsel
!*****Generate the contact surface*****!
cmsel,s,cm_contact1           !选择接触面
type,4                        !指定单元接触类型
nsla,s,1                      !选择接触面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元
allsel  
!***************Create contact pair2***************!
r,3                           !定义接触实常数
real,3                        !指定接触实常数
mat,2                         !指定材料2
et,5,TARGE170                 !定义目标单元170
et,6,CONTA174                 !定义接触单元174
keyopt,6,9,0                  !包含初始化穿透
keyopt,6,10,2
!*****Generate the target surface*****!
cmsel,s,cm_target2            !选择目标面
type,5                        !指定单元接触类型5
nsla,s,1                      !选择目标面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元  
allsel
!*****Generate the contact surface*****!
cmsel,s,cm_contact2           !选择接触面
type,6                        !指定单元接触类型6  
nsla,s,1                      !选择接触面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元
allsel
!***************Create contact pair3***************!
r,4                           !定义接触实常数
real,4                        !指定接触实常数
mat,2                         !指定材料2
et,7,TARGE170                 !定义目标单元170
et,8,CONTA174                 !定义接触单元174
keyopt,8,9,0                  !包含初始化穿透
keyopt,8,10,2
!*****Generate the target surface*****!
cmsel,s,cm_target3            !选择目标面
type,7                        !指定单元接触类型7
nsla,s,1                      !选择目标面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元  
allsel
!*****Generate the contact surface*****!
cmsel,s,cm_contact3           !选择接触面
type,8                        !指定单元接触类型8  
nsla,s,1                      !选择接触面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元
allsel
!***************Create contact pair4***************!
r,5                           !定义接触实常数
real,5                        !指定接触实常数
mat,2                         !指定材料2
et,9,TARGE170                 !定义目标单元170
et,10,CONTA174                !定义接触单元174
keyopt,10,9,0                 !包含初始化穿透
keyopt,10,10,2
!*****Generate the target surface*****!
cmsel,s,cm_target4            !选择目标面
type,9                        !指定单元接触类型9
nsla,s,1                      !选择目标面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元  
allsel
!*****Generate the contact surface*****!
cmsel,s,cm_contact4           !选择接触面
type,10                       !指定单元接触类型10  
nsla,s,1                      !选择接触面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元
allsel
!***************Create contact pair5***************!
r,6                           !定义接触实常数
real,6                        !指定接触实常数
mat,2                         !指定材料2
et,11,TARGE170                !定义目标单元170
et,12,CONTA174                !定义接触单元174
keyopt,12,9,0                 !包含初始化穿透
keyopt,12,10,2
!*****Generate the target surface*****!
cmsel,s,cm_target5            !选择目标面
type,11                       !指定单元接触类型11
nsla,s,1                      !选择目标面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元  
allsel
!*****Generate the contact surface*****!
cmsel,s,cm_contact5           !选择接触面
type,12                       !指定单元接触类型12  
nsla,s,1                      !选择接触面上的所有节点，包括边界点
esln,s,0                      !选择依附于这些节点的单元
esurf,all                     !构建接触单元
allsel
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FINISH
/SOL
LSCLEAR,ALL                   !清空所有载荷
!NLGEOM,ON                    !打开大变形
NROPT,Full                    !激活完全Newton-Raphson
PRED,ON                       !打开变形预测
LNSRCH,ON                     !激活线性搜索   
ANTYPE,0                      !静态分析
AUTOTS,1                      !自动时间步长
NSUBST,20,60,1                !设置载荷步
OUTRES,ALL,ALL                !输出所有结果
EQSLV,PCG,1E-8                !采用pcg算法，对于大模型接触算法很有效
!*************************
!Define the displacement!
!*************************
nsel,s,loc,x,(0.5*L3-L1)
d,all,all
allsel
!*****************
!Define the loads!
!*****************
!sload,1,9,lock,forc,forc_bolt,1,2   !在螺栓中施加螺栓预紧
cmsel,s,cm_shangdaban_bufen
allsel,below,volu
asel,r,loc,z,0.04
sfa,all,1,pres,5.16e6
allsel
cmsel,s,cm_xiadaban_bufen
allsel,below,volu
asel,r,loc,z,0
sfa,all,1,pres,5.16e6
allsel
nsel,s,loc,x,(L2-0.5*L3)
f,all,FX,100
allsel
finish
/config,nproc,2                         !设置CPU数为2。
/solu
eqslv,amg                               !选择AMG算法
solve !求解

methos266

这个我找了有一段时间了吧， 也求教

C丫丫

我的经验是 在建立每个预紧单元前 要先选中那个单独的螺栓的单元。否则就有重复的应力截面。

adidas04

对于那个错误可以仔细检查你的边界条件