高桩墩台式码头门机移动荷载核算（申请加精）

workforbetter

finish
/clear,start
/title, Part 1-3 of Tianjin Port
/filname,model1-3-5
/prep7
et,1,beam188  !桩单元
et,2,beam188  !门机梁单元
et,3,solid45  ! 承台和敦台

!****定义材料
!混凝土材料
mp,ex,1,3.0e10
mp,prxy,1,0.16667
mp,dens,1,2.451e3
!***定义截面
!桩
sectype,1,beam,rect,pile
secoffset,cent
secdata,0.55,0.50,5,5
!门机梁
sectype,2,beam,rect,mjl
secoffset,user,0,-1.64/2
!secoffset,cent
secdata,0.6,1.64,6,16
!************************************************** 桩建模
!****定义参数
tl=-0.6      !桩顶标高 top level
bl=-22.0     !桩底标高 bottom level
pl=tl-bl     !桩长
*afun,deg
b=atan2(1,5)      !与y轴夹角
a=90-b             !与x轴夹角
c=atan2(1,2)       !与Z轴夹角
!*****************************桩基
!***前排直桩1
k,1,0,0,tl
k,2,0,0,bl
!***前排叉桩
k,3,0,1.7,tl
k,4,-pl*tan(c)*cos(a),1.7-pl*tan(c)*cos(b),bl
k,5,0,3.4,tl
k,6,-pl*tan(c)*cos(a),3.4-pl*tan(c)*cos(b),bl
k,7,0,5.1,tl
k,8,-pl*tan(c)*cos(a),5.1-pl*tan(c)*cos(b),bl
!***前排直桩2
k,9,0,6.6,tl
k,10,0,6.6,bl
!***后排叉桩
k,11,0,8.1,tl
k,12,-pl*tan(c)*cos(a),8.1+pl*tan(c)*cos(b),bl
k,13,0,9.8,tl
k,14,-pl*tan(c)*cos(a),9.8+pl*tan(c)*cos(b),bl
!***后排直桩
k,15,0,11.5,tl
k,16,0,11.5,bl
k,17,0,13.2,tl
k,18,0,13.2,bl
!***生成排架
*dO,i,1,18,2
l,i,i+1
*enddo
wpoffs,0.8    !设置镜像对称轴
csys,4      !激活坐标系为WP
lsymm,x,all, , , ,1,0   
csys,0
wpcsys,-1,0
cm,pj,line


!****生成承台和墩台
BLOCK,-0.8,2.4,-1.1,14.3,-1.6,0.8
BLOCK,0.05,1.55,-1.1,15.3,0.8,3.95
wpoffs,,14.3
wpoffs,,,0.8
wprota,,45
vsel,s,loc,z,0.8,3.95
vsbw,all

vsel,s,loc,z,0.8,1.6
vdele,all,,,1
allsel,all
vglue,all
wpcsys,-1,0
wpstyle,,,,,,,,0   !不显示工作平面
allsel,all
!生成排架 ,不同部分分开复制，不要划分网格之后再复制，因为不同部分R，mat和type不一样   
cmsel,s,pj
lgen,4,all,,,10.5   !排架间距10.5m
cm,zj,line
allsel,all
vsel,s,loc,z,-1.6,3.95
vgen,4,all,,,10.5
cm,ct,volu
allsel,all
生成门机梁，简支结构
k,,0.8+0.2,1.4,3.95   
k,,10.5+0.8-0.2,1.4,3.95   !门机梁端头有0.4 孔隙接头
k,,0.8+0.2,1.4+10.5,3.95   
k,,10.5+0.8-0.2,1.4+10.5,3.95   !门机梁端头有0.4 孔隙接头
l,217,218
l,219,220
lsel,s,loc,z,3.95
lsel,r,loc,x,0.8+0.2,10.5+0.8-0.2
lsel,r,loc,y,1.4,1.4+10.5
lsel,u,loc,x,1.55
lsel,u,loc,x,10.55
lgen,3,all,,,10.5
cm,mjl,line
allsel,all
!***********************网格划分
!***桩
cmsel,s,zj
LATT,1,,1, , , ,1  
ESYS,0   
lesize,all,0.2
lmesh,all
allsel,all
!***承台和墩台
cmsel,s,ct
vatt,1,,3
ESYS,0   
esize,0.3
vsweep,all
allsel,all
!***门机梁
cmsel,s,mjl
LATT,1,,2, , , ,2  
ESYS,0   
lesize,all,0.2
lmesh,all
allsel,all
/eshape,0 查看形状
numcmp,all

!******************施加约束
/solu
!***约束桩
cmsel,s,zj
nsll,s
nsel,r,loc,z,-15,bl
nplot
d,all,all
allsel,all
!****耦合节点
!桩与承台
!网格密度大的选择为节点，必须为交叉的节点
esel,s,type,,1   
nsel,all
nsle,r
nsel,u,loc,z,bl,-1.6
nplot
d,all,rotx,,,,,roty,rotz
!网格密度小的选择为单元
esel,s,type,,3               
eplot
ceintf,0.2, , , , , , ,0,     ! 交叉部分的节点被约束
alls
!门机梁与承台
!网格密度大的选择为节点
esel,s,type,,2   
nsel,all
nsle,r
nsel,u,loc,x,1.55+0.01,10.55-0.01   !0.01为容差
nsel,u,loc,x,12.05+0.01,21.05-0.01
nsel,u,loc,x,22.55+0.01,31.55-0.01   
nplot
d,all,,,,,,rotx,rotz     ! 否则自由度不足
!网格密度小的选择为单元
esel,s,type,,3               
eplot
ceintf,0.2, , , , , , ,0,     ! 交叉部分的节点被约束
alls


