某焊接件的两条焊缝在顺序焊接过程中的分析

yezhongliang12

这是一个对某焊接件的两条焊缝的凝固过程的温度场进行分析!没有加载移动热源.这样模拟的结果可信吗?如果可信,请问该怎么样将温度场转化为应力场来分析!恳请大家回复.
以下是APDL命令:

/FILNAME,Exercise15       ! 定义隐式热分析文件名
/PREP7                      ! 进入前处理器
ET,1,SOLID70                ! 选择8节点实体热分析单元
MP,KXX,1,.5e-3
MP,C,1,.2
MP,DENS,1,.2833
MPTEMP,1,0,2643,2750,2875,3000
MPDATA,ENTH,1,1,0,128.1,163.8,174.2,184.6    ! 定义右焊缝材料热物理性能
MP,KXX,2,.5e-3
MP,C,2,.2
MP,DENS,2,.2833
MP,KXX,3,0.5e-3                            ! 定义两块钢板的热物理性能
MP,C,3,.2
MP,DENS,3,.2833
MPTEMP,1,0,2643,2750,2875,3000
MPDATA,ENTH,3,1,0,128.1,163.8,174.2,184.6    ! 定义左焊缝材料热物理性能
BLOCK,-0.17,0.17,0,0.34,0,1.2
BLOCK,0.17,0.34,0,0.34,0,1.2
BLOCK,0.34,1,0,0.34,0,1.2
BLOCK,-0.17,0.17,0.34,0.51,0,1.2
BLOCK,-0.17,0.17,0.51,1.34,0,1.2
WPAVE,0.17,0.34,0
CYLIND,0.17,0,0,1.2,0,90
WPAVE,0,0,0
CSYS,0
FLST,3,3,6,ORDE,3   
FITEM,3,2   
FITEM,3,-3  
FITEM,3,6   
VSYMM,X,P51X, , , ,0,0                      ! 建立焊接件的几何模型
VGLUE,ALL                               ! 粘接各体
VSEL,S,,,10
VATT,1,1,1                                 ! 附于右焊缝的材料属性
VSEL,S,,,1
VSEL,A,,,12,17,1
VATT,2,1,1                                 ! 附于两块钢板的材料属性
VSEL,S,,,11
VATT,3,1,1                                 ! 附于左焊缝的材料属性
ALLSEL,ALL
ESIZE,0.05                                 ! 定义单元划分尺寸
VSWEEP,ALL                               ! 划分单元
ESEL,S,MAT,,3
TOFFST,460                              ! 定义温度偏移量
!第一步：稳态分析
EKILL,ALL                                ! 杀死左焊缝单元
ALLSEL,ALL
/SOLU
ANTYPE,TRANS                           ! 定义瞬态分析类型
TIMINT,OFF                               ! 关闭时间积分
ESEL,S,MAT,,1                           
NSLE                                     ! 选择右焊缝节点
D,ALL,TEMP,3000                          ! 施加右焊缝初始温度载荷         
NSEL,INVE                                ! 选择其它节点
D,ALL,TEMP,70                            ! 施加初始温度载荷
TIME,1                                    ! 定义求解时间                              
KBC,0                                     ! 设置为斜坡载荷
ALLSEL,ALL
SOLVE                                    ! 求解
!第二步：右侧焊缝相变分析（1到100秒)
DDELE,ALL,TEMP                         ! 删除温度载荷
TIMINT,ON                                ! 打开时间积分
TINTP,,,,1                                  ! 定义瞬态积分参数
TIME,100                                  ! 定义求解时间
DELTIME,1,.5,10                            ! 定义时间子步
AUTOTS,ON                               ! 打开自动时间开关
KBC,1                                     ! 设置为阶越载荷
OUTRES,ERASE
OUTRES,ALL,ALL                          ! 设置结果输出
ASEL,S,EXT
ASEL,U,LOC,Y,0
SFA,ALL,,CONV,5E-5,70                     ! 施加对流换热载荷
ALLSEL,ALL
SOLVE                                    ! 求解
!第三步：右侧焊缝凝固分析（100到1000秒)
TIME,1000                                 ! 定义求解时间
DELTIME,50,10,100                         ! 定义时间子步
AUTOTS,ON                               ! 打开自动时间开关
SOLVE                                    ! 求解
!第四步：激活左侧焊缝单元进行分析（1000到1001秒)
EALIVE,ALL                               ! 激活左侧焊缝单元
ALLSEL,all  
ESEL,S,MAT,,3
NSLE                                     ! 选择左焊缝节点
D,ALL,TEMP,3000                          ! 施加左焊缝初始温度载荷
TIME,1001                                 ! 定义求解时间
DELTIME,1,1,1                             ! 定义时间子步
ALLSEL,ALL
SOLVE                                    ! 求解
!第五步：左侧焊缝相变分析（1001到1100秒)
DDELE,ALL,TEMP                         ! 删除温度载荷
TIME,1100                                ! 定义求解时间
DELTIME,1,.5,10                           ! 定义时间子步
SOLVE                                   ! 求解
!第六步：左侧焊缝相变分析（1100到2000秒)
TIME,2000                                ! 定义求解时间
DELTIME,100,10,200                       ! 定义时间子步
SOLVE                                   ! 求解
!第七步：后处理
/POST1                                   ! 进入通用后处理器
SET,,, ,,, ,1                                 ! 读取1秒中分析结果
PLNSOL, TEMP,, 0                          ! 显示1秒钟后焊接件的温度分布
SET,,, ,,, ,25                                ! 读取2秒中分析结果
PLNSOL, TEMP,, 0                          ! 显示2秒钟后焊接件的温度分布
SET,,, ,,, ,30                                ! 读取100秒中分析结果
PLNSOL, TEMP,, 0                          ! 显示100秒钟后焊接件的温度分布
SET,NEXT                                 ! 读取1000秒中分析结果
PLNSOL, TEMP,, 0                          ! 显示1000秒钟后焊接件的温度分布
SET,NEXT                                 ! 读取1001秒中分析结果
PLNSOL, TEMP,, 0                          ! 显示1001秒钟后焊接件的温度分布
SET,,, ,,, ,53                                 ! 读取1100秒中分析结果
PLNSOL, TEMP,, 0                           ! 显示1100秒钟后焊接件的温度分布
SET,,, ,,, ,59                                 ! 读取2000秒中分析结果
PLNSOL, TEMP,, 0                           ! 显示2000秒钟后焊接件的温度分布
/POST26                                    ! 进入时间历程后处理器
NSOL,2,4727,TEMP,, TEMP_2   
STORE,MERGE                           
NSOL,3,4752,TEMP,,TEMP_3
STORE,MERGE
NSOL,4,4808,TEMP,,TEMP_4
STORE,MERGE
NSOL,5,4833,TEMP,,TEMP_5
STORE,MERGE
NSOL,6,4883,TEMP,,TEMP_6
STORE,MERGE
NSOL,7,4908,TEMP,,TEMP_7
STORE,MERGE  
NSOL,8,5088,TEMP,,TEMP_8
STORE,MERGE
NSOL,9,5308,TEMP,, TEMP_9               
STORE,MERGE                          ! 定义焊接件某些位置8个节点的时间温度变量
/AXLAB,X,TIME   
/AXLAB,Y,TEMPERATURE                ! 更改坐标轴标识
/XRANGE,0,2000                         ! 设定横坐标轴范围
PLVAR,2,3,4,5,6,7,8,9,                     ! 绘制8节点温度随时间的变化曲线

hggang

这个要顶
但是要是这个模型能算一下残余应力就比较的好！

hehe369

s是啊！！！！！！！！！！！！！1