【求救】为什么我的线接触不收敛？有代码

lfzhu

一个非常简单的两条并行的梁，中间定义了接触，老是不收敛。怎么回事？



FINISH  ! Make sure we are at BEGIN level   
/CLEAR,START  ! Clear model since no SAVE found   

/PREP7  

MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e9  
MPDATA,PRXY,1,,0.3  

!*  
ET,1,BEAM188
ET,2,BEAM188
ET,3,TARGE170   
ET,4,CONTA176   


R,4,0.1,0.08,0.001, 0,0,0


SECTYPE,   1, BEAM, RECT, sqare, 0  
SECOFFSET, CENT
SECDATA,0.1,0.15,0,0,0,0,0,0,0,0,0,0

SECTYPE,   2, BEAM, CTUBE, circle, 0
SECOFFSET, CENT
SECDATA,.1,.15,0,0,0,0,0,0,0,0,0,0  



K,1,0,1,0,  
K,2,0,1,1,  
K,3,0,1,0,  
K,4,0,1,1,  
LSTR,       1,       2  
LSTR,       3,       4  

LSEL,s , , ,       1
LATT,1,1,1, , , ,1  

LSEL,s , , ,       2
LATT,1,2,2, , , ,2  

alls
LESIZE,all, , ,10, , , , ,1
lmesh,all

eplot   


! Generate the target surface   
LSEL,S,,,1  

TYPE,4
real,4
mat,1
lsel,s,,,1
esll,s
nsle,s
ESURF   

TYPE,3  
lsel,s,,,2
esll,s
nsle,s
ESURF  


EPLOT   

finish
!======================================
/solu

ANTYPE,0
NLGEOM,1
NSUBST,10,1000,5
kbc,0

nsel,s,loc,z,1
d,all,all

esel,s,type,,2
nsle,s
nsel,r,loc,z,0
f,all,fx,-1


TIME,100

alls
solve

finish

/post1
pldisp

htbbzzg

1  求解前缺少一句：  allsel,all， 因此只有单元类型 2，其它单元没有参与求解；
2  接触设置中，需要增加对间隙和穿透的调整；
对你的命令流做了一些修改，见下面。你可以试试：

!*     
FINISH  ! Make sure we are at BEGIN level   
/CLEAR,START  ! Clear model since no SAVE found
/filn,contact_line&line
   
/PREP7  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e9  
MPDATA,PRXY,1,,0.3  
!*  
ET,1,BEAM188
ET,2,BEAM188
ET,3,TARGE170   
ET,4,CONTA176
R,4,0.1,0.08,0.001, 0,0,0
SECTYPE,   1, BEAM, RECT, sqare, 0  
SECOFFSET, CENT
SECDATA,0.1,0.15,0,0,0,0,0,0,0,0,0,0
SECTYPE,   2, BEAM, CTUBE, circle, 0
SECOFFSET, CENT
SECDATA,.1,.15,0,0,0,0,0,0,0,0,0,0
K,1,0,1,0,  
K,2,0,1,1,  
K,3,0.0,1,0,  
K,4,0.0,1,1,  
LSTR,       1,       2  
LSTR,       3,       4  
LSEL,s , , ,       1
LATT,1,1,1, , , ,1  
LSEL,s , , ,       2
LATT,1,2,2, , , ,2  
alls
LESIZE,all, , ,50, , , , ,1
lmesh,all
eplot
! Generate the target surface   
LSEL,S,,,1  
TYPE,4
real,4
mat,1
lsel,s,,,1
esll,s
nsle,s
ESURF   
TYPE,3  
lsel,s,,,2
esll,s
nsle,s
ESURF
! /COM, CONTACT PAIR PROPERTIES - START   以下修改接触设置  
MP,MU,1,0.2

RMODIF,4,7,
RMODIF,4,8,

KEYOPT,4,4,2
KEYOPT,4,5,3
KEYOPT,4,10,2   
! /COM, CONTACT PAIR PROPERTIES - END

EPLOT   
finish
!======================================
/solu
ANTYPE,0
NLGEOM,1
kbc,0
nsel,s,loc,z,1
d,all,all
esel,s,type,,2      !  此处选择了单元类型 2，后面需要加一句：  allsel,all
nsle,s
nsel,r,loc,z,0
f,all,fx,-1
!*  
allsel,all
!*  
CNVTOL,,-1,23   
CNVTOL,F, ,0.001,2,-0.1,
!*  
OUTRES,ERASE
OUTRES,ALL,ALL  
NCNV,2,0,0,0,0  
TIME,1  
!*  
AUTOTS,1
!*  
alls
NSUBST,1e4,1e8,5
!*
solve
finish
/post1
pldisp

love豆瓣

NSUBST,10,1000,5
调调？

lfzhu

谢谢。找出问题了
我应该定义pipe in pipe接触
R,4,-0.1,0.08,0.001, 0,0,0

狂拳之血

htbbzzg 发表于 2013-9-15 18:19
1  求解前缺少一句：  allsel,all， 因此只有单元类型 2，其它单元没有参与求解；
2  接触设置中，需要增加 ...

我也犯过这种错误，学习了！