申请加精
这个例子很经典
其中用到宏rf enforce 等 见附件
! 直接法
! 岩土力学模式
! 求解围岩特征曲线
finish
/clear
toolbar
/title,Excavation of tunnel
r=5
r1=2*r
a=10*r
b=6*r
c=3*r
/PREP7
/PNUM,KP,1
! 生成关键点
k,1,0,0
k,2,r,0
k,3,0,r
k,4,r1,0
k,5,0,r1
k,6,c,0
k,7,0,c
k,8,c,c
k,9,a,0
k,10,0,b
k,11,c,b
k,12,a,b
k,13,a,c
! 生成线
/PNUM,KP,0
/PNUM,LINE,1
l,1,2
larc,2,3,1,r
l,3,1
l,2,4
larc,4,5,1,r1
l,5,3
l,4,6
l,6,8
l,7,8
l,5,7
l,7,10
l,10,11
l,8,11
l,11,12
l,12,13
l,8,13
l,9,13
l,6,9
LPLOT
! 生成面
/PNUM,LINE,0
/PNUM,AREA,1
al,1,2,3
al,2,4,5,6
al,5,7,8,9,10
al,9,11,12,13
al,13,14,15,16
al,8,16,17,18
! 镜像
asel,all
arsym,x,all
asel,all
arsym,y,all
APLOT
! 改变第二、四象限衬砌圆弧段的法线方向
csys,1
lsel,s,loc,y,90,180
lsel,a,loc,y,270,360
lsel,r,loc,x,r
LREVERSE,all,0
csys,0
! 合并重合的关键点和线并压缩编号
NUMMRG,ALL
NUMCMP,ALL
! 定义衬砌单元
ET,1,BEAM3
mp,ex,1,3e10 ! 设置弹性模量ex
mp,prxy,1,0.2 ! 设置泊松比
mp,dens,1,2500 ! 设置密度
d=0.3
r,1,d,d*d*d/12,d ! 设置实常数
! 定义围岩单元
ET,2,PLANE42
KEYOPT,2,3,2 ! 平面应变
mp,ex,2,6e8 ! 设置弹性模量ex
mp,prxy,2,0.38 ! 设置泊松比
mp,dens,2,1900 ! 设置密度
TBDE,DP,2
TB,DP,2,,,0
TBMODIF,1,1,80000
TBMODIF,1,2,27
! 划分网格
type,1
real,1
mat,1
MSHAPE,0,2D
MSHKEY,1
! 划分衬砌单元
csys,1
lsel,s,loc,x,r
lesize,all,,,10
lmesh,all
csys,0
allsel,all
type,2
real,2
mat,2
! 划分内圆网格
csys,1
asel,s,loc,x,0,r
amesh,all
allsel,all
! 划分圆环网格
asel,s,loc,x,r,r1
amesh,all
csys,0
allsel,all
/PNUM,KP,1
/PNUM,LINE,1
/PNUM,AREA,1
! 划分五边形网格
AMAP,3,4,6,7,5
AMAP,9,5,7,17,15
AMAP,21,15,17,24,23
AMAP,15,23,24,6,4
! 划分左右两边的中间部分网格
lsel,s,loc,x,-a,a
lsel,u,loc,x,-c,c
lsel,u,loc,x,-a
lsel,u,loc,x,a
lsel,r,loc,y,-c,c
n1=nint(5*distkp(6,9)/distkp(6,8))
lesize,all,,,n1
asel,s,loc,x,-a,a
asel,u,loc,x,-c,c
asel,r,loc,y,-c,c
amesh,all
n1=
! 划分上下两边的中间部分网格
lsel,s,loc,y,-b,b
lsel,u,loc,y,-c,c
lsel,u,loc,y,-b
lsel,u,loc,y,b
lsel,r,loc,x,-c,c
n2=nint(5*distkp(7,10)/distkp(7,8))
lesize,all,,,n2
asel,s,loc,y,-b,b
asel,u,loc,y,-c,c
asel,r,loc,x,-c,c
amesh,all
n2=
asel,all
! 划分剩余部分网格
asel,u,loc,x,-c,c
asel,u,loc,y,-c,c
aplot
amesh,all
allsel,all
! 合并重合的关键点和线并压缩编号
NUMMRG,ALL
NUMCMP,ALL
finish
/solu
ALLSEL,ALL
ANTYPE,0
NLGEOM,1 ! 打开大变形
TIME,1 ! 为载荷步设置时间
NSUBST,10,0.2,0.01 ! 指定载荷步中所需要的子步数
NROPT,FULL, ,ON ! 在静态或完全瞬态分析中,指定Newton-Raphson选项
!LUMPM,1 ! 指定一个集中质量矩阵公式
! 施加约束
nsel,all
nsel,s,loc,x,-a
nsel,a,loc,x,a
d,all,ux,0
nsel,all
nsel,s,loc,y,-b
d,all,uy,0
! 加载
! 施加重力
ALLSEL,ALL
ACEL,0,10,0,
! 杀死梁单元
ESEL,S,TYPE,,1
ekill,all
! 求解
allsel,all
solve
finish
/POST1
allsel,all
! 读出数据
SET,LAST
! 画变形云图
PLDISP,1
! 读取等效节点力
csys,1
APLOT
csys,1
ASEL,R,LOC,X,r,r1
APLOT
ESLA,S
EPLOT
LSEL,R,LOC,X,r
LPLOT
NSLL,R,1
NPLOT
rf
csys,0
finish
/SOLU
ALLSEL,ALL
ANTYPE,,REST,1,6,0
NLGEOM,1 ! 打开大变形
TIME,2 ! 为载荷步设置时间
NSUBST,10,0.2,0.01 ! 指定载荷步中所需要的子步数
NROPT,FULL, ,ON ! 在静态或完全瞬态分析中,指定Newton-Raphson选项
!LUMPM,1 ! 指定一个集中质量矩阵公式
! 杀死梁单元
ALLSEL,ALL
ESEL,S,TYPE,,1
ekill,all
! 杀死衬砌内的围岩单元
csys,1
ALLSEL,ALL
ASEL,S,loc,x,0,r
ESLA,R
ekill,all
csys,0
allsel,all
! 施加等效节点力
*ask,Factor,'Please input factor : factor=',0 ! 提示用户输入释放力系数,缺省值为0
enforce,Factor
! 求解
allsel,all
solve
finish
/POST1
allsel,all
! 读出数据
SET,LAST
! 画变形结果图
PLDISP,1
finish
/SOLU
ALLSEL,ALL
ANTYPE,,REST,2,6,0
NLGEOM,1 ! 打开大变形
TIME,3 ! 为载荷步设置时间
NSUBST,10,0.2,0.01 ! 指定载荷步中所需要的子步数
NROPT,FULL, ,ON ! 在静态或完全瞬态分析中,指定Newton-Raphson选项
!LUMPM,1 ! 指定一个集中质量矩阵公式
! 激活梁单元
ALLSEL,ALL
ESEL,S,TYPE,,1
ealive,all
! 杀死衬砌内的围岩单元
csys,1
ALLSEL,ALL
ASEL,S,loc,x,0,r
ESLA,R
ekill,all
csys,0
allsel,all
! 除去等效节点力
enforce,1
! 求解
allsel,all
solve
finish
/POST1
allsel,all
! 读出数据
SET,LAST
! 画变形结果图
PLDISP,1
! 建立单元表
ETABLE,NI,SMISC,1 !单元I点轴力
ETABLE,NJ,SMISC,7 !单元J点轴力
ETABLE,MI,SMISC,6 !单元I点弯矩
ETABLE,MJ,SMISC,12 !单元J点弯矩
! 更新单元表
ETABLE,REFL
! 画轴力分布图
/TITLE,Axial force diagram
PLLS,NI,NJ,0.1,0
! 画弯矩分布图
/TITLE,Bending moment diagram
PLLS,MI,MJ,-0.1,0
finish |