电子封装中的热-流体耦合模拟

guliuxinyong

题目：电子封装中的热-流体耦合模拟
出处：《ANSYS高级工程有限元分析范例精选》P300页 第14章
注释：小弟无意中看到这题，因为没学过CFD，感兴趣，就做来试试，发现书上印错几处，遂改正。特把改正后的命令流和结果奉上，大家一起进步。小弟还有问题若干，稍后提出，望众位大虾指点！！！

KEYW,PR_CFD,1
/UNITS,SI
/FILNAME,MCMCFD
/TITLE,2D THERMAL AND CFD SIMULATION OF MULTICHIP MODULE

*SET,D1_LENGTH,8E-3
*SET,D1_HEIGHT,0.65E-3

*SET,D2_LENGTH,5E-3
*SET,D2_HEIGHT,0.65E-3

*SET,BS1_RADIUS,0.15E-3
*SET,BS1_DIST,0.75E-3
*SET,BS1_NB,10
*SET,BS1_HEIGHT,0.2E-3
*SET,BS1_SIDE,0.625E-3

*SET,BS2_RADIUS,BS1_RADIUS
*SET,BS2_DIST,0.75E-3
*SET,BS2_NB,6
*SET,BS2_HEIGHT,0.2E-3
*SET,BS2_SIDE,0.625E-3

*SET,SUB_LENGTH,40E-3
*SET,SUB_HEIGHT,1.5E-3

*SET,BS3_RADIUS,0.3E-3
*SET,BS3_DIST,1.27E-3
*SET,BS3_NB,26
*SET,BS3_HEIGHT,0.4E-3
*SET,BS3_SIDE,4.125E-3

*SET,D_DIST,11.5E-3

*SET,PCB_LENGTH,100E-3
*SET,PCB_HEIGHT,1.5E-3

*SET,HS_LENGTH,40E-3
*SET,HS_THICK,1.5E-3

*SET,SA_HEIGHT,0.15E-3

*SET,TIM_HEIGHT,0.15E-3

*SET,COOL_LENGTH,60E-3
*SET,COOL_THICK,1E-3
*SET,COOL_HEIGHT,6E-3

*SET,IN_INNER,4E-3
*SET,IN_OUTER,6E-3
*SET,IN_DIST,4E-3
*SET,IN_HEIGHT,10E-3

*SET,OUT_INNER,4E-3
*SET,OUT_OUTER,6E-3
*SET,OUT_DIST,4E-3
*SET,OUT_HEIGHT,10E-3

/PREP7
ET,1,FLUID141
MP,KXX,1,0.613
MP,KXX,2,82
MP,KXX,3,36
MP,KXX,4,0.2
MP,KXX,5,50
MP,KXX,6,8.37
MP,KYY,6,0.32
MP,KXX,7,390
MP,KXX,8,1.1
MP,KXX,9,1
MP,KXX,10,240

CSYS,4

RECT,0,PCB_LENGTH/2,0,PCB_HEIGHT

WPOFF,BS3_DIST/2,PCB_HEIGHT+BS3_HEIGHT/2
PCIRC,BS3_RADIUS,,0,360
WPOFF,-BS3_DIST/2,BS3_HEIGHT/2

RECT,0,SUB_LENGTH/2,0,SUB_HEIGHT

AOVLAP,ALL
NUMCMP,ALL

ASEL,S,LOC,Y,0,SUB_HEIGHT
AADD,ALL

ASEL,S,LOC,Y,-(PCB_HEIGHT+BS3_HEIGHT),-BS3_HEIGHT
AADD,ALL

ASEL,ALL
AGLUE,ALL

ASEL,S,LOC,Y,-BS3_HEIGHT,0
AGEN,BS3_NB/2,ALL,,,BS3_DIST,,,,0

WPOFF,0,SUB_HEIGHT
WPOFF,BS1_DIST/2,BS1_HEIGHT/2
PCIRC,BS1_RADIUS,,0,360
WPOFF,-BS1_DIST/2,BS1_HEIGHT/2

