中间加的一个小分析项目

jack_qym

模型的建立给大家参考，能用就用。

FINISH
/CLEAR,START

/PREP7
!****************** Define Parameter**********
*ABSET,'Define Parameter Status Bar',BAR
*SET,J,10
*ABCHECK,J
*SET,SHELL_P,0.4
*SET,PIPE_P,0.6
*SET,Corrupt,0
*SET,unitcircle,1
!Shell Size
*SET,SH_RDI,1.2
*SET,SH_DI,SH_RDI-2*Corrupt
*SET,SH_DL,0.5
*SET,SH_RDta,0.014
*SET,SH_Dta,SH_RDta-Corrupt
*SET,SH_DO,SH_RDI+2*SH_Dta
!Head Size
*SET,J,30
*ABCHECK,J
*SET,HEAD_RDI,1.2
*SET,HEAD_DI,HEAD_RDI-2*Corrupt
*SET,HEAD_DH1,HEAD_DI/4
*SET,HEAD_DH2,0.04
*SET,HEAD_RDTA,0.014
*SET,HEAD_DTA,HEAD_RDTA-Corrupt
!Pipe Size
*SET,J,50
*ABCHECK,J
*SET,POS_X1,0.25
*SET,POS_Y1,0
*SET,POS_ANG1,0
*SET,PIPE_DO1,0.189
*SET,PIPE_RDTA1,0.0045
*SET,PIPE_DTA1,PIPE_RDTA1-Corrupt
*SET,PIPE_DI1,PIPE_DO1-2*PIPE_DTA1
*SET,PIPE_OUTLET1,0.2
*SET,J,70
*ABCHECK,J
*SET,POS_X2,0.3
*SET,POS_Y2,0
*SET,POS_ANG2,45
*SET,PIPE_DO2,0.089
*SET,PIPE_RDTA2,0.007
*SET,PIPE_DTA2,PIPE_RDTA1-Corrupt
*SET,PIPE_DI2,PIPE_DO2-2*PIPE_DTA2
*SET,PIPE_OUTLET2,0.2
*SET,J,100
*ABCHECK,J
*ABFINIFH

!****************** Create Model *************

!Define Element And Material
ET,1,SOLID185
MP,EX,1,2e11
MP,NUXY,1,0.3

/TITLE,Create Modeling
K,1000,,,,
KWPAVE,1000   
CIRCLE,1000,unitcircle
CSYS,4
LSEL,S,LOC,X,-unitcircle,0
LSEL,R,LOC,Y,0,unitcircle
CM,LEFT_LINE,LINE
CMSEL,A,LEFT_LINE
LSSCALE,LEFT_LINE, , ,HEAD_DH1,HEAD_DI/2,1, ,0,0
LSSCALE,LEFT_LINE, , ,HEAD_DH1+HEAD_DTA,HEAD_DI/2+HEAD_DTA,1, ,0,0
CMDELE,LEFT_LINE
LSEL,ALL
CSYS,1  
LSEL,S,LOC,X,unitcircle
LDELE,ALL, , ,1
LSEL,ALL
CSYS,0
KSEL,S,LOC,X,0
KSEL,R,LOC,Y,HEAD_DI/2,HEAD_DI/2+HEAD_DTA
*GET,KEY_TEMP1, KP, 0, NUM,MAX
*GET,KEY_TEMP2, KP, 0, NUM,MIN
L,KEY_TEMP1,KEY_TEMP2
ALLSEL,ALL
KSEL,S,LOC,Y,0
KSEL,R,LOC,X,-HEAD_DH1,-HEAD_DH1-HEAD_DTA
*GET,KEY_TEMP1, KP, 0, NUM,MAX
*GET,KEY_TEMP2, KP, 0, NUM,MIN
L,KEY_TEMP1,KEY_TEMP2
AL,ALL
ALLSEL,ALL
RECTNG,0,SH_DL+HEAD_DH2,SH_DI/2,SH_DI/2+SH_Dta,
AADD,ALL
K,1001,SH_DL,,,
VROTAT,ALL, , , , , ,1000,1001,-90, ,
!VSYMM,Y,ALL, , , ,0,0   ! Reflect The Volume
wpro,,-90,
wpoff,POS_X1
CYLIND,PIPE_DO1,PIPE_DI1,0,SH_DO/2+PIPE_OUTLET1,0,180,
VOVLAP,ALL
*SET,TEMP,sqrt((SH_DI/2)**2-(PIPE_DO1/2)**2)
CSYS,4  
wpstyle,,,,,,1,,,
VSEL,S,LOC,X,0,PIPE_DO1/2
VSEL,R,LOC,Z,0,TEMP
VDELE,ALL, , ,1
CSYS,4  
wpstyle,,,,,,1,,,   
VSEL,S,LOC,X,0,PIPE_DO1/2
ASLV,R  
LSLA,R
LSEL,R,LOC,X,0,PIPE_DO1/4
ASLL,S
VSLA,S
VDELE,ALL, , ,1
ALLSEL,ALL
wpstyl,defa
*IF,PIPE_DI2,GT, 0, THEN
wpro,,-90,
wpoff,POS_X2
wpro,,-POS_ANG2,
CYLIND,PIPE_DO2,PIPE_DI2,0,SH_DO/2+PIPE_OUTLET1,0,360,
VOVLAP,ALL
*SET,TEMP,sqrt((SH_DI/2)**2-(PIPE_DO2/2)**2)
CSYS,4
wpstyle,,,,,,1,,,
VSEL,S,LOC,X,0,PIPE_DO2/2
VSEL,R,LOC,Z,0,TEMP
VDELE,ALL, , ,1
ALLSEL,ALL
wpstyl,defa
wpro,,-90,
wpoff,POS_X2
wpro,,-POS_ANG2,
CSYS,4
wpstyle,,,,,,1,,,
VSEL,S,LOC,X,0,PIPE_DO2/2
wpro,,-90,
VSBW,ALL
wpro,,90,
ASLV,R  
LSLA,R
LSEL,R,LOC,X,0,PIPE_DO2/4
ASLL,S
VSLA,S
VDELE,ALL, , ,1
ALLSEL,ALL
WPSTYL,DEFA
*ENDIF
vplot
/replot

kingbird0110

什么不给出网格划分模型呢

jinqinghai

原帖由 kingbird0110 于 2006-8-24 00:07 发表
什么不给出网格划分模型呢

自由网格省事一点，

jack_qym

何必呢，用工作面切割几次就可以了。
觉得挺简单的，Mesh的方式很多。
每个人的处理方式不同，看你的应用。

xiao9136

说实话，对于刚学的人来说，其实应该分段来表示，
比如哪段程序表示的是干什么的
这样才直观一点。

当然这只是我个人的意见，主要自己还在用GUI操作
实在是菜