考虑自重的屈曲分析

pfsr

ansys屈曲分析给出的结果是一些系数，无论施加的是恒载还是变载。在考虑自重的前提下，必须确认由恒载产生的应力刚度矩阵不受结果系数的影响。也就是说，系数是1或接近1。一种可行的方法就是反复调整施加的变载值直至最后得到的系数满足要求。我现在正在学习APDL, 就以此做一个小练习。一个杆，底端固支，考虑自重，算轴向屈曲压力。欢迎拍砖。

finish
/clear

/PREP7
/TITLE, BUCKLING OF A BAR WITH CONSIDERING SELF WEIGHT
ET,1,BEAM3                         ! Beam element
R,1,10,10000/12,10                 ! Area,IZZ, height, unit mm
MP,EX,1,2.01E+5                    ! Define material properties
MP,PRXY,1,0.3
MP,DENS,1,7.85E-6
N,1
N,11,,100
FILL
E,1,2
EGEN,10,1,1
FINISH

flag=1
count=1
bload=1                            ! Initial buckling load
ntol=20                            ! Maximum iterations
*dowhile,flag

/SOLU
ANTYPE,STATIC                      ! Static analysis
PSTRES,ON                          ! Calculate prestress effects
acel,0,9.810,0                     ! Consider self weight
D,1,ALL                            ! Fix one end
F,11,FY,-bload                     ! Load at free end

SOLVE
FINISH

/SOLU
ANTYPE,BUCKLE                      ! Buckling analysis
BUCOPT,LANB,1                      ! Use Block Lanczos solution method, extract 1 mode
MXPAND,1                           ! Expand 1 mode shape
SOLVE
FINISH

/POST1
SET,FIRST
*get,lfactor,active,0,set,freq     ! Get load factor
norm=abs(lfactor-1)                ! Define error norm
*if,norm,le,0.01,then              ! Control if error norm within tolerance
flag=-1                            ! Exit loop if satisfied
*else
bload=bload*lfactor                ! Otherwise define a new buckling load
*endif

count=count+1
*if,count,eq,ntol,then
flag=-1                            ! Exit loop after ntol iterations
*endif

*enddo

*msg,ui,count,bload,lfactor
After %I iterations, %/&
Buckling load :%15.4F %/&
load factor :%15.4F

烟雨中国

路过，顶啊

xsdcaifu

好东西，正好用到，谢谢了

aj2000

不错不错，循环写的挺好，比较实用，不仅适用于自重情形，道理也适用于预应力

healton

循环不错，写得很有水准！！

YW3624021

真是好东西，谢谢分享

tyzjt

谢谢分享

pavon

不错！试一下！

koalabear

为什么我执行不了呢？