RECT,0,D1_LENGTH/2,0,D1_HEIGHT
ASEL,S,LOC,Y,-(SUB_HEIGHT+BS1_HEIGHT),D1_HEIGHT
AOVLAP,ALL
ASEL,S,LOC,Y,-(SUB_HEIGHT+BS1_HEIGHT),-BS1_HEIGHT
AADD,ALL
ASEL,S,LOC,Y,0,D1_HEIGHT
AADD,ALL
ASEL,S,LOC,Y,-(SUB_HEIGHT+BS1_HEIGHT),D1_HEIGHT
AGLUE,ALL

ASEL,S,LOC,Y,-BS1_HEIGHT,0
AGEN,BS1_NB/2,ALL,,,BS1_DIST,,,,0

WPOFF,D_DIST-D2_LENGTH/2
RECT,0,D2_LENGTH,0,D2_HEIGHT

WPOFF,BS2_SIDE,-BS2_HEIGHT/2
PCIRC,BS2_RADIUS,,0,360
WPOFF,-BS2_SIDE,BS2_HEIGHT/2
ASEL,S,LOC,Y,-(SUB_HEIGHT+BS2_HEIGHT),D2_HEIGHT
ASEL,R,LOC,X,0,D2_LENGTH

AOVLAP,ALL
ASEL,S,LOC,Y,-(SUB_HEIGHT+BS2_HEIGHT),-BS2_HEIGHT
AADD,ALL

ASEL,S,LOC,Y,0,D1_HEIGHT
ASEL,R,LOC,X,0,D2_LENGTH
AADD,ALL

ASEL,S,LOC,Y,-(SUB_HEIGHT+BS2_HEIGHT),D2_HEIGHT
ASEL,R,LOC,X,0,D2_LENGTH
AGLUE,ALL

ASEL,S,LOC,Y,-BS2_HEIGHT,0
ASEL,R,LOC,X,0,D2_LENGTH
AGEN,BS2_NB,ALL,,,BS2_DIST,,,,0

WPOFF,O,D2_HEIGHT
RECT,0,D2_LENGTH,0,TIM_HEIGHT

WPOFF,-(D_DIST-D2_LENGTH/2)
RECT,0,D1_LENGTH/2,0,TIM_HEIGHT

WPOFF,O,TIM_HEIGHT
RECT,0,HS_LENGTH/2,0,HS_THICK
*SET,HS_HEIGHT,TIM_HEIGHT+D1_HEIGHT+BS1_HEIGHT-SA_HEIGHT

RECT,SUB_LENGTH/2-HS_THICK,SUB_LENGTH/2,0,-HS_HEIGHT
RECT,SUB_LENGTH/2-HS_THICK,SUB_LENGTH/2,-(HS_HEIGHT+SA_HEIGHT),-HS_HEIGHT

ALLSEL,ALL
ARSYM,X,ALL

WPOFF,O,HS_THICK
RECT,-HS_LENGTH/2,HS_LENGTH/2,0,TIM_HEIGHT

WPOFF,O,TIM_HEIGHT
RECT,-COOL_LENGTH/2,COOL_LENGTH/2,0,COOL_HEIGHT+COOL_THICK*2

WPOFF,O,COOL_THICK
RECT,-COOL_LENGTH/2+COOL_THICK,COOL_LENGTH/2-COOL_THICK,0,COOL_HEIGHT

WPOFF,COOL_LENGTH/2-IN_DIST,COOL_HEIGHT+COOL_THICK
RECT,-IN_OUTER/2,IN_OUTER/2,-COOL_THICK,IN_HEIGHT
RECT,-IN_INNER/2,IN_INNER/2,-COOL_THICK,IN_HEIGHT

WPOFF,IN_DIST-COOL_LENGTH+OUT_DIST
RECT,-OUT_OUTER/2,OUT_OUTER/2,-COOL_THICK,OUT_HEIGHT
RECT,-OUT_INNER/2,OUT_INNER/2,-COOL_THICK,OUT_HEIGHT

