你可以参考下这个例子
FINISH
/FILNAME,Exercise10 ! 定义隐式热分析文件名
/PREP7 ! 进入前处理器
TIN=1000 ! 定义内圆环的内壁温度
TOUT=100 ! 定义外圆环的外壁温度
TOFF=0 ! 定义温度偏移量
STFCONST=5.67e-8 ! 定义斯蒂芬-波尔兹曼常数
ET,1,PLANE35 ! 选择三维热分析实体单元
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,200E9 ! 定义材料的弹性模量
MPDATA,PRXY,1,,0.3 ! 定义材料的泊松比
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,7.85e3 ! 定义材料密度
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,KXX,1,,66.6 ! 定义材料热传导系数
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,C,1,,460 ! 定义材料比热
CYL4,0,0,0.5,,1 ! 建立内圆环几何模型
CYL4,0,0,4, ,5 ! 建立外圆环几何模型
MSHAPE,1,2D
MSHKEY,0
SMRT,4 ! 设置网格智能划分精度
AMES,ALL ! 划分两圆环单元
LSEL,S,,,1,4 ! 选择内圆环外壁
LSEL,A,,,13,16 ! 选择外圆环内壁
SFL,ALL,RDSF,1, ,1, ! 施加热辐射率
LSEL,S,,,9,12 ! 选择外圆环外壁
DL,ALL, ,TEMP,TOUT,1 ! 施加外圆环温度载荷
LSEL,S,,,5,8 ! 选择内圆环内壁
DL,ALL, ,TEMP,TIN,1 ! 施加内圆环温度载荷
ASEL,S, , , 1
ESLA,S
CM,INSIDE,ELEM ! 建立内圆环单元组
ASEL,S, , , 2
ESLA,S
CM,OUTSIDE,ELEM ! 建立外圆环单元组
ALLSEL
FINI
/AUX12 ! 进入热辐射矩阵阵生成器
STEF,STFCONST ! 附于斯蒂芬-波尔兹曼常数
TOFFST,TOFF ! 定义温度偏移量
RADOPT,0.1,0.1,0.E+00,1000,0.1,0.1 ! 设置热辐射求解控制
SPCTEMP,1,0.E+00 ! 定义热辐射空间温度
VFCALC ! 计算热辐射形状系数
VFQUERY,INSIDE,INSIDE ! 查看内圆环对内圆环的形状系数
*GET,VFAVG1,RAD,,VFAVG ! 获取内圆环对内圆环的形状系数值
VFQUERY,OUTSIDE,INSIDE ! 查看外圆环对内圆环的形状系数
*GET,VFAVG2,RAD,,VFAVG ! 获取外圆环对内圆环的形状系数值
VFQUERY,OUTSIDE,OUTSIDE ! 查看外圆环对外圆环的形状系数
*GET,VFAVG3,RAD,,VFAVG ! 获取外圆环对内圆环的形状系数值
FINISH
/SOLU ! 进入求解器
TIME,1 ! 定义求解时间
DELTIM,0.5 ! 定义初始时间步
SOLVE ! 求解
FINI
/POST1 ! 进入通用后处理器
LSEL,S, , ,1,4
LSEL,A, , ,13,16
NSLL,S,1
*GET,TI,NODE,4,TEMP ! 获取4号节点温度
*GET,TO,NODE,13,TEMP ! 获取13号节点温度
*GET,HFI,NODE,4,TF,SUM ! 获取4号节点热流率
*GET,HFO,NODE,13,TF,SUM ! 获取13号节点热流率
HFIEXP=ABS((TO+TOFF)**4-(TI+TOFF)**4)*STFCONST/1 ! 4号节点热流率偏差
HFOEXP=ABS((TO+TOFF)**4-(TI+TOFF)**4)*STFCONST/4 ! 13号节点热流率偏差
HFIERR=(HFIEXP/HFI) ! 4号节点热流率误差
HFOERR=(HFOEXP/HFO) ! 13号节点热流率误差
*STATUS,PARM ! 列所有参数
SET,LIST ! 读取最后子步分析结果
PLNSOL,TEMP, ,0, ! 显示两圆环温度分布云图
PLVECT,TF, , , ,VECT,ELEM,ON,0 ! 显示两圆环热流率矢量分布图
FINISH
/EXIT,NOSAV ! 退出ANSYS |