!*************************************施加荷载
/solu
!****自重
acel,,,9.8*1.2
!***面板自重以均载的方式施加到承台上
asel,s,loc,z,3.95
aplot
nsla,s
sf,all,pres,(0.85*24.5*0.5654+0.7*18)*1000   !空心面板+面层自重 ,一定要看图形，力的方向,单位是N/平米
alls

!***************两个支腿移动
!(1)参数输入
!轮压参数
*afun,rad
P=1350000   !最大腿压
L1=4.16     !分布长度
!循环参数
XLOC=1         !门机起始位置
XLOCmax=32.1   !门机梁边界
STEP=1         !步长，门机移动距离
Dmin=2
TOL=0.01   !容差
!(2)施加门机荷载
/solu
*do,i,1,50,1
cmsel,s,mjl
lplot
nsll,s
nsel,u,loc,x,0,XLOC-TOL
nsel,u,loc,x,XLOC+L1+TOL,XLOC+L1+Dmin-TOL
nsel,u,loc,x,XLOC+L1+Dmin+L1+TOL,1000000       !  超过10000000000 就选NONE了
nplot
*get,nodenum,node,,count
f,all,fz,-P*4*1.5/nodenum   !按照影响区域加荷载
allsel,all
lswrite,i                   !一定要写在荷载删除之前
fdele,all,all
XLOC=XLOC+STEP
*if,XLOC+L1+Dmin+L1,GT,XLOCmax,then
*exit
*endif
*enddo
alls
lssolve,1,i
!******************************查看结果
!（1）看整体变形
/post1
alls
pldisp,1

!（2）看动态变化，确定最大内力时的荷载步：看位移和弯矩动态变化图                                 
!跨中点
/post1
*set,nodenum1,node(6.05+10.5,1.4,3.95)       !提取坐标为(6.05,1.4,3.95)的节点号赋值给nodenum
nsel,s,node,,nodenum1
/pnum,node,1
nplot


!端点
/post1
*set,nodenum2,node(11.3,1.4,3.95)       !提取坐标为(6.05,1.4,3.95)的节点号赋值给nodenum
nsel,s,node,,nodenum2
/pnum,node,1
nplot




!修改坐标轴标题
/axlab,x,Load Location
/axlab,y,Value
/dev,font,1,Courier*New,400,0,-21,0,0,,,!标题字体大小，-21数字控制
!修改坐标轴数字大小
/gropt,axnsc,1.6 !此数可任意修改
!修改曲线显示
/color,curve,whit,1   ！第一条曲线的颜色为白
/color,grbak,blac      ！图形背景为黑
/color,grid,dgra        ！网格线颜色为灰
!设置图形曲线、坐标轴线型粗细：
/gthk,axis,2       !坐标轴，1-10调整粗细；
/gthk,grid,1       !网格线，1-10调整粗细；
/gthk,curve,2     !曲线，-1-10调整粗细，-1表示不画；









!(3)查看横梁弯矩和剪力,确定内力最大位置
/post1
alls
set,9
cmsel,s,mjl
/eshape,1
lplot
esll,s      
ETABLE,IMy,SMISC, 2  
ETABLE,JMy,SMISC, 15  
ETABLE,Ifz,SMISC, 5         
ETABLE,Jfz,SMISC, 18
PLLS,IMy,JMy,-0.75,0                !My 弯矩  
PLLS,Ifz,Jfz,-0.75,0                !z剪力

!(4)查看桩轴力
/post1
alls                  !荷载步编号
set,9
ETABLE,Ni,SMISC,1    !定义桩轴力单元表
ETABLE,Nj,SMISC,14
esel,s,type,,1
PLETAB,Ni             !全部受压
PLLS,Ni,Nj,0.1,0   

!(5)查看单元应力
/eshape,1
plnsol,s,x

!控制变形比例
/dscale,1,4500
/replot


!***切面观察应力分布
plnsol,s,x,,1
wpoffs,,,tl
wpoffs,10.5
wpoffs,,18.9
wpro,,,90
/TYPE,1,5   
/CPLANE,1  
/SHADE,1,1  
/HBC,1,0
/REPLOT
!取消切面
wpcsys,-1,0
/TYPE,1,6

349001291

谢谢 ！！分享

nnhjhua

谢谢分享，好东西

34818887

楼主发的都是命令流啊 本人还看不懂啊 但是还是要感谢楼主

weicailee

正想试着学命令流,谢楼主提供

qidian

楼主发的都是命令流啊 本人还看不懂啊 但是还是要感谢楼主

jychuanshuo

好东西大家就要分享，楼主伟大

meixi050713

谢谢分享

jbsu

十分感谢

祸害

好东西！顶楼主！在学习！

springer_

学习，进步

wjxcsg

谢谢楼主分享~~

liminga123

好东西 顶起来