ASEL,S,LOC,Y,-COOL_HEIGHT+COOL_THICK*2,IN_HEIGHT
AOVLAP,ALL

ALLSEL,ALL
NUMCMP,ALL

ASEL,S,,,72
ASEL,A,,,73
ASEL,A,,,76
ASEL,A,,,80
ASEL,A,,,81
AADD,all

ASEL,s,,,74
ASEL,A,,,75
ASEL,A,,,77
ASEL,A,,,78
ASEL,A,,,79
AADD,ALL

ASEL,S,,,68
ASEL,A,,,69
ASEL,A,,,70
ASEL,A,,,71
ASEL,A,,,82
AADD,ALL

ASEL,ALL
AGLUE,ALL
NUMCMP,ALL

CSYS,0
WPAVE,0,0,0
CSYS,4

ASEL,S,LOC,Y,0,PCB_HEIGHT
AATT,6,,1,0

ASEL,S,LOC,Y,PCB_HEIGHT,PCB_HEIGHT+BS3_HEIGHT
AATT,5,,1,0

ASEL,S,LOC,Y,PCB_HEIGHT+BS3_HEIGHT,PCB_HEIGHT+BS3_HEIGHT+SUB_HEIGHT
AATT,4,,1,0

WPOFF,0,PCB_HEIGHT+BS3_HEIGHT+SUB_HEIGHT
ASEL,S,LOC,Y,0,BS1_HEIGHT
ASEL,R,LOC,X,-SUB_LENGTH/2+HS_THICK,SUB_LENGTH/2-HS_THICK
AATT,3,,1,0

ASEL,S,LOC,Y,0,SA_HEIGHT
ASEL,R,LOC,X,-SUB_LENGTH/2,-SUB_LENGTH/2+HS_THICK
AATT,8,,1,0

ASEL,S,LOC,Y,0,SA_HEIGHT
ASEL,R,LOC,X,SUB_LENGTH/2-HS_THICK,SUB_LENGTH/2
AATT,8,,1,0

ASEL,S,LOC,Y,BS1_HEIGHT,BS1_HEIGHT+D1_HEIGHT
ASEL,R,LOC,X,-SUB_LENGTH/2+HS_THICK,SUB_LENGTH/2-HS_THICK
AATT,2,,1,0

WPOFF,0,BS1_HEIGHT+D1_HEIGHT+TIM_HEIGHT
ASEL,S,LOC,Y,-TIM_HEIGHT,0
ASEL,R,LOC,X,-SUB_LENGTH/2+HS_THICK,SUB_LENGTH/2-HS_THICK
AATT,9,,1,0

ASEL,S,LOC,Y,-HS_HEIGHT,0
ASEL,R,LOC,X,-SUB_LENGTH/2,-SUB_LENGTH/2+HS_THICK
AATT,7,,1,0

ASEL,S,LOC,Y,-HS_HEIGHT,0
ASEL,R,LOC,X,SUB_LENGTH/2-HS_THICK,SUB_LENGTH/2
AATT,7,,1,0

ASEL,S,LOC,Y,0,HS_THICK
AATT,7,,1,0

ASEL,S,LOC,Y,HS_THICK,HS_THICK+TIM_HEIGHT
AATT,9,,1,0

ASEL,S,,,53
ASEL,A,,,66
AATT,10,,1,0

ASEL,S,,,54
AATT,1,,1,0

ASEL,ALL
/PNUM,AREA,1
/PNUM,MAT,1
/NUMBER,1

CSYS,0
WPAVE,0,0,0
CSYS,4

SMRT,6
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
FINISH

