【寻找】如何在体网格划分后清除面网格。

sun_11

问题在 上面，请指教。

snakeli

using ETDELE command; The following is an example in ANSYS help;
  
/batch,list
/show,combp,grph]
/title, Comb Drive Example
/prep7
! dimensions (microns) / parameters
wf=2                   ! Fixed  finger width
wm=2                   ! Moving finger width
gg=2                   ! Gap
tt=40                  ! Moving length
t1=4                   ! Fixed finger backing
t2=tt                  ! Moving finger length
hh=10                  ! Height
dt=tt/2
V0=10
xx=(2*tt-dt)*2.75
y1=(wm/2)+gg
y2=(wm/2)+gg+wf
x1=tt+t1
! Create Model
cyl4,0,0,xx,0,,360,1
block,-tt,0,y1,y2,0,1
block,(-tt-t1),-tt,-y2,y2,0,1
block,-tt,0,-y1,-y2,0,1
block,-dt,(tt-dt),(-wm/2),(wm/2),0,1
block,(-dt-(gg/2)),(tt-dt+(gg/2)),((-wm/2)-(gg/2)),(wm/2)+(gg/2),0,1
dx=wm*1.1
dy=dx
block,-x1-dx,tt-ddt+dx,-y2-dy,y2+dy,0,1
vovlap,all
/com  ---------------------------------------
/com  Volume  Component
/com  ---------------------------------------
/com  2,8,9   Fixed Finger
/com   5      Moving Finger
/com   11     Air Layer around Moving Finger
/com   12     Air Layer around the Comb Drive
/com   10     Boundary
/com  ---------------------------------------
! 2D mesh
et,11,200,7              ! Use high order tri mesh element
esize,gg/2
mshap,1                  ! Force a traingle mesh
amesh,52                 ! Mesh air layer around moving finger
esize,gg
amesh,54                 ! Mesh air layer around comb drive
esize,(y2+dy)*5
amesh,50                 ! Mesh boundary
! 3D mesh
et,1,128
emunit,epzro,8.854e-6    ! Free space permittivity (uMKSV units)
mp,perx,1,1              ! Set relative permitivity to 1
mat,1
lsel,s,loc,z,.5  
lesize,all,,,1           ! Set element size in z-direction to 1
lsel,all
type,1
vsel,s,volu,,10,12,1
vsweep,all               ! Create wedge volume elements from tri mesh
vsel,all
vsel,s,volu,,10          ! Plot model
eslv,s
eplot
allsel
asel,s,loc,z,1           ! Select original areas
aclear,all         
etdele,11                ! Remove meshing elements  
asel,all
csys,1
nsel,s,loc,x,xx
d,all,VOLT,0             ! Apply volt=0 at outer boundary
nsel,all
csys,0
vsel,s,volu,,5
cm,MFINGER,volu
asel,s,ext
nsla,s,1
d,all,VOLT,0             ! Apply a zero potential on the moving finger
sf,all,mxwf
vsel,s,volu,,2
vsel,a,volu,,8,9,1
cm,FFINGER,volu
asel,s,ext
nsla,s,1
d,all,VOLT,V0            ! Apply 10 Volts on the fixed finger
allsel
! p-convergence control
pemopt,5.0,dual          ! Select Dual Method with tolerance of 5%
pconv,2,efor,x           ! Base convergence on Maxwell forces with tolerance of 2%
/gst,on
save                     
finish
/solu
eqslv,iccg               ! Set iccg solver  
solve                  
finish
/post1
set,last                 ! Set the last data step
vsel,s,volu,,11,12
eslv,s
pplot                    ! Plot the p-levels around the fingers
esel,all
plconv,all               ! Plot the convergence curve
etable,fx,fmag,x
etable,fy,fmag,y
etable,fz,fmag,z
ssum
*get,fx,ssum,,item,fx    ! Get summed forces
*get,fy,ssum,,item,fy
*get,fy,ssum,,item,fz
/com,Comb Drive Force
*stat,fx
finish

sun_11

谢谢啊
不过命令真是够长的，有的看来了

xiaoyu845200

体网格划分后为什么要清除面网格？

sunny平

运用命令：extopt,aclear,1就可以了