请教各位 Kelvin（十四面体）模型建模如何实现

sunfield

各位大虾，毕业论文中要用到Kelvin（十四面体）模型，想知道如何建模，有没有建模小程序或是命令流啊，能不能分享！谢谢了。模型形如

julessy

论坛上刚好看到“关于voronoi多边形顶点坐标的问题”http://forum.simwe.com/thread-790219-1-1.html，不知对你有没有帮助

inkey

/CLEAR
/COM, Structural
/FILNAME,Modal,on
/TITLE, Modal analysis of a honeycomb sandwich panel.
/UNIT,SI

t=5.e-5                    !* 蜂窝芯厚度t=0.05mm，边长L，芯高H，蒙皮厚度b
L=5.e-4
H=1.e-3
b=1.5e-4

/PREP7  

et,1,shell91
et,2,shell91
r,1
rmodif,1,1,1                !* facesheet划分为1层
rmodif,1,13,1,0,b
r,2
rmodif,2,1,1                !* core划分为1层
rmodif,2,13,2,0,t

mp,ex,1,2.07e11            !* 镍基合金物性参数
mp,prxy,1,0.278
mp,dens,1,8414
mp,ex,2,4.95e9            !* 某合金物性参数   
mp,prxy,2,0.278
mp,dens,2,190.71

k,1,0,L/2.
k,2,0,1.5*L
k,3,sqrt(3.)*L/2.,2.*L   
k,4,sqrt(3.)*L,1.5*L
k,5,sqrt(3.)*L,L/2.
k,6,sqrt(3.)*L/2.
kgen,2,1,6,,,,H

*DO,i,1,5
l,i,i+1
*ENDDO
l,6,1
*DO,j,7,11
l,j,j+1
*ENDDO
l,12,7
*DO,k,1,6
l,k,k+6
*ENDDO
l,3,6
l,9,12

a,1,2,3,6
a,3,4,5,6
a,7,8,9,12
a,9,10,11,12

*DO,i,1,5
a,i,i+1,i+7,i+6
*ENDDO  
a,6,1,7,12
/REPLOT

*DO,i,1,4
asel,all
agen,2,all,,,2**(i-1)*sqrt(3)*L
*ENDDO
*DO,j,1,2
asel,all
agen,2,all,,,2**(j-1)*sqrt(3)*L/2,2**(j-1)*1.5*L
*ENDDO

                     !* 手动裁剪所需胞元使得板型为长方形

/RGB,index,100,100,100,0
/RGB,index,80,80,80,13
/RGB,index,60,60,60,14
/RGB,index,0,0,0,15

allsel
lsel,s,loc,z,0            !* facesheet网格布点
lsel,a,loc,z,H
lplot
lesize,all,,,2
asel,s,loc,z,0            !* 映射分网facesheet
asel,a,loc,z,H
type,1
real,1
mat,1
mshkey,1               
amesh,all
eplot
/IMAGE,save,mesh_facesheet,bmp

allsel
lsel,u,loc,z,0               !* core网格布点
lsel,u,loc,z,H
lplot
lesize,all,,,4               
asel,u,loc,z,0
asel,u,loc,z,H
type,2                       !* 映射分网core
real,2
mat,2
mshkey,1
amesh,all
allsel
eplot
/IMAGE,save,mesh_all,bmp
finish

/SOLU
antype,modal
modopt,lanb,10,0,10000,,off    !* 提取前10阶模态，并以质量矩阵正则化模态
eqslv,spar  
mxpand,10, , ,1
lumpm,0
pstres,0

!* 施加边条，一般为左侧简支或对称边条
!* lsel,s,line,,1,6
!* dl,all,,all,0
allsel
solve
finish

inkey

这个是论坛内的，你可以参考！