/SOLU
ASEL,S,,,62
ASEL,A,,,63
BFA,ALL,HGEN,360.6e6
ASEL,S,,,64
ASEL,A,,,65
BFA,ALL,HGEN,369.2e6
LSEL,S,,,329
DL,ALL,,VY,-1
DL,ALL,,TEMP,15
LSEL,S,,,331
DL,ALL,,PRES,0
LSEL,S,,,1,2
LSEL,A,,,4
LSEL,A,,,163,168,5
LSEL,A,,,194
LSEL,A,,,319
LSEL,A,,,323,324
LSEL,A,,,343,346,3
LSEL,A,,,353,363,2
LSEL,A,,,364,365
LSEL,A,,,367
LSEL,A,,,373,375,2
LSEL,A,,,404,406
LSEL,A,,,419,421,2
SFL,ALL,CONV,10,,25

ALLSEL,ALL
FLDATA1,SOLU,FLOW,1
FLDATA1,SOLU,TEMP,1
FLDATA1,SOLU,TURB,1

FLDATA2,ITER,EXEC,100

FLDATA7,PROT,DENS,CONSTANT
FLDATA8,NOMI,DENS,997

FLDATA7,PROT,VISC,CONSTANT
FLDATA8,NOMI,VISC,8.55E-4

FLDATA7,PROT,COND,CONSTANT
FLDATA8,NOMI,COND,0.613

FLDATA7,PROT,SPHT,CONSTANT
FLDATA8,NOMI,SPHT,4179

FLDATA24,TURB,MODL,2
FLDATA24,TURB,RATI,2

FLDATA18,METH,TEMP,4

SOLVE

FINISH
/POST1
SET,LAST
PLNSOL,TEMP,,0
PLVECT,V,,,,VECT,ELEM,ON,0
FINISH

guliuxinyong

下面是温度图

guliuxinyong

下面是速度图

guliuxinyong

小弟的问题很菜的。：）
该例子只设了一个fluid单元，且把封装中的散热元件都aatt成fluid单元了。
这样行吗？小弟不解
我请教过一位仁兄，也觉不妥。
望众位斑竹、众家兄弟指教！
小弟打以上那些命令也很辛苦的，狂谢！！！

guliuxinyong

晕，命令流有个量定义为S B，可论坛显示不了，显示***
我改个别的词吧！！！

gxx917

我觉得这里是选用了一种单元，但是是十种不同的材料，所以要设置各种材料的导热系数！！

zhaodaibin

如果都是一个单元，那么固体的热学性能不是和流体一样了？
求出来肯定不对的！
期待正解！

gxx917

这例子中流体温度不是恒温，而且设置材料号1是为了表明是流体单元属性，但是我不明白的是：为什么温度15度施加在所有的边上,这样不是温度就不会变化了吗?不太明白!

zhaodaibin

我把这个例子的求解改成瞬态后，老是出现材料2的错误！
怎么会事？？

gxx917

恳请高手予以解答！谢谢！！

tyler

guliuxinyong wrote:
小弟的问题很菜的。：）
该例子只设了一个fluid单元，且把封装中的散热元件都aatt成fluid单元了。
这样行吗？小弟不解
我请教过一位仁兄，也觉不妥。
望众位斑竹、众家兄弟指教！
小弟打以上那些命令也很辛苦的，狂谢！！！

1.fluid141,142单元可以同时解决流体与固体网格划分（可以参照帮助文件），所以这个没有问题。

tyler

zhaodaibin wrote:
如果都是一个单元，那么固体的热学性能不是和流体一样了？
求出来肯定不对的！
期待正解！

是由区分的，只有材料编号为1的物体才为流体，其余的都默认为固体；

tyler

gxx917 wrote:
这例子中流体温度不是恒温，而且设置材料号1是为了表明是流体单元属性，但是我不明白的是：为什么温度15度施加在所有的边上,这样不是温度就不会变化了吗?不太明白!

15度只是入口流体的温度，并不是指所有的边上。

gxx917

我做了一遍发现温度是加在所有的边上了！这样稳态流场计算出来的温度分布，是最终的温度分布吗？请教楼上！！

heusxg

发现一个论坛，专门作封装模拟的，有兴趣的不妨进来看看

http://www.iccae.com