关于帮助文档附带算例VM228的讨论

不够再添

VM228是计算辐射换热一个例子，用到了热辐射矩阵生成器/AUX12，很不错！我先把它附在下面，然后再提几个疑问，希望战友们回答。

VM228命令流：
/COM,ANSYS MEDIA REL. 9.0 (10/15/2004) REF. VERIF. MANUAL: REL. 9.0
/VERIFY,vm228,
/TITLE,vm228, Radiation Between Infinite Coaxial Cylinders
TIN=1000
TOUT=100
/PREP7  
ET,1,PLANE35 !CREATE 2D THERMAL ELEMENTS
MPTEMP,,,,,,,,        !SET MATERIAL PROPERTIES
MPTEMP,1,0  
MPDATA,EX,1,,30E6   
MPDATA,PRXY,1,,.27  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,.27  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,KXX,1,,1
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,C,1,,.21
CYL4,0,0,0.5,,1
CYL4,0,0,4, ,5  
MSHAPE,1,2D
MSHKEY,0
SMRT,4
AMES,ALL
  
LSEL,S,,,1,4
LSEL,A,,,13,16
SFL,ALL,RDSF,1, ,1,   !SET ALL FACING SURFACES TO EMISSIVITY 1
LSEL,S,,,9,12
DL,ALL, ,TEMP,TOUT,1  !APPLY UNIFORM TEMPERATURE TO EXTERIOR
LSEL,S,,,5,8
DL,ALL, ,TEMP,TIN,1   !APPLY UNIFORM TEMPERATURE TO INTERIOR
ASEL,S, , ,       1
ESLA,S  
CM,INSIDE,ELEM  
ASEL,S, , ,       2
ESLA,S  
CM,OUTSIDE,ELEM
ALLSEL
FINI
/AUX12  
STFCONST=0.119E-10
hemiopt,,,,,,,,,,,,,,,,,,,0
STEF,STFCONST         !SET STEFAN-BOLTZMAN CONSTANT FOR MODEL
TOFFST,0.E+00         !SET TEMPERATURE OFFSET
RADOPT,0.1,0.1,0.E+00,1000,0.1,0.1  !SET RADIOSITY OPTIONS
SPCTEMP,1,0.E+00      !SET TEMPERATURE FOR RADIATION TO SPACE
        !(NO RADIATION WILL APPEAR IN THIS MODEL)
!*
VFCALC !CALCULATE RADIOSITY VIEW FACTORS
VFQUERY,INSIDE,INSIDE !EXTRACT VIEW FACTOR FROM INTERIOR CYLINDER ELEMENTS DUE TO INTERIOR CYLINDER
*GET,VFAVG1,RAD,,VFAVG   !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
VFQUERY,OUTSIDE,INSIDE   !EXTRACT VIEW FACTOR FROM EXTERIOR CYLINDER ELEMENTS DUE TO INTERIOR CYLINDER
*GET,VFAVG2,RAD,,VFAVG   !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
VFQUERY,OUTSIDE,OUTSIDE  !EXTRACT VIEW FACTOR FROM EXTERIOR CYLINDER ELEMENTS DUE TO EXTERIOR CYLINDER
*GET,VFAVG3,RAD,,VFAVG   !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
FINISH
/SOLU
TIME,1
DELTIM,0.5
SOLV
FINI
/POST1
LSEL,S, , ,1,4
LSEL,A, , ,13,16
NSLL,S,1
*GET,TI,NODE,4,TEMP !INSIDE CYLINDER SURFACE TEMP
*GET,TO,NODE,13,TEMP !OUTSIDE CYLINDER SURFACE TEMP
*GET,HFI,NODE,4,TF,SUM !INSIDE CYLINDER HEAT FLUX
*GET,HFO,NODE,13,TF,SUM !OUTSIDE CYLINDER HEAT FLUX
! CALCULATE EXPECTED RADIATION FLUX
HFIEXP=ABS(TO**4-TI**4)*STFCONST/1
HFOEXP=ABS(TO**4-TI**4)*STFCONST/4
HFIERR=(HFI/HFIEXP)
HFOERR=(HFO/HFOEXP)
*status,parm
*DIM,VALUE,,5,3
*VFILL,VALUE(1,1),DATA,0,0.25,0.75,HFI,HFO
*VFILL,VALUE(1,2),DATA,VFAVG1,VFAVG2,VFAVG3,HFIEXP,HFOEXP
*VFILL,VALUE(1,3),DATA,0.000,VFAVG2/0.25,VFAVG3/0.75,HFIERR,HFOERR
*DIM,LABEL,CHAR,10,2
LABEL(1,1) = 'VF(1-1)','VF(2-1)','VF(2-2)','HFINSIDE','HFOUTSIDE'
/COM,------------------- VM228 RESULTS COMPARISON --------------
/COM,
/COM,               |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F8.3,'  ',F8.3,'   ',1F7.2)
/COM,-----------------------------------------------------------
FINI

其中的求解设置是：
TIME,1
DELTIM,0.5

为什么要把时间步长设为0.5？我把0.5改为0.1，0.2，0.8等等，计算结果都是不一样的。这是什么原因呢？
另外，按0.5计算后，ERROR文件会有这样的提示：

*** WARNING ***                        
Specify offset temperature for radiation problem using TOFFST command -
For model data in degrees Fahrenheit or Celsius.   
                     
*** WARNING ***                        
The calculated reference HT FLOW CONVERGENCE VALUE= 4.774703212E-10 is  
less than the default minimum of 1E-6 (MINREF field of CNVTOL           
command).  Check results carefully.

第一个WARING不要紧，第二个就可能比较致命了，难道ANSYS自带的例子也是有毛病的？

[ 本帖最后由 不够再添 于 2008-11-15 22:42 编辑 ]